Surilli WiFi ESP8266 Web Server with Arduino IDE

In this tutorial, we will create a standalone web server with Surilli WiFi ESP8266 that can toggle two LEDs using Arduino IDE. This Surilli WiFi ESP8266 is mobile responsive and it can be accessed with any device that acts as a browser in your local network.

Hardware Required

1. Surilli WiFi

2. 2 LEDs

3. 2 x 330 ohm Resistors (values other than 330 ohms will also work)

4. Breadboard

5. Connecting Wires

6. Arduino IDE

Set Up Arduino IDE for Surilli

Make sure you have selected the right port, board and processor for the Surilli as shown in the picture below and it is programmable (compile and upload “Blink” from File>Examples>Digital>Blink onto your Surilli to check if everything is working fine).

The Circuitry

The circuitry is very simple. It's mostly the programming. Follow the figure below to set up your hardware.

Upload and Burn Code Onto Surilli

Now you have completed setting up your hardware and Arduino IDE. Copy and paste the Arduino sketch given below into your Arduino IDE. Replace the SSID and password with your own credentials and hit upload. The results can be viewed on the Serial Monitor.

Arduino Code:

// Load Wi-Fi library
#include <ESP8266WiFi.h>
// Replace with your network credentials
const char* ssid     = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";
// Set web server port number to 80
WiFiServer server(80);
// Variable to store the HTTP request
String header;
// Auxiliar variables to store the current output state
String output5State = "off";
String output4State = "off";
// Assign output variables to GPIO pins
const int output5 = 5;
const int output4 = 4;
void setup() {
 Serial.begin(115200);
 // Initialize the output variables as outputs
 pinMode(output5, OUTPUT);
 pinMode(output4, OUTPUT);
 // Set outputs to LOW
 digitalWrite(output5, LOW);
 digitalWrite(output4, LOW);
 // Connect to Wi-Fi network with SSID and password
 Serial.print("Connecting to ");
 Serial.println(ssid);
 WiFi.begin(ssid, password);
 while (WiFi.status() != WL_CONNECTED) {
   delay(500);
   Serial.print(".");
 }
 // Print local IP address and start web server
 Serial.println("");
 Serial.println("WiFi connected.");
 Serial.println("IP address: ");
 Serial.println(WiFi.localIP());
 server.begin();
}
void loop(){
 WiFiClient client = server.available();   // Listen for incoming clients
 if (client) {                             // If a new client connects,
   Serial.println("New Client.");          // print a message out in the serial port
   String currentLine = "";                // make a String to hold incoming data from the client
   while (client.connected()) {            // loop while the client's connected
     if (client.available()) {             // if there's bytes to read from the client,
       char c = client.read();             // read a byte, then
       Serial.write(c);                    // print it out the serial monitor
       header += c;
       if (c == '\n') {                    // if the byte is a newline character
         // if the current line is blank, you got two newline characters in a row.
         // that's the end of the client HTTP request, so send a response:
         if (currentLine.length() == 0) {
           // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
           // and a content-type so the client knows what's coming, then a blank line:
           client.println("HTTP/1.1 200 OK");
           client.println("Content-type:text/html");
           client.println("Connection: close");
           client.println();
           // turns the GPIOs on and off
           if (header.indexOf("GET /5/on") >= 0) {
             Serial.println("GPIO 5 on");
             output5State = "on";
             digitalWrite(output5, HIGH);
           } else if (header.indexOf("GET /5/off") >= 0) {
             Serial.println("GPIO 5 off");
             output5State = "off";
             digitalWrite(output5, LOW);
           } else if (header.indexOf("GET /4/on") >= 0) {
             Serial.println("GPIO 4 on");
             output4State = "on";
             digitalWrite(output4, HIGH);
           } else if (header.indexOf("GET /4/off") >= 0) {
             Serial.println("GPIO 4 off");
             output4State = "off";
             digitalWrite(output4, LOW);
           }
           // Display the HTML web page
           client.println("<!DOCTYPE html><html>");
           client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
           client.println("<link rel=\"icon\" href=\"data:,\">");
           // CSS to style the on/off buttons 
           // Feel free to change the background-color and font-size attributes to fit your preferences
           client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
           client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
           client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
           client.println(".button2 {background-color: #77878A;}</style></head>");
           // Web Page Heading
           client.println("<body><h1>ESP8266 Web Server</h1>");
           // Display current state, and ON/OFF buttons for GPIO 5  
           client.println("<p>GPIO 5 - State " + output5State + "</p>");
           // If the output5State is off, it displays the ON button       
           if (output5State=="off") {
             client.println("<p><a href=\"/5/on\"><button class=\"button\">ON</button></a></p>");
           } else {
             client.println("<p><a href=\"/5/off\"><button class=\"button button2\">OFF</button></a></p>");
           } 
           // Display current state, and ON/OFF buttons for GPIO 4  
           client.println("<p>GPIO 4 - State " + output4State + "</p>");
           // If the output4State is off, it displays the ON button       
           if (output4State=="off") {
             client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
           } else {
             client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
           }
           client.println("</body></html>");
           // The HTTP response ends with another blank line
           client.println();
           // Break out of the while loop
           break;
         } else { // if you got a newline, then clear currentLine
           currentLine = "";
         }
       } else if (c != '\r') {  // if you got anything else but a carriage return character,
         currentLine += c;      // add it to the end of the currentLine
       }
     }
   }
   // Clear the header variable
   header = "";
   // Close the connection
   client.stop();
   Serial.println("Client disconnected.");
   Serial.println("");
 }
}

Open the Arduino IDE Serial Monitor at a baud rate of 115200. After a few seconds your IP address should appear. In my case, the IP Address was displayed as follows:

Now, in order to see the LEDs blinking ON and OFF, copy the IP Address that you got from the Serial Monitor of Arduino IDE and paste in your web browser (Google Chrome, Firefox etc) and then the following window will appear.

Now when you press the buttons in your web server you can control both the LEDs.

Play with the program to see how it reacts to different values and logic.

If you make something fun and interesting, do share it with our community.

That’s all for now. If you have any queries, visit surilli.io or contact our support. Stay connected with the Surilli family for more amazing stuff. :-)