DHT11 Temperature and Humidity Sensor With Arduino

In this section, we will build a simple project using Arduino that reads the temperature and humidity and displays the results on the serial monitor.

Supplies

Arduino UNO – Read Best Arduino Starter Kits

DHT11 Temperature and Humidity Sensor

Breadboard

4.7k Ohm Resistor

Jumper Wires

Step 1: Schematic

Follow the next schematic to connect the DHT11 (or DHT22) Temperature and Humidity Sensor to the Arduino.

NOTE: If you are using a module with a DHT sensor, it will usually only come with three pins. The pins should be labeled so you know how to wire them. Also, many of these modules already come with an internal pull-up resistor so you don't need to add one to your circuit.

Step 2: Installing the Library

To read the DHT sensor, we will use the DHT library from Adafruit. To use this library, you will also need to install the Adafruit Unified Sensor library. Follow the steps below to install these libraries.

Open your Arduino IDE and go to Sketch > Include Library > Manage Libraries. The Library Manager should open.

Search for "DHT" in the Search box and install the DHT library from Adafruit.

Once the DHT library from Adafruit is installed, type "Adafruit Unified Sensor" in the search box. Scroll all the way down to find the library and install it.

Once the library is installed, restart the Arduino IDE.

Step 3: Coding

After installing the necessary libraries, you can upload the example code from the library.

In your Arduino IDE, go to File > Examples > DHT Sensor Library > DHTtester

The following code should load. It reads the temperature and humidity and displays the results in the serial monitor.

// Example testing sketch for various DHT humidity/temperature sensors

// Written by ladyada, public domain

// REQUIRES the following Arduino libraries:

// - DHT Sensor Library: https://github.com/adafruit/DHT-sensor-library

// - Adafruit Unified Sensor Lib: https://github.com/adafruit/Adafruit_Sensor

#include "DHT.h"

#define DHTPIN 2 // Digital pin connected to the DHT sensor

// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --

// Pin 15 can work but DHT must be disconnected during program upload.

// Uncomment whatever type you're using!

//#define DHTTYPE DHT11 // DHT 11

#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321

//#define DHTTYPE DHT21 // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V

// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1

// to 3.3V instead of 5V!

// Connect pin 2 of the sensor to whatever your DHTPIN is

// Connect pin 3 (on the right) of the sensor to GROUND (if your sensor has 3 pins)

// Connect pin 4 (on the right) of the sensor to GROUND and leave the pin 3 EMPTY (if your sensor has 4 pins)

// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor.

// Note that older versions of this library took an optional third parameter to

// tweak the timings for faster processors. This parameter is no longer needed

// as the current DHT reading algorithm adjusts itself to work on faster procs.

DHT dht(DHTPIN, DHTTYPE);

void setup() {

Serial.begin(9600);

Serial.println(F("DHTxx test!"));

dht.begin();

}

void loop() {

// Wait a few seconds between measurements.

delay(2000);

// Reading temperature or humidity takes about 250 milliseconds!

// Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)

float h = dht.readHumidity();

// Read temperature as Celsius (the default)

float t = dht.readTemperature();

// Read temperature as Fahrenheit (isFahrenheit = true)

float f = dht.readTemperature(true);

// Check if any reads failed and exit early (to try again).

if (isnan(h) || isnan(t) || isnan(f)) {

Serial.println(F("Failed to read from DHT sensor!"));

return;

}

// Compute heat index in Fahrenheit (the default)

float hif = dht.computeHeatIndex(f, h);

// Compute heat index in Celsius (isFahreheit = false)

float hic = dht.computeHeatIndex(t, h, false);

Serial.print(F("Humidity: "));

Serial.print(h);

Serial.print(F("% Temperature: "));

Serial.print(t);

Serial.print(F("°C "));

Serial.print(f);

Serial.print(F("°F Heat index: "));

Serial.print(hic);

Serial.print(F("°C "));

Serial.print(hif);

Serial.println(F("°F"));

}

Step 4: For Example

After uploading the code to the Arduino, open the Serial Monitor at a baud rate of 9600. You should get a sensor reading every two seconds. This is what you should see in the Arduino IDE serial monitor.