Emergency Nasal Spray Medication Dispenser

/**
   This example connects to the device specific endpoint in AWS in order to
   publish and retrieve MQTT messages.
*/

#include <Arduino.h>

#include <ecc608.h>
#include <led_ctrl.h>
#include <log.h>
#include <lte.h>
#include <mqtt_client.h>


// documentation.
const char MQTT_SUB_TOPIC_FMT[] PROGMEM = "$aws/things/%s/shadow/update/delta";
const char MQTT_PUB_TOPIC_FMT[] PROGMEM = "%s/sensors";

char mqtt_sub_topic[128];
char mqtt_pub_topic[128];

bool initTopics() {
  ATCA_STATUS status = ECC608.begin();

  if (status != ATCA_SUCCESS) {
    Log.errorf(F("Failed to initialize ECC, error code: %X\r\n"), status);
    return false;
  }

  // Find the thing ID and set the publish and subscription topics
  uint8_t thing_name[128];
  size_t thing_name_length = sizeof(thing_name);

  status =
    ECC608.readProvisionItem(AWS_THINGNAME, thing_name, &thing_name_length);

  if (status != ATCA_SUCCESS) {
    Log.errorf(
      F("Could not retrieve thingname from the ECC, error code: %X\r\n"),
      status);
    return false;
  }

  snprintf_P(mqtt_sub_topic,
             sizeof(mqtt_sub_topic),
             MQTT_SUB_TOPIC_FMT,
             thing_name);
  snprintf_P(mqtt_pub_topic,
             sizeof(mqtt_pub_topic),
             MQTT_PUB_TOPIC_FMT,
             thing_name);

  return true;
}

static volatile bool button_pressed = false;
uint8_t medicationCount = 50;
/**
   @brief Gets called when the SW0 button is pressed.
*/
static void buttonInterrupt(void) {
  button_pressed = true;
}

static void sendMessage() {

  // Attempt to connect to AWS
  if (MqttClient.beginAWS()) {
    MqttClient.subscribe(mqtt_sub_topic);
  } else {
    Log.error(F("Failed to connect to AWS"));
    while (1) {}
  }



  const bool published_successfully =
    MqttClient.publish(mqtt_pub_topic, "{\"ButtonPress\":1}");

  if (published_successfully) {
    Log.info(F("Published message"));
  } else {
    Log.error(F("Failed to publish\r\n"));
  }

  delay(4000);

  String message = MqttClient.readMessage(mqtt_sub_topic);

  // Read message will return an empty string if there were no new
  // messages, so anything other than that means that there were a
  // new message
  if (message != "") {
    Log.infof(F("Got new message: %s\r\n"), message.c_str());
  }

  


  Log.info(F("Closing MQTT connection"));

  MqttClient.end();
  
}
void setup() {
  Log.begin(115200);
  LedCtrl.begin();
  LedCtrl.startupCycle();

  pinConfigure(PIN_PD2, PIN_DIR_INPUT | PIN_PULLUP_ON);
  attachInterrupt(PIN_PD2, buttonInterrupt, FALLING);

  pinConfigure(PIN_PA7, PIN_DIR_OUTPUT);
  digitalWrite(PIN_PA7, LOW);

  Log.info(F("Starting MQTT for AWS example\r\n"));

  if (!initTopics()) {
    Log.error(F("Unable to initialize the MQTT topics. Stopping..."));
    while (1) {}
  }

  if (!Lte.begin()) {
    Log.error(F("Failed to connect to operator"));
    while (1) {}
  }



  
}


void loop() {
  if (button_pressed)
  {
    digitalWrite(PIN_PA7, HIGH);
    sendMessage();
    button_pressed = false;
    digitalWrite(PIN_PA7, LOW);
  }
  
  
}