Published August 28, 2023 © MIT

A Simple Way to Connect a Small Display to an 8080 Computer

Use a debug serial monitor as a display for the 8080-based computer UT-88 (or any 8080 kit), with less than 80 bytes of "library" code.

BeginnerFull instructions provided1 hour125

A Simple Way to Connect a Small Display to an 8080 Computer

Things used in this project

Hardware components

UT-88 Soviet DIY educational computer

or any 8080/8085/Z80 kit

Mini 0.96 OLED Breadboard Debugging Serial Monitor

14-pin DIP Clip

Solderless Breadboard Half Size

optional

Jumper wires (generic)

Story

(This is an adaptation of my post in LiveJournal (in Russian). Also, a UT-88 computer can be hard to find, but the ideas below can be easily applied to any 8080/8085/Z80 kit, for example, the ones available from Wichit Sirichote. In fact, I was using his 8080 kit to write and debug the code example.)

The UT-88 computer (and its slightly improved version) in its minimal configuration only has a cassette tape recorder, a small keyboard (18 keys), and six seven-segment displays as its 'screen'.

And this is how we can connect a small display to the UT-88 without soldering (see photo).

The idea of using a serial debug monitor as a display for the UT-88 came to me as soon as I saw it on Tindie. The monitor's description claimed that it was sufficient to simply send it characters over the serial line at the speed of 9,600 baud, and they will be displayed on the screen.

The only problem is that the UT-88, in its minimal configuration, doesn't have a serial data transmission port... But wait—how is data recorded onto a cassette tape? Here's the electronic schematic. It turns out that if you send a byte to port A1 (using the OUT A1 instruction), its least significant bit (D0) will appear at the output of the D-type flip-flop DD4.2 (on the schematic)—this is the first step for storing this bit on magnetic tape.

So, all that needs to be done from a hardware perspective is to connect (using the clip for 14-pin ICs):

Pin 7, the ground pin of the К155ТМ2 chip, to the 'GND' pin on the monitor
Pin 14, the power supply pin of the chip, to the 'VCC' pin on the monitor
Pin 9, the Q2 output, to the 'RX' pin on the monitor.

What remains is the software emulation of data transmission through the serial port at the speed of 9,600 baud—a simple 'bit-banging' algorithm. We just need to clarify the exact data transmission protocol. In layman's terms, we simply send a bit 1 ('idle state'), then a bit 0 ('start bit'), followed by the least significant bit (D0) of the byte, then bit D1, and so on up to bit D7, and finally, a bit 1 ('stop bit'). After sending each bit, a fixed time interval must be maintained so that the sent sequence of bits resembles data transmission at the speed of 9,600 baud.

For an example please see the example code (manually assembled).

When you run the program (by pressing the '6' button on the UT-88 keyboard), the display should show 'Vot tak vot!' ('Just like that!').

Why do we arrange a sequence of bytes to send a sequence of bits when, theoretically, we could simply shift the accumulator to the right and send it to port A1 eight times? This is to make sure that the transmission of all 11 bits, including the start and stop bits, is exactly the same. For the same reason, interrupts are disabled during the actual transmission of the sequence.

Sending the zero byte clears the display screen - as in the example at address C007.

Example

address opcode(s)   instruction          comment
-----------------------------------------------------
C000    21 0C C0    LXI     H,VOTTAKVOT  ; address of the string "Vot tak vot!!!" below
C003    CD 00 C2    CALL    PUTS         ; call subroutine to display string on the display
C006    C7          RST     0            ; end of program

CLEAR_SCREEN:
C007    AF          XRA     A            ; zeroing the accumulator
C008    CD 11 C2    CALL    PUTCHAR      ; sending zero byte to clear the display screen
C00B    C9          RET                  ; we could have used JMP instead of CALL followed by RET 

VOTTAKVOT:                               ; string to print on the screen
C00C    56 6F 74 20 DB      'Vot '
C010    74 61 6B 20 DB      'tak '
C014    76 6F 74    DB      'vot'
C017    21 00       DB      '!', 0       ; C-style, i.e., should end with a null byte

PUTS:                                    ; subroutine to display string on display
C200    E5          PUSH    H            ; polite subroutine - saves all used registers
C201    F5          PUSH    PSW
    PUTS_2:
C202    7E          MOV     A,M          ; read string character
C203    B7          ORA     A            ; if zero - end of subroutine
C204    CA 0E C2    JZ      PUTS_3
C207    CD 11 C2    CALL    PUTCHAR      ; otherwise - call subroutine to print a character on the screen
C20A    23          INX     H            ; move to the next string character
C20B    C3 02 C2    JMP     PUTS_2
    PUTS_3:
C20E    F1          POP     PSW
C20F    E1          POP     H
C210    C9          RET

PUTCHAR:                                 ; subroutine to display a character on display
C211    C5          PUSH    B
C212    E5          PUSH    H
C213    F5          PUSH    PSW
                                         ; we need to send a sequence of 11 bits
                                         ; 1, 0, D0, D1, D2, D3, D4, D5, D6, D7, 1
C214    21 42 C2    LXI     H,CHAR_BITS+2; aiming for the third bit (the first and second are always 1 and 0)
C217    0E 08       MVI     C,8          ; the 8 bits of the accumulator are mapped to 8 bytes of the sequence
    PUTCHAR_2:
C219    0F          RRC                  ; shift the least significant bit into the Carry flag
C21A    DA 22 C2    JC      PUTCHAR_3    ; if the least significant bit is one, write a byte of 1 into the sequence
C21D    36 00       MVI     M,0          ; otherwise, write a byte of 0
C21F    C3 24 C2    JMP     PUTCHAR_4
    PUTCHAR_3:
C222    36 01       MVI     M,1
    PUTCHAR_4:
C224    23          INX     H            ; move to the next byte of the sequence
C225    0D          DCR     C
C226    C2 19 C2    JNZ     PUTCHAR_2
                    
C229    21 40 C2    LXI     H,CHAR_BITS ; returning to the beginning of the entire sequence
C22C    06 0B       MVI     B,0B        ; out of 11 bytes

C22E    F3          DI                  ; the transmission of the bit sequence should not be interrupted

  PUTCHAR_5:
C22F    7E          MOV     A,M
C230    D3 A1       OUT     A1          ; the least significant bit of the accumulator will reach the RX pin of the display
C232    CD 50 C2    CALL    DELAY       ; hold a pause after sending each bit
C235    23          INX     H
C236    05          DCR     B
C237    C2 2E C2    JNZ     PUTCHAR_5

C23A    FB          EI
C23B    F1          POP     PSW
C23C    E1          POP     H
C23D    C1          POP     B
C23E    C9          RET

  CHAR_BITS:
C240    01 00 00 00 DB      1,0,0,0     ; sequence of 11 bytes to be sent to port A1
C244    00 00 00 00 DB      0,0,0,0
C248    00 00 01    DB      0,0,1

DELAY:                                  ; "pause" subroutine
C250    0E 08       MVI     C,8         ; "magic" number of idle cycles - 8 ("it works on my machine")
  DELAY_2:
C252    0D          DCR     C
C253    C2 52 C2    JNZ     DELAY_2
C256    C9          RET

Credits

Evgeny Adamenkov

5 projects • 0 followers

game AI/ML programmer

A Simple Way to Connect a Small Display to an 8080 Computer

Things used in this project

Hardware components

Story

Code

Example

Credits

Evgeny Adamenkov

Comments

Embed the widget on your own site

A Simple Way to Connect a Small Display to an 8080 Computer

A Simple Way to Connect a Small Display to an 8080 Computer

Things used in this project

Hardware components

Story

Code

Example

Credits

Evgeny Adamenkov

Comments

Related channels and tags