Published April 30, 2019 © MIT

Arduino - Make a Wi-Fi/Ethernet Serial Converter

Make a converter that transform data from Serial to Wi-Fi/Ethernet and vice versa, by using Arduino.

BeginnerFull instructions provided1 hour20,029

Arduino - Make a Wi-Fi/Ethernet Serial Converter

Things used in this project

Hardware components

Arduino UNO

PHPoC Shield 2 for Arduino

PHPoC Smart RS232 Board

DIYables USB Cable 2.0 Type A/B for Arduino Uno

DIYables Starter Kit

Story

Why should we do it?

In the era of IoT, do you still own any serial device?

For me? Yes, I do. I have a Pan-tilt camera which only supports RS485 interface, and I am not gonna throw it away any time soon. There are tons of serial devices over there in the real world, not to mention that most of industrial devices still use serial interfaces. Serial communication is simple, cost-efficient, reliable, and can come to the rescue whenever you need to get the console access to the device.

But, we are living in the era of IoT! Isn't it great if we can add network capability to those serial devices, so that we are able to access them from wherever we want.

Here I will show you how I made a simple Ethernet to RS232 converter by using Arduino Uno and PHPoC Shield. TCP data that bypasses Ethernet connection can be transformed into serial data, and vice versa.

System Architecture

So, how to make it?

I use a Smart RS232 Board for serial interface. Along with a PHPoC Shield 2, they are stacked on an Arduino Uno.

Each Smart RS232 Board has an RS-232 port, and is addressed by ID, which can set by manually setting DIP switches. For example, in this project, the board is addressed as 1.

A PHPoC shield supports both Wi-Fi and Ethernet connectivity, but you can only choose either of them for network connection. In my project, I set up an Ethernet connection for PHPoC Shield.

With a small change in hardware setup, this can become a Wi-Fi/Ethernet to RS232/RS422/RS485 converter. Maybe with more effort, you can even make a Wi-Fi/Ethernet Serial gateway, since an Arduino board can carry up to 14 smart expansion boards, and by combining with a PHPoC shield, it can support up to 4 TCP connections simultaneously.

Arduino Uno + PHPoC Shield 2 + Smart RS232 Board

With cables

In my project, Arduino board with PHPoC shield works as a TCP client. That means, it can connect to a TCP server via Ethernet network. Well, TBH, you can just call my project "TCP to Serial converter" as well.

Arduino code does the straightforward work: read the incoming data from serial, then forward it to TCP server, as well as read incoming data from TCP server and send it to serial.

You can take a look at the screenshot below for the demonstration:

Simple test window

Learn more about Arduino for Beginners

ethernet2RS232

#include <Phpoc.h>
#include <PhpocExpansion.h>

#define BUFFER_SIZE 100
#define TCP_PEER_ADDR "192.168.0.110"   // enter your tcp server addr here
#define TCP_PEER_PORT 1470    // enter your tcp server port here

char peer_addr[] = TCP_PEER_ADDR;
int peer_port = TCP_PEER_PORT;
PhpocClient tcp_client;

byte expansionId = 1; // based on the DIP switches you set
// https://www.phpoc.com/support/manual/pes-2607_user_manual/contents.php?id=layout
ExpansionSerial rs232(expansionId);

byte tcp_buf[BUFFER_SIZE];
byte serial_buf[BUFFER_SIZE];
int rwlen;

void setup() {
  Serial.begin(9600);
  while(!Serial)
    ;

  // initialize PHPoC [WiFi] Shield:
  Phpoc.begin(PF_LOG_SPI | PF_LOG_NET);

  // connect to TCP server
  if(tcp_client.connect(peer_addr, peer_port))
  {
    // if connected
    Serial.println("Connected to server");
  }
  else // if not connected
    Serial.println("connection failed");

  Expansion.begin();
  // set baudrate, parity, data bit, stop bit and flow control to  115200, none,
  // 8 bit, 1 bit and no flow control, respectively.
  rs232.begin(F("115200N81N"));

}

void loop() {


  int tcp_rxlen = tcp_client.available();
  int serial_txfree = rs232.availableForWrite();
  if (tcp_rxlen) {
    if (serial_txfree > tcp_rxlen)
  {
    rwlen = (tcp_rxlen <= BUFFER_SIZE) ? tcp_rxlen : BUFFER_SIZE;
  
    // read the incoming bytes from TCP communication
    tcp_client.readBytes(tcp_buf, rwlen);
    // send these received data via serial interface
    rs232.write(tcp_buf, rwlen);
  }
  }

  int serial_rxlen = rs232.available();
  int tcp_txfree = tcp_client.availableForWrite();
  if(serial_rxlen) {
  if (tcp_txfree > serial_rxlen)
  {
  rwlen = (serial_rxlen <= BUFFER_SIZE) ? serial_rxlen : BUFFER_SIZE;
  // read the incoming bytes from serial communication
  rs232.readBytes(serial_buf, rwlen);
  // send these received data via TCP interface
    tcp_client.write(serial_buf, rwlen);
  }
  }

  if(!tcp_client.connected())
  {
    // if the server's disconnected, stop the tcp_client:
    Serial.println("disconnected");
    tcp_client.stop();
    // do nothing forevermore:
    while(true)
      ;
  }
}