Published October 9, 2017 © CC BY-NC-SA

Full Alexa Home Automation for the Particle + Skill

Change color, read and set temperatures, lock and turn on/off using Alexa's home automation and the Particle Photon + Skill.

IntermediateProtip2 hours1,763

Full Alexa Home Automation for the Particle + Skill

Things used in this project

Hardware components

Particle Photon

Software apps and online services

Photon Smart Home Bridge

Story

**NOTE: For those who discovered oddly named devices in your alexa after trying this, we found a bug in the alexa skill which is now fixed. Special thanks to Bruce and Lagartus for both helping me track down and confirm it's fixed.

It's Simple. An Alexa Skill interfaces to a Library on the Particle device which abstracts away all the calls and communication required to implement Amazon Home Automation Skills. So now you can concentrate on bringing your devices to life instead of writing Lambdas, oAuth Servers and interfaces.

What does that really mean? Simple. You link your Particle.IO account to your Amazon Alexa account, then when you make a device that includes home automation, you simply say, "Alexa, Discover Devices" and it will find your device. And this interface supports a wide range of controls, not just on and off.

Using the EchoPhotonBridge, you'll be able to use phrases like:

Alexa, Turn Photon Light On

Alexa, Make Photon Light Red

Alexa, Lock File Cabinet

Alexa, what is the temperature of the blanket

What can it do?

The EchoPhotonBridge supports

Turn On & Off (like a Light or Fan)

Change a Device's Color (like a Light)

Set, Increase or Decrease a Percentage on a Device (like a Light Dimmer or Fan Speed)

Set, Increase or Decrease a Target Temperature (like for a Thermostat)

Ask for the Current Temperature of a Device (like how cold a room is)

Ask for the Target Temperature of a Device (like what the Thermostat is set to)

Lock a Device (like a door lock) - Alexa does not support unlocking

Ask for the Status of a Lock (locked or unlocked)

Set, Increase or Decrease a Color Temperature (like a light bulb)

What you need?

Purchase a Particle Photon when you get it, Create a Particle IO Account then add your Photon to your Account using your smart phone.

Program your Photon, in the Particle.io IDE, click on Libraries, search for EchoPhotonBridge and click on EchoPhotonBridge, then under examples, choose your what example to try. Then flash your device.

Add the Photon Smart Home Bridge to your Amazon Echo. You will be asked for your Particle.IO Login, so login - this will give the skill access to your devices. The bridge will scan your particle account for devices running the EchoPhotonBridge Library and interface them to Amazon.

Ask "Alexa Discover Devices" to trigger scanning for new devices and find your new Photon.

Got a Code Example?

You just define the name of the device and attach a function to call - it's easy - how easy? 5 Lines of code easy!

#include "EchoPhotonBridge.h"
EchoPhotonBridge epb;
int functionOnOff(int device, bool onOff, String rawParameters) {
  digitalWrite(D7, (onOff) ? HIGH : LOW);
}
void setup() {
  pinMode(D7, OUTPUT);
  epb.addEchoDeviceV2OnOff("Photon Light", &functionOnOff);
}
void loop() { }

Need More Code?

Check out the examples!

Need Help?

The Particle IO Bridge is available free. Should you need assistance, our suggestion is to visit the Particle.IO Community Site.

If you found a bug, please document it and open an issue on github.

// This #include statement was automatically added by the Particle IDE.
#include "EchoPhotonBridge.h"

EchoPhotonBridge epb;

//function OnOff - this turns a device on or off
int functionOnOff(int device, bool onOff, String rawParameters)
{
    digitalWrite(D7, (onOff) ? HIGH : LOW);
}

//  REMINDER: Tell your echo, "Alexa, Discover Devices" after you program your photon so Amazon picks it up.

void setup()
{
    pinMode(D7, OUTPUT);
    epb.addEchoDeviceV2OnOff("Photon Light", &functionOnOff);
}

void loop() 
{
  
}

#include <EchoPhotonBridge.h>
#include "Adafruit_GFX.h"
#include "Adafruit_SSD1306.h"

#define OLED_RESET D4
Adafruit_SSD1306 display(OLED_RESET);
EchoPhotonBridge epb;

#define LOGO16_GLCD_HEIGHT 16 
#define LOGO16_GLCD_WIDTH  16 

//Pin assignments
#define FAN A4
#define LIGHT A5

//#define DEBUG_PUBLISH_TO "sumologic"

void setup()   {     
    pinMode(FAN, OUTPUT);
    analogWrite(FAN, 0, 500);
    
    pinMode(LIGHT, OUTPUT);
    analogWrite(LIGHT, 0, 500);
      
    
    String deviceName = "Chair Fan";
    epb.addEchoDeviceV2OnOff(deviceName, &functionOnOff);
    epb.addEchoDeviceV2Percent(deviceName, &functionPercent);
    
    deviceName = "Chair Light";
    epb.addEchoDeviceV2OnOff(deviceName, &functionOnOff);
    epb.addEchoDeviceV2Percent(deviceName, &functionPercent);
    
    display.begin(SSD1306_SWITCHCAPVCC, 0x3c);  // initialize with the I2C addr 0x3D (for the 128x64)
    display.clearDisplay();
    display.display();
    display.setTextSize(3);
    display.setTextColor(WHITE);
    display.setCursor(0,0);
    display.println("Chair");
    display.display();
 
}



void loop() {
  
}

void writeLCD(int Size, String Line1, String Line2, String Line3, String Line4)
{
  display.clearDisplay();
  display.display();
  display.setTextSize(Size);
  display.setTextColor(WHITE);
  display.setCursor(0,0);
  display.println(Line1);
  display.println(Line2);
  display.println(Line3);
  display.println(Line4);
  display.display();
 
}

//function OnOff - this turns a device on or off
int functionOnOff(int device, bool onOff, String rawParameters)
{
    #ifdef DEBUG_PUBLISH_TO
        Particle.publish(DEBUG_PUBLISH_TO, String("functionOnOff  " + String(device) + "  " + String(onOff) + "  " + rawParameters));
    #endif
    
    writeLCD(2,"Chair",(device==0) ? " Fan" : " Light", "  Is",(onOff) ? "   On" : "   Off");
    
    analogWrite((device == 0) ? FAN : LIGHT, (onOff) ? 250 : 0, 500);
            
    return 0;
}




int functionPercent(int device, int percent, int changeAmount, String rawParameters)
{
    #ifdef DEBUG_PUBLISH_TO
        Particle.publish(DEBUG_PUBLISH_TO, String("functionPercent  " + String(device) + "  " + String(percent) + "  " + String(changeAmount) + "  " + rawParameters));
    #endif
    
    writeLCD(2,"Chair",(device==0) ? " Fan" : " Light", "  at","     " + String(percent) + "%");
    
    analogWrite((device == 0) ? FAN : LIGHT, percent * 2.5, 500);
   
    return percent;
}

#include <FastLED.h>
FASTLED_USING_NAMESPACE;
#define PARTICLE_NO_ARDUINO_COMPATIBILITY 1

#include <EchoPhotonBridge.h>

#define NUM_LEDS 32
#define FASTLED_PIN 6


CRGB leds[NUM_LEDS];
EchoPhotonBridge epb;

int currentTemp = 81;
int setTemp = 78;

/*

Test Device Names: Photon, Blanket, Test Room

Test Utterances:

Alexa, Turn Photon On
Alexa, Turn Photon Off
Alexa, Make Photon Red
Alexa, Make Photon Blue
Alexa, Set Photon to 10 Percent
Alexa, Set Photon to 90 Percent

Alexa, Turn Test Room On
Alexa, Turn Test Room Off
Alexa, Make Test Room Red
Alexa, Make Test Room Blue
Alexa, Set Test Room to 10 Percent
Alexa, Set Test Room to 90 Percent
Alexa, Lock Test Room

Alexa, Set the Temperature of my blanket to 90 degrees
Alexa, What is the temperature of my blanket?
Alexa, Turn Blanket On
Alexa, Turn Blanket Off

*/


int functionOnOff(int device, bool onOff, String rawParameters)
{
    leds[device] = (onOff) ? CRGB::White : CRGB::Black;
    FastLED.show();
    return 0;
}

int functionPercent(int device, int percent, int changeAmount, String rawParameters)
{
    leds[device + 3].r = 255 - (255 * percent / 100);
    leds[device + 3].g = percent / 100 * 255;
    leds[device + 3].b = percent + 50;
    FastLED.show();
    return 0;
}

int functionColor(int device, int R, int G, int B, String rawParameters)
{
    leds[device].r = R;
    leds[device].g = G;
    leds[device].b = B;
    FastLED.show();
    return 0;
}

int functionTemp(int device, bool requestCurrentTemp, bool requestSetTemp, int temperature, int changeAmount, String rawParameters)
{
    leds[6] = CRGB::White;
    if (requestCurrentTemp) return currentTemp;
    if (requestSetTemp) return setTemp;
    setTemp = temperature;
    leds[6].r = setTemp;
    leds[6].g = setTemp;
    leds[6].b = setTemp;
    FastLED.show();
    return 0;
}

bool virtualLock = false;

//functionLock tells a device to change color or requests the status of a lock.
//(int, bool, bool, String);
int functionLock(int device, bool requestStatus, bool locked, String rawParameters)
{
    if (requestStatus) return ((virtualLock) ? 1 : 0);
    
    virtualLock = locked;
    
    leds[7] = (virtualLock) ? CRGB::Red : CRGB::Green; 
    FastLED.show();
    
    return 0;
}


void setup() 
{
    FastLED.addLeds<WS2812, FASTLED_PIN, GRB>(leds, NUM_LEDS);

    String deviceName = "Photon";
    epb.addEchoDeviceV2OnOff(deviceName, &functionOnOff);
    epb.addEchoDeviceV2Percent(deviceName, &functionPercent);
    epb.addEchoDeviceV2Color(deviceName, &functionColor);
    
    deviceName = "Test Room";
    epb.addEchoDeviceV2OnOff(deviceName, &functionOnOff);
    epb.addEchoDeviceV2Percent(deviceName, &functionPercent);
    epb.addEchoDeviceV2Color(deviceName, &functionColor);
    epb.addEchoDeviceV2Lock(deviceName, &functionLock);
    
    deviceName = "Blanket";
    epb.addEchoDeviceV2OnOff(deviceName, &functionOnOff);
    epb.addEchoDeviceV2Temp(deviceName, &functionTemp);
    
    leds[0] = CRGB::Pink;
    leds[1] = CRGB::Blue;
    leds[2] = CRGB::Orange;
    leds[3] = CRGB::Purple;
    leds[4] = CRGB::Yellow;
    leds[5] = CRGB::Green;
    leds[6] = CRGB::Red;
    leds[7] = CRGB::White;
    FastLED.show();
}

void loop() 
{
    
}

#include <OneWire.h>
#include <DS18.h>
#include <Adafruit_ST7735.h>
#include <EchoPhotonBridge.h>
//Load Fast LED Library and set it's options.
#include <FastLED.h>
FASTLED_USING_NAMESPACE;
#define PARTICLE_NO_ARDUINO_COMPATIBILITY 1

//Set Defines to set up Hardware.
#define NUM_LEDS 32
#define FASTLED_PIN 6

#define FAN D0
#define ONEWIRE D2
#define BL  D1
#define CS  A2
#define DC  D4
#define RST A1

#define TEMPLOCKTIME 30 //30 minutes

//Local Variables
int setTemp = 80;
int currentTemp;
String lastUpdate = "";
unsigned long oldTime = 0;
unsigned long tempLockTime = 0;
bool thermostat = true;


CRGB leds[NUM_LEDS];
EchoPhotonBridge epb;
Adafruit_ST7735 tft = Adafruit_ST7735(CS, DC, RST);
DS18 sensor(ONEWIRE);

int functionOnOff(int device, bool onOff, String rawParameters)
{
    tft.setTextColor((onOff) ? ST7735_GREEN : ST7735_RED, ST7735_BLACK);
    tft.setTextSize(1);
    tft.setCursor(0,140);
    tft.fillRect(0,140,128,160,ST7735_BLACK);
    switch (device)
    {
        case 0: //Fan
            analogWrite(FAN, (onOff) ? 250 : 0, 500);
            tft.println((onOff) ? "Fan On" : "Fan Off");
            tempLockTime = millis() + (1000 * 60 * TEMPLOCKTIME);
            updateThermostatDisplay("Paused");
            break;
        case 1: //LCD BackLight
            analogWrite(BL, (onOff) ? 250 : 0, 500);
            tft.println((onOff) ? "Backlight On" : "Backlight Off");
            break;
        case 2: //termostat
            thermostat = onOff;
            updateThermostatDisplay((onOff) ? "On" : "Off");
            break;
        case 3: //Fast LED Array
            for (int i = 0; i < NUM_LEDS; i++) 
            {
                leds[i] = (onOff) ? CRGB::White : CRGB::Black;
            }
                FastLED.show();
            tft.println((onOff) ? "Light On" : "Light Off");
            break;
    }
    return 0;
}

int functionPercent(int device, int percent, int changeAmount, String rawParameters)
{
    tft.setTextColor(ST7735_BLUE, ST7735_BLACK);
    tft.setTextSize(1);
    tft.setCursor(0,140);
    tft.fillRect(0,140,128,160,ST7735_BLACK);
    switch (device)
    {
        case 0: //Fan
            analogWrite(FAN, percent * 2.5, 500);
            tft.println("Fan to " + String(percent) + "%");
            tempLockTime = millis() + (1000 * 60 * TEMPLOCKTIME);
            updateThermostatDisplay("Paused");
            break;
        case 1: //LCD BackLight
            analogWrite(BL, percent * 2.5, 500);
            tft.println("LCD BL to " + String(percent) + "%");
            break;
        case 3: //Fast LED
            
            FastLED.show();
            break;    
    }
    
    return 0;
}

int functionColor(int device, int R, int G, int B, String rawParameters)
{
    for (int i = 0; i < NUM_LEDS; i++) 
    {
        leds[i].r = R;
        leds[i].g = G;
        leds[i].b = B;
    }
    FastLED.show();
    
    return device * 1000000;
}



int functionTemp(int device, bool requestCurrentTemp, bool requestSetTemp, int temperature, int changeAmount, String rawParameters)
{
    if (requestCurrentTemp) return currentTemp;
    if (requestSetTemp) return setTemp;
    setTemp = temperature;
    thermostat = true;
    updateThermostatDisplay("On");
    return 0;
}

void updateThermostatDisplay(String state) 
{
    tft.setCursor(0,80);
    tft.println("Thermostat " + String(setTemp) + " F");
    tft.fillRect(0,80,128,120,ST7735_BLACK);
    tft.setCursor(0,100);
    tft.println(state);
}

void setup() {
    pinMode(FAN, OUTPUT);
    analogWrite(FAN, 0, 500);
    
    pinMode(BL, OUTPUT);
    analogWrite(BL, 250, 500);
    
    FastLED.addLeds<WS2812, FASTLED_PIN, GRB>(leds, NUM_LEDS);

    String deviceName = "Cool Breeze";
    String deviceType = "Fan";
    epb.addEchoDeviceV2OnOff(deviceName + " " + deviceType, &functionOnOff);
    epb.addEchoDeviceV2Percent(deviceName + " " + deviceType, &functionPercent);
    epb.addEchoDeviceV2Temp(deviceName + " " + deviceType, &functionTemp);
    
    deviceType = "BackLight";
    epb.addEchoDeviceV2OnOff(deviceName + " " + deviceType, &functionOnOff);
    epb.addEchoDeviceV2Color(deviceName + " " + deviceType, &functionColor);
    epb.addEchoDeviceV2Percent(deviceName + " " + deviceType, &functionPercent);
    
    deviceType = "Thermostat";
    epb.addEchoDeviceV2OnOff(deviceName + " " + deviceType, &functionOnOff);
   
    deviceType = "Light";
    epb.addEchoDeviceV2OnOff(deviceName + " " + deviceType, &functionOnOff);
    epb.addEchoDeviceV2Color(deviceName + " " + deviceType, &functionColor);
    epb.addEchoDeviceV2Percent(deviceName + " " + deviceType, &functionPercent);
    
    tft.initG();
    tft.fillScreen(ST7735_BLACK);
    //tft.setFont(TIMESNEWROMAN8);
    tft.setTextSize(1);
    tft.setTextColor(ST7735_WHITE);
	tft.setCursor(10,120);
    tft.setTextColor(ST7735_WHITE);
    tft.setTextWrap(true);
    tft.println(deviceName);  
    
    functionOnOff(2,true,""); //Turn on Thermostat.
    oldTime = millis();
}

void loop() {
    
    if(millis() - oldTime >= 1000)
    {
        
        if (sensor.read()) {
            tft.setTextColor(ST7735_BLACK);
            tft.setCursor(20, 20);
            tft.setTextSize(4);
            tft.print(lastUpdate);
            tft.setTextColor(ST7735_WHITE);
            tft.setCursor(20,20);
            lastUpdate = String::format("%1.1f",sensor.fahrenheit());
            tft.print(lastUpdate);
            Particle.publish("sumologic", lastUpdate);
            
            currentTemp = sensor.fahrenheit();
            if (tempLockTime < millis() && thermostat) 
            {
                if (currentTemp > setTemp + 1)
                {
                    functionOnOff(0,true,"");
                }
                else if (currentTemp < setTemp - 1)
                {
                    functionOnOff(0,false,"");                
                }
            }
        }   
        oldTime = millis(); //update old_time to current millis()
    }
}

Credits

Jeremy Proffitt

1 project • 7 followers

An SRE by trade, I'm the jack of all trades, master of none with an understanding of failure, risk and reward. I love to create and fix.

Contact

Comments

Please log in or sign up to comment.

Full Alexa Home Automation for the Particle + Skill

Things used in this project

Hardware components

Software apps and online services

Story

What can it do?

What you need?

Got a Code Example?

Need More Code?

Need Help?

Code

Example Code: Turn Item On / Off

Example Code: Fan and Light with OLED

Example Code: All Supported Alexa Functions

Example Code: Temperature Controlled Fan

Full GitHub: EchoPhotonBridge Photon Library + Examples

Credits

Jeremy Proffitt

Comments

Embed the widget on your own site

Full Alexa Home Automation for the Particle + Skill

Full Alexa Home Automation for the Particle + Skill

Things used in this project

Hardware components

Software apps and online services

Story

What can it do?

What you need?

Got a Code Example?

Need More Code?

Need Help?

Code

Example Code: Turn Item On / Off

Example Code: Fan and Light with OLED

Example Code: All Supported Alexa Functions

Example Code: Temperature Controlled Fan

Full GitHub: EchoPhotonBridge Photon Library + Examples

Credits

Jeremy Proffitt

Comments

Related channels and tags