Introduction to Home Automation: Arduino Weather Station Lab

        //CS198 Home Automation & Networking Fundamentals
        //LAB 2: Weather Station Demo Using an LCD
        //Ron Kessler
        //Created 7/16/2015
        //Updated 7/29/2020
        //  Uses the V1.2 LCD from DFRobot and the updated Library.
        
        
        
        //Updated 7/27/2015  Made note about pull-ups and changed row/column assignments on setCursor method. Also
        //      made humidity display as an integer instead of a float. See note below.
        //Adapted from Home Automation with Arduino by Marco Swartz
      
        //When wiring the LCD, add 4.7K pull-up resistors on the SCL and SDA pins (A4 and A5 on Arduino)

        // Code to measure data & display it on the LCD screen
        //the correct liquidcrystal lib is in c\progfiles\arduino\libs
        
        // import these Libraries  See the README for details!
        #include <Wire.h> 
        #include <LiquidCrystal_I2C.h>    // for the LCD using ver 1.2 as of 7/28/2020
        #include <DHT.h>                  //the temp/humidity sensor
        
        // DHT sensor setup
        #define DHTPIN 7 
        #define DHTTYPE DHT11
        
        // LCD display instance
        LiquidCrystal_I2C lcd(0x20,20,4);   //make sure the lcd address is 0x20. It shows 0x27 in the book and will never work!

        // create a DHT instance
        DHT dht(DHTPIN, DHTTYPE);
        
        void setup()
        {
          // Initialize the lcd 
          lcd.init();
          
          // Print a message to the LCD.
          lcd.backlight();
          lcd.setCursor(0,0);
          lcd.print("CS198: Arduino Lab 2");
          lcd.setCursor(0,1);
          lcd.print("Weather Station");
          
          lcd.setCursor(0,3);
          lcd.print("Initializing.....");
          // Init DHT to start reading data
          dht.begin();
          
          // Clear LCD
         delay(5000);
         lcd.clear();
          
          
        }
        
        //---Our main loop
        void loop()
        {
          
          
          // Measure from DHT
          float temperature = dht.readTemperature();
          float humidity = dht.readHumidity();
          
          // Measure light level
          float sensor_reading = analogRead(A0);
          float light = sensor_reading/1024*100; //the Arduino A/D converter uses 10 bits. 2^10 =1024 so divide raw data by 1024 and * by 100 to get %
          
          // Display temperature
          lcd.setCursor(0,0);                       //col 0 row 0    setCursor is zero-based
          lcd.print("Temp.: ");
          //lcd.print((float)temperature,1);          //celsius with 1 decimal
          
          //--my C2F function (see below)
          lcd.print((float)C2F(temperature),1);   //Fahrenheit to 1 decimal.  Leave out the ,1 if you want a whole number
          lcd.print((char)223);                   //the little degree symbol
          lcd.print("F");
          
           // Display humidity
          lcd.setCursor(0,1);                     //col 0 row 1
          lcd.print("Humidity: ");
          lcd.print((int)humidity);               //cast to a float if you want decimal places. I was happy with integer!
          lcd.print("%");
          
          // Display light level
          lcd.setCursor(0,2);                    //col 0 row 2
          lcd.print("Light: ");
          lcd.print(light);
          lcd.print("%");

       
         
          // Wait 2 seconds
          delay(2000);                            //wait 2 seconds before updating again

         
         
        }

        /* *************HELPER FUNCTIONS *************** */
        
        //Celsius to Fahrenheit conversion
        float C2F(float celsius)
        {
          return 1.8 * celsius + 32;
        }

        /*  END OF CODE  */