Fridgechat

Project Demo

Description

The kitchen is undeniably a place of social gathering. In most households, a variety of social interactions happen in the kitchen as we prepare and consume food. The fridge is particularly central, as it holds not only consumables inside, but memories on its exterior, in the form of photographs and mementos.  We wanted to explore the idea of sound as a memento, and designed Fridgechat, a simple device that stays on the fridge door like any other magnet. Using a photoresistor, we can determine if the fridge door is open or closed. When the door is opened, it will play one of several queued message recordings. After the door has been closed, several seconds of ambient noise will be recorded and queued for future listening. In this way, Fridgechat becomes a time capsule, capturing sound bites of current events in the kitchen.

Observational Process

We began our observational process by spending time in our respective kitchens, tracking tasks we did, how we did them, tools we used, and interactions we had with others. After a few days, we spent a few hours brainstorming ideas and picking out topics that we found particularly interesting, for further independent study in our own kitchens once again.

Other ideas we considered were related to sorting garbage and recycling, or monitoring who did and who didn't wash dishes in the sink. We were all also interested in was the social nature of the kitchen. We considered ways to make dish cleaning fun and social, by diffracting light through water. We also played with various fridge magnet ideas, starting with music generation and moving towards a voicemail, where each member of the household had their own magnet and could record messages for one another.

Thinking of the fridge as a central social hub in the kitchen, we worked out various magnet ideas, thinking about notes that we leave for roommates and family members, photographs, clippings, and other miscellaneous items that tend to be kept on the fridge. 

Kitchen Exploration

Design Process

We sketched out many different ideas around social magnets, and eventually settled on interaction with opening and closing the fridge door--a common event for anyone actively using the kitchen. We decided against having a music maker: though it would encourage creativity in household members, it didn't allow for multiple threads. We also decided against having magnets for each individual person, since it seemed inflexible--what if somebody moved out? 

Recording ambient noise to play back later combines the right amount of unintentional interaction with social time shifting, so others can hear things that happened earlier. 

A basic box would hold our circuitry, speaker, and VoiceShield. We also wanted to give some indication of when the box was recording, using an LED display and a loud beep (which was very annoying and was removed). We then changed the basic LED display to be a bottom-lit etched plastic sign of a microphone.

Sketches

Prototype

Wiring Diagram

Code

#include <Wtv020sd16p.h>
#include <ISD.h>

//PINS
// As usual, we'll create constants to name the pins we're using.
// This will make it easier to follow the code below.

const int lightSensingPin = A0;

const int ledPin = 7;

// record/playback module
const int recordPlaybackPin = A1;
const int msgPins[] = {A5, A4, A3, A2};
const int numMsgs = 1;

int currentMsgToPlay, currentMsgToRecord;

// Light sensor threshold
// TODO: Fine tune magnitude by experimentation
const int LIGHT_THRESHOLD = 160;

// Record and playback length
const int RECORD_LENGTH = 5000;


// Internal State
enum State {
  IDLE_STATE,
  PLAYBACK,
  FINISHED_PLAYBACK,
  RECORD
} state;

long stateBeginTime;

void setup()
{
  // Set up Serial. We will print out debugging messages through Serial.
  Serial.begin(9600); 
  Serial.println("setup");

  // Initialize pin modes
  pinMode(lightSensingPin, INPUT);
  pinMode(ledPin, OUTPUT);
  digitalWrite(ledPin, LOW);
  pinMode(recordPlaybackPin, OUTPUT);
  digitalWrite(recordPlaybackPin, LOW);
  for (int i = 0; i < numMsgs; i++) {
    pinMode(msgPins[i], OUTPUT);
    digitalWrite(msgPins[i], HIGH);
  }
  currentMsgToPlay = 0;
  currentMsgToRecord = 0;
  
  // Initialize state
  state = IDLE_STATE;
}


void loop()
{
  int lightLevel = analogRead(lightSensingPin); 
  long currentTime = millis();

  // Check if we need to transition to a new state. If so, do state-based behavior.
  switch (state) {
    // IDLE_STATE: nothing is happening currently.
    case IDLE_STATE:
      // Check the light sensor to see if the fridge was opened
      if (lightLevel > LIGHT_THRESHOLD){
        // The fridge was opened
        Serial.println("Fridge Opened.");
        handleFridgeOpenedEvent();
        // Update state
        state = PLAYBACK;
        stateBeginTime = currentTime;
      }
    break;

    // PLAYBACK: The recorded message is being played back currently.
    case PLAYBACK:
      // Check to see if the playback finished
      if (currentTime - stateBeginTime > RECORD_LENGTH) {
        // The playback finished
        Serial.println("Playback finished.");
        handlePlaybackFinishedEvent();
        // Update state
        state = FINISHED_PLAYBACK;
        stateBeginTime = currentTime;
      }
    break;

    // FINISHED_PLAYBACK: The recorded message finished playing. The fridge is still open currently.
    case FINISHED_PLAYBACK:
      // Check the light sensor to see if the fridge was closed
      if (lightLevel <= LIGHT_THRESHOLD) {
        // The fridge was closed
        Serial.println("Fridge Closed.");
        handleFridgeClosedEvent();
        // Update state
        state = RECORD;
        stateBeginTime = currentTime;
      }
    break;

    // RECORD: The device is currently recording.
    case RECORD:
      // Check to see if the recording time elapsed.
      if (currentTime - stateBeginTime > RECORD_LENGTH) {
        Serial.println("Record finished.");
        handleRecordFinishedEvent();
        // Update state
        state = IDLE_STATE;
        stateBeginTime = currentTime;
      }
    break;
  }
}


void handleFridgeOpenedEvent(){
  playback();
}


void handlePlaybackFinishedEvent(){
  digitalWrite(msgPins[currentMsgToPlay % numMsgs], HIGH);
  currentMsgToPlay = currentMsgToPlay + 1;
}


void handleFridgeClosedEvent(){
  record();
  digitalWrite(ledPin, HIGH);  
}


void handleRecordFinishedEvent(){
  digitalWrite(msgPins[currentMsgToRecord % numMsgs], HIGH);
  digitalWrite(ledPin, LOW);
  currentMsgToRecord = currentMsgToRecord + 1;
}


void record(){
  Serial.print("Recording msg ");
  Serial.println(currentMsgToRecord % numMsgs);
  // To record, set record/playback pin low, then select message by setting message pin low
  digitalWrite(recordPlaybackPin, LOW);
  digitalWrite(msgPins[currentMsgToRecord % numMsgs], LOW);
}


void playback(){
  Serial.print("Playing msg ");
  Serial.println(currentMsgToPlay % numMsgs);
  // To playback, set record/playback pin high, then select message by setting message pin low
  digitalWrite(recordPlaybackPin, HIGH);
  digitalWrite(msgPins[currentMsgToPlay % numMsgs], LOW);
}

Instructions

Electronics:
Follow the wiring diagram. 

To add lighting lighting, attach 3-6 white LEDs in parallel (each with some resistance in serial) to pin 7 and ground.

Code:
Upload the code in the code widget.Tune the LIGHT_THRESHOLD constant so that it correctly detects when the fridge is opened and closed.

The code is set up as a state machine. Each time the state changes, new behavior occurs based on the handle...Event() function called. The code is set up to begin playback when the fridge is opened, then record with LEDs lit up when the fridge is closed.

Assembly Instructions

• download fridgebox2.ai" and "screen.ai"
• add holes to the faces of the box and the screen to fit your corner brace length.
• laser cut box on grey acrylic
• assemble box by joining sides with corner braces + machine screws + nuts. (on the front side, join the glass + acrylic
• put the electronics in the box
• hot glue 3-6 LEDs in the bottom of the screen, depending on your lighting preference 
• we added a scrap piece of grey acrylic to the bottom to cover up the LEDs. If you do, cover the back with electronic tape to keep the LEDs from shining through. 

Presentation Link

https://docs.google.com/presentation/d/1r5noiT_PKGq9Yr37Q7uAOBICgA1-pFyoyb3DLwDXoQY/edit#slide=id.g2...

Laser Files