An Automated Pool-Side Water Gun for Dogs

#include <Servo.h>
Servo myservo;  // create servo object to control a servo


/*
 * This code controls a servo that is attached to a tube straying out water. The servo
 * is meant to direct the water stray randomly between a minAngle and maxangle.  Once the 
 * servo moves to its random position, it will wait a random amount of time before moving again.  
 * 
 * By randomly changing the direction of the water and waiting, the dog is kept entertained because she/he is 
 * unable to guess what the water will do next. 
 */
int minAngle = 50;    // The mimimum angle of the servo
int maxAngle = 160;   // The maximum angle of the servo
int pos = 0;          // The variable to store the current servo position
int newPos;           // The variable to store the new servo position

int minDelayStep = 10;  //The mimimum wait time between each "step" of the servo (smaller wait time -> faster movement)
int maxDelayStep = 100; //The maximum wait time between each "step" of the servo (larger wait time -> slower movement)
int delayStep;          // The variable to store wait time between each "step" of the servo

int minWaitTime = 500;  //The mimimum wait time after the servo has stopped moving
int maxWaitTime = 2500;  //The maximum wait time after the servo has stopped moving

void setup() {
  Serial.begin(9600);
  myservo.attach(9);  // attaches the servo on pin 9 to the servo object
  randomSeed(analogRead(0));
}


/* Before running the random code, you might want to test the servo's back and forth
 *  action. To do this, uncomment the definition below
 */
//#define BackAndForthTest
#ifdef BackAndForthTest
  void loop() { //Test the servo's ability to go back and forth 
    for (pos = minAngle; pos <= maxAngle; pos += 1) { 
      // in steps of 1 degree
      myservo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(15);                       // waits for the servo to reach the position
    }
    delay(1500);  //Wait a bit to indicate the servo has reached its maximum angle
    for (pos = maxAngle; pos >= minAngle; pos -= 1) {
      myservo.write(pos);              // tell servo to go to position in variable 'pos'
      delay(15);                       // waits for the servo to reach the position
    }
    delay(1500);  //Wait a bit to indicate the servo has reached its maximum angle
  }
#else
  void loop() { //Random loop
      newPos = random(minAngle, maxAngle); //Randomly pick a direction to aim
      delayStep = random(minDelayStep, maxDelayStep); //Randomly pick the speed to move to that new direction
      if (pos <= newPos){  // Check if the new postion is going up or down compared to the old position
        for (pos; pos <= newPos; pos += 1) {
          myservo.write(pos);              // tell servo to go to position in variable 'pos'
          delay(delayStep); 

          /*
          Serial.print("posUp:");
          Serial.print(pos);
          Serial.print("  newPos:");
          Serial.print(newPos);
          Serial.print("  delay:");
          Serial.print(delayStep);
          Serial.print("\n");
          */
        }
      } else {
          for (pos; pos >= newPos; pos -= 1) {
            myservo.write(pos);              // tell servo to go to position in variable 'pos'
            delay(delayStep); 
            
            /*
            Serial.print("posDown:");   
            Serial.print(pos);
            Serial.print("  newPos:");
            Serial.print(newPos);
            Serial.print("  delay:");
            Serial.print(delayStep);
            Serial.print("\n");
            */
          }
      }
      delay(random(minWaitTime, maxWaitTime)); //Wait a random amount of time
  }
#endif