Sensor module to aid rescue and monitoring

/* Cdigo para o transmissor eo receptor para mdulo Nrf24L01, do Drone Terrestre 
 * do projeto: Sensor module to aid rescue and monitoring, do concurso 
 * do Site https://www.hackster.io/, Contest Transform Your Thinking, 17/01/2019
 
    (1) Receptor Module RF 433 // Garagino
    
    GND    ->   GND
    Vcc    ->   5v
    Data   ->   D11
    Ant    ->   Antena
            
    (2) Morores
    Neste projeto M1  -> motor direito
                      -> motor esquerdo
    M1 Velocidade -> D5
    M2 Velocidade -> D6
    M2 Sentido -> D7
    M1 Sentido -> D8

    Biblioteca DualMotor.
    Comandos:
    M1move(Velocidade,Sentido) -> M1move(D5,D8)
    M1parar()
    M2move(Velocidade,Sentido) -> M2move(D6,D7)
    velocidade (0 a 255) e 
    sentido (0 - horario,frente ou 1 - Anti-horario,tras)

    (3) Servos da camera

    Servo eixo D cima/baixo -> D4
    Servo eixos XY Direita/Esquerda -> D9

    (5) Potenciometro -> D10

Sketch com 5 canais, feito com base em http://www.brincandocomideias.com/ e http://www.electronoobs.com
*/

#include <VirtualWire.h> //Inclui a biblioteca VirtualWire.h
#include <ServoTimer2.h> //Biblioteca substituindo Servo.h que conflita
                         //com VirtualWire. Disponvel em https://github.com/nabontra/ServoTimer2/blob/master/ServoTimer2.cpp
#include <DualMotor.h> //Dual Motor Garagino
#include <Wire.h> 
#include <SoftwareSerial.h> //Saida TXRX

//Definies
#define pinRF 11 //Pino de recep. do radio

//*************** Controle do RF ***********************

struct tipoPacote //mesma estrutura para o transmissor e para o receptor
{ 
   int joystEsqX;
   int joystEsqY;
   int joystDirX;
   int joystDirY;
   int potenc;
};
tipoPacote pacote;

//Varivel para o armazenamento do buffer dos dados e do do tamanho do buffer
uint8_t buf[sizeof(pacote)]; 
uint8_t buftam = sizeof(pacote);

//*********************Controle do receptor***********************

ServoTimer2 camD;
ServoTimer2 camXY;
DualMotor dualmotor;

//Declarao de variveis dos dados recebidos pelo radio
int joystEsqX_valor = 1500;
int joystEsqY_valor = 1500;
int joystDirX_valor;
int joystDirY_valor;
int potenc_valor;

void setup() {
 
  //Definio dos pinos dos servos da camera
  camD.attach(4);
  camXY.attach(9);

  //Definio dos pinos dos motores
  pinMode(5, OUTPUT);
  pinMode(6, OUTPUT);
  pinMode(7, OUTPUT);
  pinMode(8, OUTPUT);

  //Definio do pino do Potenciometro
  pinMode(10, OUTPUT);
  
  //Inicializa o mdulo receptor
  vw_set_rx_pin(pinRF); //Configura o pino D11 para a leitura dos dados
  vw_setup(2000); //Configurao da velocidade (at 4000 bits por segundo)
  vw_rx_start(); //Inicia a leitura de dados do mdulo receptor
   
}

//****************************

void sentidoFT(){
  if(joystDirY_valor >= 0 && joystDirY_valor <= 85){
    dualmotor.M1move(potenc_valor,1);
    dualmotor.M2move(potenc_valor,0);
    
  }else if (joystDirY_valor >= 170 && joystDirY_valor <= 255){
    dualmotor.M1move(potenc_valor,0);
    dualmotor.M2move(potenc_valor,1);
  }
  
}

void sentidoDE(){
  if(joystDirX_valor >= 0 && joystDirX_valor <= 85){
    dualmotor.M1move(potenc_valor,1);
    dualmotor.M2move(potenc_valor,1);
    
  }else if (joystDirX_valor >= 170 && joystDirX_valor <= 255){
    dualmotor.M1move(potenc_valor,0);
    dualmotor.M2move(potenc_valor,0);
  }
}

//****************************

void loop() {
  
  if(vw_have_message()){
    vw_get_message(buf, &buftam);
    memcpy(&pacote,&buf,buftam);
 
    joystEsqX_valor = map(pacote.joystEsqX, 3, 1021, 2248, 748);
    camXY.write(joystEsqX_valor);
  
    joystEsqY_valor = map(pacote.joystEsqY, 3, 1021, 2248, 748);
    camD.write(joystEsqY_valor);
  
  }    

  joystDirX_valor = map(pacote.joystDirX, 0, 1023, 0, 255);
  sentidoDE();

  joystDirY_valor = map(pacote.joystDirY, 0, 1023, 0, 255);
  sentidoFT();

  potenc_valor = map(pacote.potenc, 0, 1023, 0, 255);
  
}