PWM PeltierTemperature Control Simulation with Qspice

***************************************
* SIMULATION OF MEASURING SYSTEM
* TAMB = AMBIENT TEMPERATURE
* SE = SEEBECK CONSTANT
***************************************
* modified for Qspice 02 oct 2023 from:
*SPICE model of thermoelectric elements including thermal effects
*February 2000Conference Record - IEEE Instrumentation and Measurement Technology Conference 2:1019 - 1023 vol.2
*DOI: 10.1109/IMTC.2000.848895
*SourceIEEE Xplore
*Conference: Instrumentation and Measurement Technology Conference, 2000. IMTC 2000. Proceedings of the 17th IEEEVolume: 2
*********************************
******** THERMAL CIRCUIT ********
*********************************
*** HEAT SINK ***
.subckt PELTIER4 H C I1 I2  Tambient OTC
.param SE=0.05292 Rp=1.806 Tinit=25
.IC V(1)={Tinit+273.15} V(2)={Tinit+273.15} V(3)={Tinit+273.15} V(4)={Tinit+273.15} V(OTC)={Tinit+273.15}
B2 3 0 V=V(Tambient)+273.15
RKRAD 4 3 0.34
CRAD 4 0 340
RSILH 4 1 0.143
*** THERMAL PELTIER MODEL ***
CH 1 0 2
BPE 0 1 I=-I(VPOS)*({RP}*I(VPOS)+{SE}*(V(1)-V(2)))
BPX 2 1 I=I(VPOS)*( {SE}*V(1)-{RP}/2*I(VPOS))
RKM 1 2 1.768
CC 2 0 2
*** THERMAL MASS ***
RSILC OTC 2 0.143
CCONINT OTC 0 304
RCONINT OTC 3 3.1
B3 H 0 V=V(4)-273.15
B4 C 0 V=V(OTC)-273.15
************************************
******** ELECTRICAL CIRCUIT ********
************************************
*** ELECTRICAL PELTIER MODEL ***
VPOS I1 13 0
RM 13 12 {Rp}
BALPHA 12 I2 V={SE}*(V(1)-V(2))
.ENDS
*****************************************