Published October 12, 2022 © LGPL

Automatic degausser arduino controlled

The degausser applies a decreasing alternating magnetic field. The decreasing field is produced by TRIAC phase control driven by an arduino

AdvancedFull instructions provided491

Things used in this project

Hardware components

SparkFun Arduino Pro Mini 328 - 5V/16MHz

Triac 60V 25A (e.g. Q6025R5)

Opto Triac MOC3021

Optocoupler, 1 Channel

Story

WARNINGS:

If you want to embark on this project be very careful because it uses dangerous mains voltages. You have to know how to deal with.

Also, NEVER connect the Arduino to the PC while leaving the degausser's mains cable plugged in.

The usefulness of the degausser

When milling, the parallel blocks or the vice jaws can become magnetic. Milling chips stick to them and are difficult to remove. This demagnetizer applies a decreasing alternating magnetic field. At the end of the cycle, the remaining magnetization of all inserted steel parts has disappeared. Excluding neodymium magnets or other permanent magnets.

For the vise jaws, you have to take them out of the vise... or you'll make a bigger coil !

Theory of operation

A zero crossing detection circuit provides a "LOW" pulse through an optocoupler to the interrupt input pin 2 of the arduino.

The Arduino uses Timer1 to trigger the triac with increasing lag behind the zero crossing interrupt. The lag grows until it is equal to half a cycle of the ac voltage. So the alternating magnetic field decreases down to zero. The detailed timing sequence is described at the begin of the software file "AC Phase control for demagnetization".

The triac is triggered by means of an opto-triac MOC3021. A low-pass filter (R6-C2) rejects short voltage spikes. R7 limits inrush current when the opto-triac is fired. The two series resistors R11 and R14 are optional. They are in fact not needed as the impedance of the coil itself is about 27Ω at 50Hz.

Formula for calculating the impedance of a series RL

The whole degaussing sequence is about 2s. The degausser remains inhibited for 2.5 seconds more to allow the generated heat to spread. This can be useful if lot of cycles are launched one after the other.

The voltage across the coil decreases for about 2s

Making the coil

The coil is made of 4 wafers of 250 turns each of enamelled copper wire 17AWG (~ ø 1.2mm). They are individually insulated with tape and connected in series. This will help not to have to high potential gradient between the wires inside each wafers.

For winding the wafers, a wooden core serves as a winding template. The corners of the core must be rounded so as not to damage the enameling of the wire. In my case, I needed dimensions of 128x40mm for the core. If you need to demagnetize smaller or larger parts or of other shapes, you can adapt dimensions. Also, the gauge of the wires could be reduced to 20 AWG (~ ø 0.8 mm) because high current only flows for a short time and the warming up will be minimal.

But if you change significantly the dimensions, you must measure the resulting inductance and DC resistance of your coil and adapt the number of turns so that the impedance is roughly similar to mine (about 27Ω at 50Hz). More than 20Ω is desirable since we deal with 220Vac mains voltage. The impedance calculation formula is given above...

The wooden core

For the photos I used rectangular flanges. The wire tends to get stuck on the corners while winding. To wind more easily, it is necessary to round the angles and chamfer the flanges inwards

The winding ... on a lathe !

Four (or more) pieces of strong cotton or polyester yarn are first fixed on the core with smal tape pieces. They will serve to hold together the copper wires with a tight knot before removing the coil from the wooden core. The coil is then surrounded with electrician's tape. Finally the 4 wafers are connected in serie and hold tight together with electrician's tape. Pay attention to the direction of the winding when connecting them: the winding end of one shall go to winding begin of the next. One way to check this after connecting, is to power the coils sucessively 2 per 2 with a low voltage DC power supply (first and second, second and third and finally third and fourth). Each time you sense the magnetic field in the center of the coils with a screwdriver or any other iron or steel piece. If the connection is made the right way you can feel the attraction of the magnetic field. If you don't feel it, either the current is much too low or the connection is reversed.

The finished coil. On left side the 275V VDR

Assembly

The control board electronics is mounted on a perfboard. To maintain good insulation the unused copper pads are removed with the solder iron. The voltage dependent resistor VR2 is directly soldered on both ends of the coil. The two 2R2/50W resistors are mounted on a 52x80mm aluminum plate 1.5mm thick to diffuse the little generated heat. This plate is screwed on the bottom with 4mm thick nuts as spacers. You can see the two white wires comming from the resistors in the photo below.

For the optocoupler with transistor output you can use mostly any 6 pin optocoupler. Maybe also 4 pin optocouplers could do the job. I used an SL5500 but I've tried with 4N25, CNY17, MCT2 and TIL111. All of them were working well. The voltage dependent resistor VR1 is optionnal; I had not mounted it.

The inside (blue and brown mains wires are not connected to the controller board)

Left, the big yellow part: the home made coil. The black part on the top, next to the right is a salvaged 500mA USB power adapter. The plug was removed and the mains wires directly connected to the PCB. The USB socket was also removed.

To prevent damage to the coil from impact with steel parts, the inside of the coil is protected by a 3mm plastic shell - the gray parts screwed on both sides to the black parts (at the bottom of the photo).

Finished and ready for degaussing !

Code

AC Phase control for demagnetization

/*         ******************************************
//         *  AC Phase control for demagnetization  *
//         *    Daniel Engel         16/10/2022     *
//         ******************************************
//
//  V_0.3:  Translated into English and added more detailed comments
//
//  Inspired by: "AC Control V1.1" (author unknown)
// ==========================================================================
*/

// Timing Sequence
// ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
// * timer is set up but disabled
// * zero crossing detected on pin 2
// * timer starts counting from zero
// * comparator set to a "delay to on" value
// * counter reaches comparator value
// * comparator ISR turns on TRIAC gate
// * counter set to overflow - pulse width
// * counter reaches overflow
// * overflow ISR turns off TRIAC gate
// * TRIAC stops conducting at next zero cross
// * "delay to on" is increased, waiting for the next loop at zero crossing

// Timer runs at 16MHz.
// Using a divide by 256 on the counter each count is 16 microseconds.
// 1/2 wave of a 60Hz AC signal is about 520 counts (8,333 microseconds).
// 1/2 wave of a 50Hz AC signal is about 625 counts (10.0 microseconds).
// note that "delay to on" + triac gate pulse width shall not exceed the half wave duration

// NB: Timer0 (8 bits) is used by delay() millis() micros() and the PWM on pins 5 and 6.

// #include <avr/io.h>
#include <avr/interrupt.h>

#define DETECT 2            // zero cross detect
#define GATE 9              // TRIAC gate
#define PULSE 8             // trigger pulse width (counts)
#define StartBtn 7          // Start Button
#define LedRun 4            // Red LED => RUN

// -----------------------------------------------------------------------
int i = 587;          // Value where the triac is no longer fired. Determined experimentally
int SetPower = 200;   // smaller number => More power !!! SetPower=>TBD !!!
// (minimum current ~400;  maximum current ~200;) Determined experimentally
// -----------------------------------------------------------------------

void setup() {
  pinMode(DETECT, INPUT_PULLUP);    // zero cross detect
  pinMode(GATE, OUTPUT);            // TRIAC gate control
  pinMode(LED_BUILTIN, OUTPUT);
  pinMode(LedRun, OUTPUT);
  digitalWrite(LedRun, LOW);
  pinMode(StartBtn, INPUT_PULLUP);

  // set up Timer1    (see ATMEGA328 data sheet p.134 for more details)
  OCR1A = SetPower;     //initialize the comparator
  TIMSK1 = 0x03;        //enable comparator A and overflow interrupts
  TCCR1A = 0x00;        //timer control registers set for
  TCCR1B = 0x00;        //normal operation, timer disabled

  // set up zero crossing interrupt (IRQ0 is on pin 2)
  // Call zeroCrossingInterrupt on rising signal
  attachInterrupt(0, zeroCrossingInterrupt, RISING);

  BlinkFast();
}

//=======================================================================
void loop() {
  i++;
  if (i > 587)    // end of degauss cycle -

  {
    noInterrupts();
    digitalWrite(GATE, LOW);
    digitalWrite(LedRun, LOW);
    i = SetPower;    // timer value is set waiting for next cycle
    delay(2500);     // delay between cycles to allow the heat to be spread
    //                  if several cycles are chained one after the other
    while (digitalRead (StartBtn) == HIGH) {}     // button is released
    while (digitalRead (StartBtn) == LOW) {}      // button is pressed
    //   the degaussing cycle starts after the button is released

    interrupts();
    digitalWrite(LedRun, HIGH);
  }
  OCR1A = i;      // set the compare register
  delay(5);       // wait for a quarter of an alternation (for 50Hz)
  //          (could be set to 10 if more time is needed for degaussing)
}

//=======================================================================
void BlinkFast() {
  for (byte i = 6; i != 0; i--)
  {
    digitalWrite(LedRun, HIGH);  delay(100);
    digitalWrite(LedRun, LOW);  delay(100);
  }
}

//=======================================================================
//Interrupt Service Routines

void zeroCrossingInterrupt() {  //zero cross detect
  TCCR1B = 0x04;                //start timer with divide by 256 input
  TCNT1 = 0;                    //reset timer - count from zero
}

ISR(TIMER1_COMPA_vect) {        //comparator match
  digitalWrite(GATE, HIGH);     //set TRIAC gate to high
  TCNT1 = 65536 - PULSE;        //trigger pulse width
}

ISR(TIMER1_OVF_vect) {          //timer1 overflow
  digitalWrite(GATE, LOW);      //turn off TRIAC gate
  TCCR1B = 0x00;                //disable timer stopd unintended triggers
}

Credits

daniel23

8 projects • 10 followers

Automatic degausser arduino controlled

Things used in this project

Hardware components

Story

WARNINGS:

The usefulness of the degausser

Theory of operation

Making the coil

Assembly

Schematics

Degausser diagram

Code

AC Phase control for demagnetization

Credits

daniel23

Comments

Embed the widget on your own site

Automatic degausser arduino controlled

Automatic degausser arduino controlled

Things used in this project

Hardware components

Story

WARNINGS:

The usefulness of the degausser

Theory of operation

Making the coil

Assembly

Schematics

Degausser diagram

Code

AC Phase control for demagnetization

Credits

daniel23

Comments

Related channels and tags