Spice Modeling of a Peltier Cooled "Laser" with thermistor

***************************************
* SIMULATION OF MEASURING SYSTEM
* TAMB = AMBIENT TEMPERATURE
* SE = SEEBECK CONSTANT
***************************************
*modified from:
*SPICE model of thermoelectric elements including thermal effects
*February 2000Conference Record - IEEE Instrumentation and Measurement Technology *Conference 2:1019 - 1023 vol.2
*DOI: 10.1109/IMTC.2000.848895
*SourceIEEE Xplore
*Conference: Instrumentation and Measurement Technology Conference, 2000. IMTC *2000. Proceedings of the 17th IEEEVolume: 2
*********************************
******** THERMAL CIRCUIT ********
*********************************
*** HEAT SINK ***
.subckt PELTIER4 H C I GND Tambient OTC
.param SE=0.05292, RM=1.806 Rp=2
.IC V(1)={Tinit+273.15} V(2)={Tinit+273.15} V(3)={Tinit+273.15} V(4)={Tinit+273.15} V(OTC)={Tinit+273.15}
ETAMB 3 GND value={V(Tambient)+273.15}
RKRAD 4 3 0.34
CRAD 4 GND 340
RSILH 4 1 0.143
*** THERMAL PELTIER MODEL ***
CH 1 GND 50
GPE GND 1 VALUE={I(VPOS)*(I(VPOS)*RP+SE*
+(V(1)-V(2)))}
RKM 1 2 1.768
GPX 2 1 VALUE={I(VPOS)*
+(SE*V(2)-0.9*I(VPOS))}
CC 2 GND 50
*** THERMAL MASS ***
RSILC OTC 2 0.143
CCONINT OTC GND 304
RCONINT OTC 3 3.1
ETH GND H VALUE={-V(4)+273.15}
ETC GND C VALUE={-V(OTC)+273.15}
************************************
******** ELECTRICAL CIRCUIT ********
************************************
*** ELECTRICAL PELTIER MODEL ***
VPOS I 13 DC 0
RM 13 12 1.8
EALPHA 12 GND VALUE = {SE*(V(1)-V(2))}
.END
*****************************************