Plotting IMU data on artik cloud

#include <WiFi.h>
#include <Wire.h>
#include <ArduinoJson.h>

#define MPU6050_ADDR  0x68
#define PWR_MGMT_1    0x6B
#define ACCEL_XOUT_H  0x3B

char server[] = "api.artik.cloud";  
int port = 443;

String AuthorizationData = "Authorization: _DEVICE_TOKEN_";

WiFiClient client;
char ssid[] = "xxxxx";
char pass[] = "xxxxx";
int status;

char buf[200];

void MPU_wakeup(void)
{
    Wire.begin();
    Wire.beginTransmission(MPU6050_ADDR);
    Wire.write(PWR_MGMT_1);
    Wire.write(0);
    Wire.endTransmission(true);
}


int MPU_read_values(void)
{
    StaticJsonBuffer<200> jsonBuffer; // reserve spot in memory

    JsonObject& root = jsonBuffer.createObject(); // create root objects
    root["sdid"] = "<Device id>";
    root["type"] = "message";

    JsonObject& dataPair = root.createNestedObject("data"); // create nested objects
    Wire.beginTransmission(MPU6050_ADDR);
    Wire.write(ACCEL_XOUT_H);
    Wire.endTransmission(false);
    Wire.requestFrom(MPU6050_ADDR,14,true);  // request a total of 14 registers
  
    dataPair["ACCEL_X"] = (Wire.read() << 8 | Wire.read());
    dataPair["ACCEL_Y"] = (Wire.read() << 8 | Wire.read());
    dataPair["ACCEL_Z"] = (Wire.read() << 8 | Wire.read());

    dataPair["TEMP"] = ((((double)(Wire.read() << 8 | Wire.read())) / 340.00) + 36.53);

    dataPair["GYRO_X"] = (Wire.read() << 8 | Wire.read());
    dataPair["GYRO_Y"] = (Wire.read() << 8 | Wire.read());
    dataPair["GYRO_Z"] = (Wire.read() << 8 | Wire.read());

    root.printTo(buf, sizeof(buf)); // JSON-print to buffer

    return (root.measureLength()); // also return length
}

void setup(){
    Serial.begin(115200);
    Serial.print("Trying to connect to WiFi");
    do {
        Serial.print(".");
        status = WiFi.begin(ssid,pass);
    } while (status != WL_CONNECTED);
      
    Serial.println("Connected to WiFi!!!");
    MPU_wakeup();
}

void loop(){
    client.sslConnect(server, port);
    delay(100);
    if (!client.connected()) { 
        Serial.println("Connection to server failed!");
    } else {
        client.println("POST /v1.1/messages HTTP/1.1");
        client.println("Host: api.artik.cloud");
        client.println("Accept: \*/\*");
        client.println("Content-Type: application/json");
        client.println(AuthorizationData);

        //Post accel, gyro and temperature values
        client.print("Content-Length: ");
        client.println(MPU_read_values());
        client.println();
        client.println(buf);
        Serial.println("Data Sent");
        client.stop();
    }
}