AI Assisted Coding in an IoT-monitored Secure Environment

#include <Adafruit_BME680.h>

#define serialDebug Serial
#define serialNotecard Serial1

#define NOTE_PRODUCT_UID "com.gqc.sudhir:build2gether_2.0"

Adafruit_BME680 bmeSensor;
#define SEALEVELPRESSURE_HPA (1013.25)

#define RX_PIN D7
#define TX_PIN D6
#define BAUD 9600

float pressure,  altitude;
int gas_kohm;

uint16_t heartRate;

//BLE 

#include "BLEDevice.h"
//#include "BLEScan.h"
#include <ArduinoJson.h>

// The remote service we wish to connect to.
//static BLEUUID serviceUUID("4fafc201-1fb5-459e-8fcc-c5c9c331914b");

// The remote service we wish to connect to (Heart Rate Service).
static BLEUUID serviceUUID((uint16_t)0x180D);
// The characteristic of the remote service we are interested in.
//static BLEUUID charUUID("beb5483e-36e1-4688-b7f5-ea07361b26a8");

// The characteristic of the remote service we are interested in (Heart Rate Measurement).
static BLEUUID charUUID((uint16_t)0x2A37);

static boolean doConnect = false;
static boolean connected = false;
static boolean doScan = false;
static BLERemoteCharacteristic *pRemoteCharacteristic;
static BLEAdvertisedDevice *myDevice;

static void notifyCallback(BLERemoteCharacteristic *pBLERemoteCharacteristic, uint8_t *pData, size_t length, bool isNotify) {
  Serial.print("Notify callback for characteristic ");
  Serial.print(pBLERemoteCharacteristic->getUUID().toString().c_str());
  Serial.print(" of data length ");
  Serial.println(length);
  Serial.print("data: ");
  Serial.write(pData, length);
  Serial.println();

  // Parse the heart rate measurement data
  uint8_t flags = pData[0];
  bool isHeartRateIn16Bits = flags & 0x01;

 
  if (isHeartRateIn16Bits) {
        heartRate = (pData[2] << 8) | pData[1];
    } else {
        heartRate = pData[1];
  }

  // Create a JSON object
  StaticJsonDocument<200> doc;
  doc["heart_rate"] = heartRate;

  // Optionally, add more fields to the JSON if needed
  // For example, you might add energy expended, RR intervals, etc.

  // Serialize JSON to a string
  char jsonOutput[128];
  serializeJson(doc, jsonOutput);

  // Print the JSON string to Serial
  Serial.println("JSON data:");
  Serial.println(jsonOutput);

  }

class MyClientCallback : public BLEClientCallbacks {
  void onConnect(BLEClient *pclient) {}

  void onDisconnect(BLEClient *pclient) {
    connected = false;
    Serial.println("onDisconnect");
  }
};

bool connectToServer() {
  Serial.print("Forming a connection to ");
  Serial.println(myDevice->getAddress().toString().c_str());

  BLEClient *pClient = BLEDevice::createClient();
  Serial.println(" - Created client");

  pClient->setClientCallbacks(new MyClientCallback());

  // Connect to the remove BLE Server.
  pClient->connect(myDevice);  // if you pass BLEAdvertisedDevice instead of address, it will be recognized type of peer device address (public or private)
  Serial.println(" - Connected to server");
  pClient->setMTU(517);  //set client to request maximum MTU from server (default is 23 otherwise)

  // Obtain a reference to the service we are after in the remote BLE server.
  BLERemoteService *pRemoteService = pClient->getService(serviceUUID);
  if (pRemoteService == nullptr) {
    Serial.print("Failed to find our service UUID: ");
    Serial.println(serviceUUID.toString().c_str());
    pClient->disconnect();
    return false;
  }
  Serial.println(" - Found our service");

  // Obtain a reference to the characteristic in the service of the remote BLE server.
  pRemoteCharacteristic = pRemoteService->getCharacteristic(charUUID);
  if (pRemoteCharacteristic == nullptr) {
    Serial.print("Failed to find our characteristic UUID: ");
    Serial.println(charUUID.toString().c_str());
    pClient->disconnect();
    return false;
  }
  Serial.println(" - Found our characteristic");

  // Read the value of the characteristic.
  if (pRemoteCharacteristic->canRead()) {
    String value = pRemoteCharacteristic->readValue();
    Serial.print("The characteristic value was: ");
    Serial.println(value.c_str());
  }

  if (pRemoteCharacteristic->canNotify()) {
    pRemoteCharacteristic->registerForNotify(notifyCallback);
  }

  connected = true;
  return true;
}
/**
 * Scan for BLE servers and find the first one that advertises the service we are looking for.
 */
class MyAdvertisedDeviceCallbacks : public BLEAdvertisedDeviceCallbacks {
  /**
   * Called for each advertising BLE server.
   */
  void onResult(BLEAdvertisedDevice advertisedDevice) {
    Serial.print("BLE Advertised Device found: ");
    Serial.println(advertisedDevice.toString().c_str());

    // We have found a device, let us now see if it contains the service we are looking for.
    if (advertisedDevice.haveServiceUUID() && advertisedDevice.isAdvertisingService(serviceUUID)) {

      BLEDevice::getScan()->stop();
      myDevice = new BLEAdvertisedDevice(advertisedDevice);
      doConnect = true;
      doScan = true;

    }  // Found our server
  }  // onResult
};  // MyAdvertisedDeviceCallbacks

void setup() {
  // Initialize Serial Debug
  serialDebug.begin(115200);
  while (!serialDebug) {
    ; // wait for serial port to connect. Needed for native USB
  }
  serialDebug.println("Starting...");
  BLEDevice::init("");

  // Retrieve a Scanner and set the callback we want to use to be informed when we
  // have detected a new device.  Specify that we want active scanning and start the
  // scan to run for 5 seconds.
  BLEScan *pBLEScan = BLEDevice::getScan();
  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks());
  pBLEScan->setInterval(1349);
  pBLEScan->setWindow(449);
  pBLEScan->setActiveScan(true);
  pBLEScan->start(5, false);

  // Initialize Notecard Serial
  //serialNotecard.begin(9600);
  serialNotecard.begin(BAUD,SERIAL_8N1,RX_PIN,TX_PIN);
  serialNotecard.println("\n");

  // Configure the Notecard
  serialNotecard.println("{\"req\":\"hub.set\",\"product\":\"" NOTE_PRODUCT_UID "\",\"mode\":\"continuous\"}");

  // Await and log Notecard configuration response
  delay(50); // wait for the Notecard to respond
  while (serialNotecard.available() > 0) {
    char incomingByte = serialNotecard.read();
    if (incomingByte != '\r' && incomingByte != '\n') {
      serialDebug.print(incomingByte);
    }
  }
  serialDebug.println();

  // Initialize and configure the BME680
  if (!bmeSensor.begin()) {
    serialDebug.println("Could not find a valid BME680 sensor...");
    while(false); // halt sketch
  } else {
    serialDebug.println("BME680 Connected...");
  }
  bmeSensor.setTemperatureOversampling(BME680_OS_8X);
  bmeSensor.setHumidityOversampling(BME680_OS_2X);

  
  // Set up oversampling and filter initialization
  //bme.setTemperatureOversampling(BME680_OS_8X);
  bmeSensor.setHumidityOversampling(BME680_OS_2X);
  bmeSensor.setPressureOversampling(BME680_OS_4X);
  bmeSensor.setIIRFilterSize(BME680_FILTER_SIZE_3);
  bmeSensor.setGasHeater(320, 150); // 320*C for 150 ms
}

void loop() {
  // If the flag "doConnect" is true then we have scanned for and found the desired
  // BLE Server with which we wish to connect.  Now we connect to it.  Once we are
  // connected we set the connected flag to be true.
  if (doConnect == true) {
    if (connectToServer()) {
      Serial.println("We are now connected to the BLE Server.");
    } else {
      Serial.println("We have failed to connect to the server; there is nothing more we will do.");
    }
    doConnect = false;
  }

  // If we are connected to a peer BLE Server, update the characteristic each time we are reached
  // with the current time since boot.
  if (connected) {
    String newValue = "Time since boot: " + String(millis() / 1000);
    Serial.println("Setting new characteristic value to \"" + newValue + "\"");

    // Set the characteristic's value to be the array of bytes that is actually a string.
    pRemoteCharacteristic->writeValue(newValue.c_str(), newValue.length());
  } else if (doScan) {
    BLEDevice::getScan()->start(0);  // this is just example to start scan after disconnect, most likely there is better way to do it in arduino
  }



  // Sample the BME680 sensor
  if (!bmeSensor.performReading()) {
    serialDebug.println("Failed to obtain a reading...");
    delay(3000);
    return;
  }

  // Print readings to the console
  serialDebug.print("Temperature = ");
  serialDebug.print(bmeSensor.temperature);
  serialDebug.println(" *C");
  serialDebug.print("Humidity = ");
  serialDebug.print(bmeSensor.humidity);
  serialDebug.println(" %");

  // added more measurements
  serialDebug.print("Pressure = ");
  pressure=bmeSensor.pressure/100.0;
  serialDebug.print(pressure);
  serialDebug.println(" hPa");
  gas_kohm=bmeSensor.gas_resistance / 1000.0;
  serialDebug.print("Gas = ");
  serialDebug.print(gas_kohm);
  serialDebug.println(" KOhms");
  altitude=bmeSensor.readAltitude(SEALEVELPRESSURE_HPA);
  serialDebug.print("Approx. Altitude = ");
  serialDebug.print(altitude);
  serialDebug.println(" m");

  // Create the JSON request string
  char json_request[300];
  snprintf(json_request, sizeof(json_request),
    "{"
      "\"req\":\"note.add\","
      "\"file\":\"sensors.qo\","
      "\"start\":true,"
      "\"body\":{"
        "\"temp\":%d.%02d,"
        "\"humidity\":%d.%02d,"
        "\"pressure\":%d.%02d,"
        "\"gas_kohm\":%d,"
        "\"altitude\":%d.%02d,"
        "\"heart_rate\":%d"
      "}"
    "}",
    (int)bmeSensor.temperature, abs(((int)(bmeSensor.temperature*100.0)%100)),
    (int)bmeSensor.humidity, (int)(bmeSensor.humidity*100.0)%100,
    (int)(pressure), int((pressure-(int)(pressure))*100),
    (int)(gas_kohm),
    (int)(altitude), abs(int((altitude-(int)(altitude))*100)),
    (int)(heartRate)
    
  );
  serialDebug.println(json_request);
  // Send request to Notecard
  serialNotecard.println(json_request);
  delay(50); // wait for the Notecard to respond
  while (serialNotecard.available() > 0) {
    char incomingByte = serialNotecard.read();
    if (incomingByte != '\r' && incomingByte != '\n') {
      serialDebug.print(incomingByte);
    }
  }
  serialDebug.println();

  delay(15000);
}