Cat Tracker with Linkit One

// including a bunch of libraries
#include <HttpClient.h>
#include <LTask.h>
#include <LWiFi.h>
#include <LWiFiClient.h>
#include <LDateTime.h>

// Set Connection settings
#define WIFI_AP "IT Portable Hotspot" // Put in your home wifi name
#define WIFI_PASSWORD "12345678"      // Put in your password
#define WIFI_AUTH LWIFI_WPA  // choose from LWIFI_OPEN, LWIFI_WPA, or LWIFI_WEP.
#define per 50                        // leave this setting
#define per1 3                        // leave this setting
#define DEVICEID "********"           // Input your deviceId from MediaTek
#define DEVICEKEY "***************"   // Input your deviceKey from MediaTek
#define SITE_URL "api.mediatek.com"   // leave this setting (because we are using MediaTek)

LWiFiClient c;          // This sets the wifi client variable for exchanging data
unsigned int rtc;       
unsigned int lrtc;
unsigned int rtc1;
unsigned int lrtc1;
char port[4]={0};
char connection_info[21]={0};
char ip[21]={0};             
int portnum;
int val = 0;
String tcpdata = String(DEVICEID) + "," + String(DEVICEKEY) + ",0";
String upload_led;    // This is what is modified and sent to the sandbox
String tcpcmd_led_on = "LED_Control,1";
String tcpcmd_led_off = "LED_Control,0";

LWiFiClient c2;       // This is the other wifi client variable
HttpClient http(c2);  // setup the HttpClient using c2

///////////////////// setup ///////////////////////
void setup()
{
  
  LTask.begin();
  LWiFi.begin();
  Serial.begin(115200);   // HTTP requires a much higher than 9600 baud rate
  while(!Serial) delay(1000); /* comment out this line when Serial is not present, ie. run this demo without connect to PC */

  Serial.println("Connecting to AP");   // Tell the user that the it is going to try connecting
  while (0 == LWiFi.connect(WIFI_AP, LWiFiLoginInfo(WIFI_AUTH, WIFI_PASSWORD)))
  {
    delay(1000);    // if it can't connect to the wifi then it'll just keep waiting until it connects
  }

  // After it is done waiting it'll tell the user that it's going to start connecting
  Serial.println("calling connection");

  while (!c2.connect(SITE_URL, 80))
  {
    Serial.println("Re-Connecting to WebSite");
    delay(1000);  // if it can't connect to the website then it'll just keep waiting until it does
  }
  delay(100);     // this delay is just to make sure that the arduino doesn't freak out

  pinMode(13, OUTPUT);  // pin 13 on the arduino is typically the onboard LED
  getconnectInfo();     // Go to the function getconnectInfo()
  connectTCP();         // Go to the function connectTCP()
}

void getconnectInfo(){
  //calling RESTful API to get TCP socket connection
  // This is pretty straight forward, it sends information to the HTTP setup 
  // and the println() at the end is the confirmation to say that we are done
  // transmitting
  c2.print("GET /mcs/v2/devices/");
  c2.print(DEVICEID);
  c2.println("/connections.csv HTTP/1.1");
  c2.print("Host: ");
  c2.println(SITE_URL);
  c2.print("deviceKey: ");
  c2.println(DEVICEKEY);
  c2.println("Connection: close");
  c2.println();

  // wait a little bit to hear back on how we did
  delay(500);

  // we print the number of errors up to 10 if we don't hear back positively
  int errorcount = 0;
  while (!c2.available())
  {
    Serial.println("waiting HTTP response: ");
    Serial.println(errorcount);
    errorcount += 1;
    if (errorcount > 10) {
      c2.stop();
      return;
    }
    delay(100);
  }
  int err = http.skipResponseHeaders();

  // bodyLen is used (as far as I understand it) a check on whether the information was transmitted correctly
  int bodyLen = http.contentLength();
  Serial.print("Content length is: ");
  Serial.println(bodyLen);
  Serial.println();
  char c;
  int ipcount = 0;
  int count = 0;
  int separater = 0;
  while (c2)
  {
    int v = c2.read();
    if (v != -1)
    {
      c = v;
      Serial.print(c);
      connection_info[ipcount]=c;
      if(c==',')
      separater=ipcount;
      ipcount++;    
    }
    else
    {
      Serial.println("no more content, disconnect");
      c2.stop();

    }
    
  }
  Serial.print("The connection info: ");
  Serial.println(connection_info);
  int i;
  for(i=0;i<separater;i++)
  {  ip[i]=connection_info[i];
  }
  int j=0;
  separater++;
  for(i=separater;i<21 && j<5;i++)
  {  port[j]=connection_info[i];
     j++;
  }
  Serial.println("The TCP Socket connection instructions:");
  Serial.print("IP: ");
  Serial.println(ip);
  Serial.print("Port: ");
  Serial.println(port);
  portnum = atoi (port);
  Serial.println(portnum);

} //getconnectInfo

void uploadstatus(){
  //calling RESTful API to upload datapoint to MCS to report LED status
  // This basically uploads the information that we want to transmit back to the MediaTek sandbox
  Serial.println("calling connection");
  LWiFiClient c2;  

  while (!c2.connect(SITE_URL, 80))
  {
    Serial.println("Re-Connecting to WebSite");
    delay(1000);    // I wait until I've connected
  }
  delay(100);
  if(digitalRead(13)==1)    // if the onboard pin (13) is high then transmit the string "LED_Display,,1"
  upload_led = "LED_Display,,1";    // the structure is "VariableFromMediaTek,,Value"
  else
  upload_led = "LED_Display,,0";
  int thislength = upload_led.length();   // I get the length of the upload_led
  HttpClient http(c2);                    
  c2.print("POST /mcs/v2/devices/");      // I start sending information to the website (which I verified worked above)
  c2.print(DEVICEID);                     // I send the deviceID to specify where to send the data
  c2.println("/datapoints.csv HTTP/1.1");
  c2.print("Host: ");
  c2.println(SITE_URL);                  
  c2.print("deviceKey: ");
  c2.println(DEVICEKEY);                  // The Devicekey is used from MediaTek to identify the specific device
  c2.print("Content-Length: ");
  c2.println(thislength);                 // thislength is used as a check (it would appear) to verify the data got sent correctly
  c2.println("Content-Type: text/csv");
  c2.println("Connection: close");
  c2.println();
  c2.println(upload_led);                 // this is the important information that needs to be send
  
  delay(500);

  // Now I verify that I didn't get any errors back
  int errorcount = 0;
  while (!c2.available())
  {
    Serial.print("waiting HTTP response: ");
    Serial.println(errorcount);
    errorcount += 1;
    if (errorcount > 10) {
      c2.stop();
      return;
    }
    delay(100);
  }
  int err = http.skipResponseHeaders();

  int bodyLen = http.contentLength();
  Serial.print("Content length is: ");
  Serial.println(bodyLen);
  Serial.println();
  while (c2)
  {
    int v = c2.read();
    if (v != -1)
    {
      Serial.print(char(v));
    }
    else
    {
      Serial.println("no more content, disconnect");
      c2.stop();

    }
    
  }
}



void connectTCP(){
  //establish TCP connection with TCP Server with designate IP and Port
  c.stop();
  Serial.println("Connecting to TCP");
  Serial.println(ip);
  Serial.println(portnum);
  while (0 == c.connect(ip, portnum))
  {
    Serial.println("Re-Connecting to TCP");    
    delay(1000);
  }  
  Serial.println("send TCP connect");
  c.println(tcpdata);
  c.println();
  Serial.println("waiting TCP response:");
} //connectTCP

void heartBeat(){
  Serial.println("send TCP heartBeat");
  c.println(tcpdata);
  c.println();
    
} //heartBeat

void loop()
{
  //Check for TCP socket command from MCS Server 
  String tcpcmd="";
  while (c.available())
   {
      int v = c.read();
      if (v != -1)
      {
        Serial.print((char)v);
        tcpcmd += (char)v;
        if (tcpcmd.substring(40).equals(tcpcmd_led_on)){
          digitalWrite(13, HIGH);
          Serial.print("Switch LED ON ");
          tcpcmd="";
        }else if(tcpcmd.substring(40).equals(tcpcmd_led_off)){  
          digitalWrite(13, LOW);
          Serial.print("Switch LED OFF");
          tcpcmd="";
        }
      }
   }

  LDateTime.getRtc(&rtc);
  if ((rtc - lrtc) >= per) {
    heartBeat();
    lrtc = rtc;
  }
  //Check for report datapoint status interval
  LDateTime.getRtc(&rtc1);
  if ((rtc1 - lrtc1) >= per1) {
    uploadstatus();
    lrtc1 = rtc1;
  }
  
}