Published September 28, 2022 © GPL3+

Lawn Maintenace

This project was to use some preset values to tell you when you should mow your lawn.

IntermediateWork in progress20 hours85

Things used in this project

Hardware components

Seeed Studio Wio Terminal

Seeed Studio Grove - Soil Moisture Sensor

Seeed Studio Grove - I2C High Accuracy Temp&Humi Sensor (SHT35)

Seeed Studio grove i2c hub

Story

This is my journey on creating a project to determine when it is best to mow your lawn. The idea was to be able to read a few sensors and take the values and display them on the WIO Terminal. And also upload the values to an MQTT broker for another application to process them.

Now with this project, I wanted to challenge myself by coding it using the Arduino IDE and FreeRTOS. This was both a good and bad idea. The good part is I was able to read the sensors and display the data using FreeRTOS tasks on the WIO terminal, but the bad part was I could not get any communications to work with FreeRTOS, I mainly tried to use Wi-Fi but could not get it to connect to my Wi-Fi network. I know there wasn't an issue with the hardware as I was able to connect to the network if I just loaded a simple Wi-Fi sample app.

For this project I use the Arduino IDE, that means you have to add some libraries to be able to compile the code. Before beginning, I would strongly suggest following the instructions on how to setup the WIO Terminal and also find each of the sensors on the SeeedStudio site and following the instructions to install any extra libraires necessary. I also would suggest loading up the example programs for any sensor you're using to make sure they work.

Now for my project I started with a sample FreeRTOS example and modified it, to work with the sensors and the WIO Terminal.

I setup the code to have a separate task for each sensor.

There are a few things to note here, the parameters that are important are the method to call (1st parameter), the number of bytes to allocate (3rd parameter), priority (5th parameter) and the handle (6 parameter).

Notice the DISPLAY_TASK has a lower priority then the rest, this is because we want to make sure sensor tasks are executed before updating the display.

The image above is how task are created. Notice they are similar to the loop() method in an Arduino sketch. Also note that there is an endless for loop. This is because FreeRTOS will manage when and how much CPU the task gets to use. Also in the code, nothing is ever put in the loop() method, this is because it never gets executed when using FreeRTOS

This also brings me to one of my first issues. Normally you should use a semaphore around the call to the sensor and setting the global variables. This is to make sure that the variable gets set before any other task uses it. Every time I tried using one, it would lock up the WIO Terminal. I would have to do a manual reset. No idea why this happened as any example of FreeRTOS code seems to be able to use them. I think my app worked without them because of how small the values being returned are.

Each of the task are similar on how they are setup, you can initialize the sensor in the setup() method. then write up the task method and finally add the task to the scheduler.

The one task that is a little different is the DISPLAY_TASK, here I created a method called drawScreen() that will draw all the details that doesn't change, this is called from the setup() and then I created a DISPLAY_TASK that will display all the values from the sensors. The code in the DISPLAY_TASK uses sprites, those will basically create update only the section defined in the sprite. It allows the screen to be redrawn without drawing the whole screen.

That is the basics of how I used FreeRTOS to create my app.

Now comes my second issue, Communications. When trying to setup the app to use a WIFI connection and MQTT. Before I did this, I loaded one of the examples sketches and configured it to use my WIFI settings. After a lot of head scratching, I remembered something I read in the setup. The WIFI device needed to have the firmware updated. The instruction on how to update the firmware are here. Once the firmware was updated and I reloaded the example sketch, the WIFI connection worked.

Now I just needed to add it to my application. Easier said than done, no matter what I did, it would not work in FreeRTOS. Every attempt locked up the WIO Terminal. After a lot of time debugging, I narrowed it down the rpcWiFi.h file. If I comment out the include file the app works, uncomment it, it locks up. I still can't figure out why.

The second part of the app was to send the data to MQTT and have a raspberry pi read the data to determine the best time to mow your lawn then notify you. I did use another contributors work on how to setup HiveMQTT on the WIO. So, I setup the MQTT part but without the communication link working I didn't have time to build the raspberry pi part.

The image below shows the running app, notice the Light sensor is showing 0, this is because the sensor is on the back of the WIO Terminal, and it is laying on the table. So, it won't read any light.

1 / 2

I think if I were to do it all over again, I would build the simple app first to have a better project to turn in, incase I'm not able to do what I really wanted to do.

I would like the thank the SeeedStudio and IoT Into the Wild Contest for Sustainable Planet 2022 for giving me the chance to build this project. It was very informative as I have never built an app using FreeRTOS or one that uses a TFT graphics like this before. And even though I didn't get it work like I wanted it to I'm sure I will be able to take what I have learned and use it in other projects.

Thanks

Dana.

Code

main code

#include <SensirionCore.h>

#include <Seeed_Arduino_FreeRTOS.h>
#include <semphr.h>
#include <TFT_eSPI.h>
#include <SensirionI2CSht4x.h>
#include "sensirion_common.h"
#include "sgp30.h"

TaskHandle_t Handle_SHT4X;
TaskHandle_t Handle_MOISTURE;
TaskHandle_t Handle_DISPLAY;
TaskHandle_t Handle_GAS;
TaskHandle_t Handle_LIGHT;
 
TFT_eSPI tft = TFT_eSPI();
TFT_eSprite spr = TFT_eSprite(&tft);

SensirionI2CSht4x sht4x;

float gTemperature;
float gHumidity;
float gMoisture;
long gVOC;
long gCO2;
float gLight;

int iTempPosX = 5;
int iTempPosY = 50;
int iHumidityPosX = 100;
int iHumidityPosY = 50;
int iMoisturePosX = 205;
int iMoisturePosY = 50;  
int iVOCPosX = 5;
int iVOCPosY = 150;
int iCO2PosX = 100;
int iCO2PosY = 150;
int iLightPosX = 205;
int iLightPosY = 150;

void setup() {
  //Start up Temperature and Humidity sensor
  Wire.begin();    
  sht4x.begin(Wire);
  
  pinMode(WIO_LIGHT, INPUT);
  
  
  
  Serial.begin(115200);
  
  s16 err;
  u16 scaled_ethanol_signal, scaled_h2_signal;
  
  #if defined(ESP8266)
    pinMode(15, OUTPUT);
    digitalWrite(15, 1);
    Serial.println("Set wio link power!");
    delay(500);
  #endif
  
  while (sgp_probe() != STATUS_OK) {
    Serial.println("SGP failed");
    while (1);
  }  
  err = sgp_measure_signals_blocking_read(&scaled_ethanol_signal,
                                            &scaled_h2_signal);
    if (err == STATUS_OK) {
        Serial.println("get ram signal!");
    } else {
        Serial.println("error reading signals");
    }
  err = sgp_iaq_init();
    
  vNopDelayMS(1000); // prevents usb driver crash on startup, do not omit this

  
  drawScreen();
  
  Serial.println("");
  Serial.println("******************************");
  Serial.println("        Program start         ");
  Serial.println("******************************");
  
  // Create the threads that will be managed by the rtos
  // Sets the stack size and priority of each task
  // Also initializes a handler pointer to each task, which are important to communicate with and retrieve info from tasks
  xTaskCreate(SHT4X_TASK,    "SHT4X_TASK",    256,  NULL, tskIDLE_PRIORITY + 2, &Handle_SHT4X);
  xTaskCreate(MOISTURE_TASK, "Moisture TASK", 256,  NULL, tskIDLE_PRIORITY + 2, &Handle_MOISTURE);
  xTaskCreate(LIGHT_TASK,    "Light TASK",    256,  NULL, tskIDLE_PRIORITY + 2, &Handle_LIGHT);
  xTaskCreate(GAS_TASK,      "Gas TASK",      1000, NULL, tskIDLE_PRIORITY + 2, &Handle_GAS);
  xTaskCreate(DISPLAY_TASK,  "Display TASK",  200,  NULL, tskIDLE_PRIORITY + 1, &Handle_DISPLAY);
  //Start the RTOS, this function will never return and will schedule the tasks.
  vTaskStartScheduler();
}

void loop() {
  //NOTHING
}

static void drawScreen(){
  tft.begin();
  tft.setRotation(3);

  //Heading
  tft.fillScreen(TFT_BLACK);
  tft.setFreeFont(&FreeSerifBold18pt7b);
  tft.setTextColor(TFT_WHITE);
  tft.fillRoundRect(3, 3 , tft.width() -3 , 45, 10, TFT_BLUE); 
  tft.drawString("Grass Monitor", 35, 10 , 1);

  //Temperature
  tft.setFreeFont(&FreeSerifBold9pt7b);
  tft.setTextColor(TFT_YELLOW) ;
  tft.drawString("Temp", iTempPosX + 15  , iTempPosY + 5 , 1);
  tft.setTextColor(TFT_WHITE);
  tft.drawString("o", iTempPosX + 47, iTempPosY + 35, 1);
  tft.drawString("C", iTempPosX + 57, iTempPosY + 50, 1);

  //Humidity
  tft.setFreeFont(&FreeSerifBold9pt7b);
  tft.setTextColor(TFT_YELLOW) ;
  tft.drawString("Humidity", iHumidityPosX + 2  , iHumidityPosY + 5 , 1); 
  tft.setTextColor(TFT_WHITE);
  tft.drawString("(%)", iHumidityPosX + 77, iHumidityPosY + 5, 1);

  //Moisture
  tft.setFreeFont(&FreeSerifBold9pt7b);
  tft.setTextColor(TFT_YELLOW) ;
  tft.drawString("Moisture", iMoisturePosX + 2  , iMoisturePosY + 5 , 1); 
  tft.setTextColor(TFT_WHITE);
  tft.drawString("(%)", iMoisturePosX + 77, iMoisturePosY + 5, 1); 

  //VOC
  tft.setFreeFont(&FreeSerifBold9pt7b);
  tft.setTextColor(TFT_YELLOW) ;
  tft.drawString("VOC", iVOCPosX + 12  , iVOCPosY + 5 , 1); 
  tft.setTextColor(TFT_WHITE);
  //tft.drawString("ppb", iVOCPosX + 57, iVOCPosY + 50, 1);
  tft.drawString("(ppb)", iVOCPosX + 57, iVOCPosY + 5, 1);

  //CO2
  tft.setFreeFont(&FreeSerifBold9pt7b);
  tft.setTextColor(TFT_YELLOW) ;
  tft.drawString("CO2", iCO2PosX + 12  , iCO2PosY + 5 , 1); 
  tft.setTextColor(TFT_WHITE);
  tft.drawString("(ppm)", iCO2PosX + 57, iCO2PosY + 5, 1);

  //Light
  tft.setFreeFont(&FreeSerifBold9pt7b);
  tft.setTextColor(TFT_YELLOW) ;
  tft.drawString("Light", iLightPosX + 12  , iLightPosY + 5 , 1); 
  tft.setTextColor(TFT_WHITE);
  tft.drawString("(lm)", iLightPosX + 57, iLightPosY + 5, 1); 
}

static void SHT4X_TASK (void* pvParameters) {
  Serial.println("Thread SHT4X: Started");
  
  float temperature;
  float humidity;
  
  for(;;){
    uint16_t err;
    err = sht4x.measureHighPrecision(temperature, humidity);
    gTemperature = temperature;
    gHumidity = humidity;
    vTaskDelay(1000);
  }
  vTaskDelete( NULL );
}
 
static void MOISTURE_TASK (void* pvParameters) {
  Serial.println("Thread MOISTURE: Started");
  
  int iMoistureSensorPin = A0;
  
  for(;;){
    gMoisture = analogRead(iMoistureSensorPin) / 7;
    vTaskDelay(1000);
  }
  vTaskDelete( NULL );   
}

static void GAS_TASK (void* pvParameters) {
  Serial.println("Thread GAS: Started");
  s16 err = 0;
  u16 tvoc_ppb, co2_eq_ppm;
  
  for(;;){    
    err = sgp_measure_iaq_blocking_read(&tvoc_ppb, &co2_eq_ppm);
 
    gVOC = (long)tvoc_ppb;
    gCO2 = (long)co2_eq_ppm;
    
    vTaskDelay(1000);
  }
  vTaskDelete( NULL );
} 

static void LIGHT_TASK (void* pvParameters) {
  Serial.println("Thread LIGHT: Started");
  for(;;){
    gLight = analogRead(WIO_LIGHT) / 10;
    vTaskDelay(1000);
  }    
  vTaskDelete( NULL );
}

void DISPLAY_TASK(void* pvParameters) {
  Serial.println("Task DISPLAY: Started");  
  for(;;){
    //Temperature
    spr.createSprite(40, 30);
    spr.setFreeFont(&FreeSerifBold18pt7b);
    spr.setTextColor(TFT_GREEN);
    spr.drawNumber(gTemperature, 0, 0, 1);
    spr.pushSprite(iTempPosX + 7, iTempPosY + 40);
    spr.deleteSprite();
  
    //Humidity
    spr.createSprite(100, 30);
    spr.setFreeFont(&FreeSerifBold18pt7b);
    spr.setTextColor(TFT_GREEN);
    spr.drawNumber(gHumidity, 0, 0, 1);
    spr.pushSprite(iHumidityPosX + 37, iHumidityPosY + 40);
    spr.deleteSprite();
    
    //Moisture
    spr.createSprite(100, 30);
    spr.setFreeFont(&FreeSerifBold18pt7b);
    spr.setTextColor(TFT_GREEN);
    spr.drawNumber(gMoisture, 0, 0, 1);
    spr.pushSprite(iMoisturePosX + 40, iMoisturePosY + 40);
    spr.deleteSprite();

    //VOC
    spr.createSprite(100, 30);
    spr.setFreeFont(&FreeSerifBold12pt7b);
    spr.setTextColor(TFT_GREEN);
    spr.drawNumber(gVOC, 0, 0, 1);
    spr.pushSprite(iVOCPosX + 27, iVOCPosY + 40);
    spr.deleteSprite();
    
    //CO2
    spr.createSprite(100, 30);
    spr.setFreeFont(&FreeSerifBold12pt7b);
    spr.setTextColor(TFT_GREEN);
    spr.drawNumber(gCO2, 0, 0, 1);
    spr.pushSprite(iCO2PosX + 27, iCO2PosY + 40);
    spr.deleteSprite();
    
    //Light
    spr.createSprite(100, 30);
    spr.setFreeFont(&FreeSerifBold12pt7b);
    spr.setTextColor(TFT_GREEN);
    spr.drawNumber(gLight, 0, 0, 1);
    spr.pushSprite(iLightPosX + 27, iLightPosY + 40);
    spr.deleteSprite();

    vTaskDelay(1000);
  }
  vTaskDelete(NULL);
}

Credits

Dana Mah

12 projects • 27 followers

I'm a hobbyist interested in microcontroller solutions to simple problems.

Contact

Thanks to Salman Faris.

Comments

Please log in or sign up to comment.

Lawn Maintenace

Things used in this project

Hardware components

Story

Schematics

Wiring Setup

Code

main code

Credits

Dana Mah

Comments

Embed the widget on your own site

Lawn Maintenace

Lawn Maintenace

Things used in this project

Hardware components

Story

Schematics

Wiring Setup

Code

main code

Credits

Dana Mah

Comments

Related channels and tags