WiFi NodeMCU ESP8266 Google Clock

// V.3 - Date converted to a number and daylight saving time calculation
// V.4 - Localized date
// V.6 - Temperature and humidity
// V.7 - Corrected animated clock + seconds +1.5
// V.8 - Calibration of thermometer and hygrometer
// V.9 - Corrected daylight saving time
// V.10 - Corrected date change at 00:00 -> May 4, 2020
// V.11 - Corrected daylight saving time for last Sundays
// V.12 - Code optimized and commented

#include "Arduino.h"
#include <ArduinoJson.h>
#include <ESP8266WiFi.h> // ESP8266 Core WiFi Library

WiFiClient client;

#define NUM_MAX 6

// for NodeMCU 1.0
#define DIN_PIN 13  // D7
#define CS_PIN  15  // D8
#define CLK_PIN 14  // D5

#include "max7219.h"
#include "fonts.h"

#include "DHT.h" // DHT sensor

// DHT sensor
#define DHTPIN 12  // GPIO 12 = D6
#define DHTTYPE DHT22   // DHT 22  (AM2302)

DHT dht(DHTPIN, DHTTYPE, 11); // for ESP8266

// DHT data
float temperature = 0;
int temp = 0;
byte minus = 0;
int humidity = 0;
int poz, poz2;
int mult = 0;

float temp_offset = -1.04; // Thermometer calibration
float rh_offset = +1;      // Hygrometer calibration

char TempLabel[] = "    Temperatura:  "; // Fixed text
char UmiLabel[] = "    Umidita':  ";    // Fixed text

// Test IP modification
const char ssid[] = "XXXXXXXX";  // Your network SSID
const char password[] = "XXXXXXXX"; // Your network password

// Localized months and days of the week
//String M_arr[13] = {" ", "January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December"};
//String Dow_arr[8] = {" ", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday", "Sunday"};

String M_arr[13] = {" ", "Gennaio", "Febbraio", "Marzo", "Aprile", "Maggio", "Giugno", "Luglio", "Agosto", "Settembre", "Ottobre", "Novembre", "Dicembre"};
String Dow_arr[8] = {" ", "Lunedi", "Martedi", "Mercoledi", "Giovedi", "Venerdi", "Sabato", "Domenica"};

void setup() 
{
  Serial.begin(115200);

  initMAX7219();
  sendCmdAll(CMD_SHUTDOWN, 1);
  sendCmdAll(CMD_INTENSITY, 1); // Brightness from 1 to 5

  Serial.print("Connecting to ");
  Serial.println(ssid);
  
  WiFi.begin(ssid, password);

  printStringWithShift("Connecting", 30);
  delay(1000);
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.print("IP number assigned by DHCP is ");
  Serial.println(WiFi.localIP());

  printStringWithShift((String("  IP:") + WiFi.localIP().toString()).c_str(), 30);
  delay(1000);

  // DHT initialization
  dht.begin();
  temperature = dht.readTemperature();
  humidity = dht.readHumidity();

  Serial.print(temperature);
  Serial.println(" C");

  Serial.print(humidity);
  Serial.println(" %RH");

  if (temperature < 0) {
    temp = -10 * temperature;
    minus = 1;
  } else {
    minus = 0;
    temp = 10 * temperature;
  }
}

// =============================DEFINE VARS==============================
#define MAX_DIGITS 20
byte dig[MAX_DIGITS] = {0};
byte digold[MAX_DIGITS] = {0};
byte digtrans[MAX_DIGITS] = {0};
int updCnt = 0;
int dots = 0;
long dotTime = 0;
long clkTime = 0;
int dx = 0;
int dy = 0;
byte del = 0;
int h, m, s;
float utcOffset = +1; // Your timezone
long localEpoc = 0;
long localMillisAtUpdate = 0;
int day, month, year, dayOfWeek;
int monthnum = 0;
int downum = 0;
int summerTime = 0;
String date; 
String dayloc; 
String monthloc; 

// =======================================================================

void loop()
{
  if (updCnt <= 0) { // Every 10 scrolls, ~450s = 7.5m
    updCnt = 60;
    Serial.println("Getting data ...");
    printStringWithShift("   Get Time...", 30);
    getTime();
    Serial.println("Data loaded");
    clkTime = millis();
  }

  contrast(); // Auto-brightness

  // Print data
  if (millis() - clkTime > 30000 && !del && dots) { // Clock for 30s, then scrolls for about 30s
    printStringWithShift("            ", 30);  // Space before
    printStringWithShift(date.c_str(), 30);    // Date

    // Reading temperature and humidity 
    int humidity = dht.readHumidity();
    float temperature = dht.readTemperature(); 
    
    humidity = humidity + rh_offset;
    temperature = temperature + temp_offset;
    
    Serial.println("Corrected Temp and Humidity");
    Serial.println(temperature);
    Serial.println(humidity);
    
    int t2 = 10 * temperature; 

    // Print temperature
    char c[3], d[2]; 
    String str1, str2;
    int t2z = t2 / 10;
    int t2u = t2 - t2z * 10;
    str1 = String(t2z);
    str1.toCharArray(c, 3);
    str2 = String(t2u);
    str2.toCharArray(d, 2);
    printStringWithShift(TempLabel, 30);  // Send scrolling text
    printStringWithShift("+", 30);
    printStringWithShift(c, 30);
    printStringWithShift(",", 30);
    printStringWithShift(d, 30);
    printStringWithShift(" C^", 30);

    // Print humidity
    char b[3];
    String str;
    str = String(humidity);
    str.toCharArray(b, 3);
    printStringWithShift(UmiLabel, 30);  // Send scrolling text
    printStringWithShift(b, 30);
    printStringWithShift(" %", 30);
    
    printStringWithShift("                 ", 30);  // Space after
    delay(200);

    updCnt--;
    clkTime = millis();
  }
  
  if (millis() - dotTime > 500) {
    dotTime = millis();
    dots = !dots;
  }
  updateTime(); // Get time

  // Print clock
  showAnimClock();
}

// =======================================================================

void showSimpleClock()
{
  dx = dy = 0;
  clr();
  showDigit(h / 10,  0, dig6x8);
  showDigit(h % 10,  8, dig6x8);
  showDigit(m / 10, 17, dig6x8);
  showDigit(m % 10, 25, dig6x8);
  showDigit(s / 10, 34, dig6x8);
  showDigit(s % 10, 42, dig6x8);
  setCol(15, dots ? B00100100 : 0);
  setCol(32, dots ? B00100100 : 0);
  refreshAll();
}

// =======================================================================

void showAnimClock()
{
  byte digPos[6] = {0, 8, 17, 25, 34, 42};
  int digHt = 12;
  int num = 6; 
  int i;
  
  if (del == 0) {
    del = digHt;
    for (i = 0; i < num; i++) digold[i] = dig[i];
    dig[0] = h / 10 ? h / 10 : 10;
    dig[1] = h % 10;
    dig[2] = m / 10;
    dig[3] = m % 10;
    dig[4] = s / 10;
    dig[5] = s % 10;
    for (i = 0; i < num; i++) digtrans[i] = (dig[i] == digold[i]) ? 0 : digHt;
  } else {
    del--;
  }
  
  clr();
  for (i = 0; i < num; i++) {
    if (digtrans[i] == 0) {
      dy = 0;
      showDigit(dig[i], digPos[i], dig6x8);
    } else {
      dy = digHt - digtrans[i];
      showDigit(digold[i], digPos[i], dig6x8);
      dy = -digtrans[i];
      showDigit(dig[i], digPos[i], dig6x8);
      digtrans[i]--;
    }
  }
  dy = 0;
  setCol(15, dots ? B00100100 : 0);
  setCol(32, dots ? B00100100 : 0);
  refreshAll();
  delay(10); // Default 30
}

// =======================================================================

void showDigit(char ch, int col, const uint8_t *data)
{
  if (dy < -8 || dy > 8) return;
  int len = pgm_read_byte(data);
  int w = pgm_read_byte(data + 1 + ch * len);
  col += dx;
  for (int i = 0; i < w; i++)
    if (col + i >= 0 && col + i < 8 * NUM_MAX) {
      byte v = pgm_read_byte(data + 1 + ch * len + 1 + i);
      if (!dy) scr[col + i] = v; else scr[col + i] |= dy > 0 ? v >> dy : v << -dy;
    }
}

// =======================================================================

void setCol(int col, byte v)
{
  if (dy < -8 || dy > 8) return;
  col += dx;
  if (col >= 0 && col < 8 * NUM_MAX)
    if (!dy) scr[col] = v; else scr[col] |= dy > 0 ? v >> dy : v << -dy;
}

// =======================================================================

int showChar(char ch, const uint8_t *data)
{
  int len = pgm_read_byte(data);
  int w = pgm_read_byte(data + 1 + ch * len);
  for (int i = 0; i < w; i++)
    scr[NUM_MAX * 8 + i] = pgm_read_byte(data + 1 + ch * len + 1 + i);
  scr[NUM_MAX * 8 + w] = 0;
  return w;
}

// =======================================================================

// Function to print characters with shift
void printCharWithShift(unsigned char c, int shiftDelay) {
  if (c < ' ' || c > '~'+25) return;
  c -= 32;
  int w = showChar(c, font);
  for (int i = 0; i < w + 1; i++) {
    delay(shiftDelay);
    scrollLeft();
    refreshAll();
  }
}

// =======================================================================

void printStringWithShift(const char* s, int shiftDelay) {
  while (*s) {
    printCharWithShift(*s, shiftDelay);
    s++;
  }
}

// =======================================================================

void getTime()
{
  WiFiClient client;
  if (!client.connect("www.google.com", 80)) {
    Serial.println("Connection to Google failed");
    return;
  }

  client.print(String("GET / HTTP/1.1\r\n") +
               String("Host: www.google.com\r\n") +
               String("Connection: close\r\n\r\n"));
  int repeatCounter = 0;
  while (!client.available() && repeatCounter < 10) {
    delay(500);
    repeatCounter++;
  }

  String line;
  client.setNoDelay(false);
  while (client.connected() && client.available()) {
    line = client.readStringUntil('\n');
    line.toUpperCase();
    if (line.startsWith("DATE: ")) {
      date = line.substring(6, 22);
      date.toUpperCase();

      Serial.println(date); // Check

      int day = atoi(date.substring(5, 7).c_str()); // Day number
      int year = 2000 + atoi(date.substring(13, 16).c_str()); // Year number

      monthnum = month2index(date.substring(8, 11)); // Convert month to number
      month = monthnum;

      downum = dow2index(date.substring(0, 3)); // Convert day of week to number
      dayOfWeek = downum;

      Serial.println(day); // Check
      Serial.println(month); // Check
      Serial.println(year); // Check
      Serial.println(dayOfWeek); // Check

      monthloc = M_arr[month]; // Localize month
      dayloc = Dow_arr[dayOfWeek]; // Localize day of week

      date = dayloc + " " + day + " " + monthloc + " " + year;
      Serial.println(date); // Check

      h = line.substring(23, 25).toInt();
      m = line.substring(26, 28).toInt();
      s = line.substring(29, 31).toInt() + 1.5; // Correct time

      // Calculate daylight saving time (DST)
      if (month > 3 && month < 10) {
        summerTime = 1; // Between April and September is always DST
      } else if (month == 3) {
        if (day >= 31 - (((5 * year / 4) + 4) % 7)) {
          summerTime = 1; // DST starts on the last Sunday of March
        }
      } else if (month == 10) {
        if (day < 31 - (((5 * year / 4) + 1) % 7)) {
          summerTime = 0; // DST ends on the last Sunday of October
        }
      }

      Serial.print("Summertime: ");
      Serial.println(summerTime);

      if (h + utcOffset + summerTime > 23) {
        h = h - 24;
        dayOfWeek = (dayOfWeek % 7) + 1;
        day += 1;
        // Check for month and year rollover
        unsigned short Tage_Monat[12] = { 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31 };
        if (day > Tage_Monat[month - 1]) {
          day = 1;
          month += 1;
          if (month > 12) {
            month = 1;
            year += 1;
          }
        }
      }

      monthloc = M_arr[month]; // Localize month
      dayloc = Dow_arr[dayOfWeek]; // Localize day of week
      date = dayloc + ",   " + day + " " + monthloc + " " + year;
      Serial.println(date); // Check

      localMillisAtUpdate = millis();
      localEpoc = (h * 60 * 60 + m * 60 + s);
    }
  }
  client.stop();
}

// =======================================================================

// Convert month string to month number
int month2index(String month)
{
  String months[12] = {"JAN", "FEB", "MAR", "APR", "MAY", "JUN", "JUL", "AUG", "SEP", "OCT", "NOV", "DEC"};
  for (int i = 0; i < 12; i++) {
    if (months[i] == month)
      return i + 1;
  }
  return 0;
}

// =======================================================================

// Convert day of week string to day number
int dow2index(String dayOfWeek)
{
  String dows[7] = {"MON", "TUE", "WED", "THU", "FRI", "SAT", "SUN"};
  for (int i = 0; i < 7; i++) {
    if (dows[i] == dayOfWeek)
      return i + 1;
  }
  return 0;
}

// =======================================================================

void updateTime()
{
  long curEpoch = localEpoc + ((millis() - localMillisAtUpdate) / 1000);
  long epoch = round(curEpoch + 3600 * (utcOffset + summerTime) + 86400L);
  h = ((epoch % 86400L) / 3600) % 24;
  m = (epoch % 3600) / 60;
  s = epoch % 60;
}

// =======================================================================

void contrast()
{
  int brightness = analogRead(A0);  // Auto-brightness (+3.3V ---|==10k==|---A0---|GND)
  brightness = map(brightness, 0, 1023, 0, 4);  // Brightness 0-4
  sendCmdAll(CMD_INTENSITY, brightness);
}