Simulate accurately your NTCLE317E4103SBA temp. accuracy

* Copyright : Vishay Intertechnology 2020
* Voltage_driven_thermistor
*
* customer : general
* $Revision:   1.0  $
* $Author:   Alain Stas  $
* $Date:   17 May 2020 $
* $Revision History :correction <> introduced
*---------------------------------------------------------------
*$
* concerned data sheet : http://www.vishay.com/docs/29216/ntcle317e4103sba.pdf
* modeled properties: self heating, Monte Carlo tolerance on temp. accuracy =+/-0.5°C between 25 and 85°C
* and according to R_T table outside of this range
* R-T nominal curve according to modified Steinhart and Hart equation (third power of 1/T)
* For simulation, connect a voltage source (external temperature) to the Ti pin via an RC network (R*C being equal to the response time in the
* used medium (0.8 s in stirred oil , 3 s in stirred air or else)
*
*                pin1
*                 | pin2
*                 |  | Temperature
*                 |  | |
.SUBCKT NTC_BASE RN Rp Ti Params: W=1 X=1 Y=1 Z=1 GTH=1 GTH1=1 CTH=1 A=1 R25=1 B=1 C=1 D=1 T0=273.15
*
R1 Vtol 0 R={mc(1,1)-1}
I1 Vtol 0 1
R2 TOL2 0 R=table(V(Ti),-55,4.7,-30,3.74,0,2.82,25,2.19,45,1.96,65,1.76,85,1.59,100,1.84,125,2.15,155,2.45)*V(Vtol)
I2 TOL2 0 1
*
G_G1         AOUT 0 VALUE { if(V(Ti)>25,V(AOUT,
+  0)/(R25*(1+V(TOL2)/100)*exp(((D/(T0+abs(V(H))+V(Ti))+C)/(T0+abs(V(H))+V(Ti))+B)/(T0+V(Ti)+abs(V(H)))+A)),0)
+  }
G_G2         AOUT 0 VALUE { IF(V(Ti)>25,0,V(AOUT,
+  0)/(R25*(1+V(TOL2)/100)*exp(((Z/(T0+abs(V(H))+V(Ti))+Y)/(T0+abs(V(H))+V(Ti))+X)/(T0+abs(V(H))+V(Ti))+W)))
+  }
G_G3         H 0 VALUE {
+  if(V(Ti)>25,-V(RP,RN)*V(RP,RN)/(R25*(1+V(TOL2)/100)*exp(((D/(T0+abs(V(H))+V(Ti))+C)/(T0+abs(V(H))+V(Ti))+B)/
+  (T0+V(Ti)+abs(V(H)))+A)),0)}
G_G4         H 0 VALUE {
+  if(V(Ti)>25,0,-V(RP,RN)*V(RP,RN)/(R25*(1+V(TOL2)/100)*exp(((Z/(T0+abs(V(H))+V(Ti))+Y)/(T0+abs(V(H))+V(Ti))+X)/
+  (T0+V(Ti)+abs(V(H)))+W)))}
G_G5         RP RN VALUE { V(RP, RN)/V(AOUT) }
G_G6         H 0 VALUE { V(H)*(Gth + Gth1*(V(Ti)-25)) }
I_I1         0 AOUT DC 1Adc
R_R1         0 AOUT  1T TC=0,0
R_R2         0 H  1T TC=0,0
C_C1         0 H  {Cth}
R_R99        0 Ti 1T
.IC V(H) =0
.ENDS
*$
.SUBCKT NTCLE317E4103SBA RN Rp Ti
X01 RN Rp Ti NTC_BASE Params:
+ w=-14.6571976
+ x=4798.842
+ y=-115334
+ z=-3730535
+ gth=0.0008 gth1 = 0.000006
+ cth=0.0035
+ a=-14.65719769
+ r25=10000
+ b=4798.842
+ c=-115334
+ d=-3730535
+ T0=273.15
.ENDS