Published November 1, 2021 © CC BY

Warty Monster

Warty Monster is a "smart" Halloween Pumpkin featuring scary sounds, lights, and cool mist, activated by a proximity sensor and a sonar.

IntermediateFull instructions provided4 hours1,276

Things used in this project

Hardware components

Arduino UNO

Ultrasonic Sensor - HC-SR04 (Generic)

PIR Sensor, 7 m

MG995 Servo Motor

Arduino 4 Relays Shield

LED (generic)

Sound Device

USB Battery Pack

Story

Video 1. Warty Monster

This Halloween project consists of a real pumpkin (warty pumpkin) enhanced with sensors and actuators. When the pumpkin detects movement (via a PIR proximity sensor), it activates blinking lights and pre-recorded scary sounds for a period. Next, if someone gets very close to the pumpkin (i.e., less than 20 cm), it will spray a cool mist through one of its eyes. This cool mist spraying mechanism is done with a servo motor and thermal water spray. Next, I will present the project in detail.

Fig. 1. Schematics Diagram

Overview

As shown in Fig. 1, the electronics for this project is relatively straight-forward: the "brain" is an Arduino Uno board, the "heart" is a 5V battery pack, the sensing is done with a PIR proximity sensor and an HR04 sonar sensor, and the effects are done with 5V LED lights, a 5V sound recording+playback device, and a custom-made cool mist spray mechanism. The control of the lights and sound devices is done via a relay board (shield). I used an 8-relay board, but only 2 relays are needed.

Sensors and Actuators

Fig. 2. Sensors and Actuators (front view)

Fig. 2 shows the frontal view of the scary pumpkin, featuring the sensors and the cool mist spray. Fig. 3 shows the cool mist spray mechanism built with an MG995 servo motor and a thermal water spray. The MG995 rotates to an angle of 40 degrees to activate the spray (see my code below).

if (distance < 20) {
    if (sprayTimer == 0) {
      Myservo.write(40);
      delay(1000);
      Myservo.write(0);
      sprayTimer++;
    }
  }

Fig. 3. Cool Mist Spray Mechanism

Fig. 4. Sound Device

For the sound effects, I used the device shown in Fig. 4. I do not know exactly the name of this device, but I bought it from Taobao two years ago. Any device working at 5V which allows you to control it via a switch can be used for this project.

Finally, I recommend using a plastic bag inside the pumpkin to protect the circuits. Do not place the circuits and wires directly inside the pumpkin! Enjoy!

Code

Pumpkin.ino

#include<Servo.h>

Servo Myservo;                    // cool mist spray servo motor
#define servoPin            5     // servo pin
#define sprayTimerTh        20    // cool mist spray timer threshold
int sprayTimer = 0;               // cool mist spray timer (counter)
#define sprayServoAngle     40    // rotate to 40 degrees
#define sprayServoDuration  1000  // spray for 1000 ms
#define sprayDistanceTh     20    // sonar distance threshold to activate the spray

#define proximityPin  A0      // analogue
#define proximityTh   100     // threshold

#define soundOnPin 8          // sound on relay pin
#define soundTimerTh  10      // how long is the sound on
int soundOn = 0;              // is sound on? (flag)
int soundTimer = 0;           // sound on timer (counter)

#define lightOnPin      7     // light on relay pin
#define lightTimerTh   30     // how long 
int lightOn = 0;              // is light on? (flag)
int lightOnTimer = 0;         // light on timer (counter)

#define echoPin       2       // HC-SR04 sonar echo pin
#define trigPin       3       // HC-SR04 sonar trigger pin


void doSound() {
  int proximityVal;

  // if there is movement, on the sound
  proximityVal = analogRead(proximityPin);
  if (proximityVal > proximityTh) {
    if (soundOn == 0) {
      digitalWrite(soundOnPin, HIGH);
      delay(100);
      digitalWrite(soundOnPin, LOW);
      soundOn = 1;      
      lightOnTimer = 1;
      soundTimer = 0;
    }
  }

  // keep the sound on for "soundTimerTh"
  soundTimer++;
  if (soundTimer > soundTimerTh) {
    soundTimer = 0;
    if (soundOn == 1) {
      digitalWrite(soundOnPin, HIGH);
      delay(100);
      digitalWrite(soundOnPin, LOW);
      soundOn = 0;
    }
  }
}

void doLight() {
  // while the timer is active, keep blinking the light
  if (lightOnTimer > 0) {
    digitalWrite(lightOnPin, lightOn == 0 ? HIGH : LOW);
    lightOn = (lightOn == 0 ? 1 : 0);
    lightOnTimer++;
    if (lightOnTimer == lightTimerTh) {
      lightOnTimer = 0;
    }
  }
}

void doSpray() {
  long duration; // duration of sound wave travel
  int distance;  // sonar distance

  // read the sonar
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  duration = pulseIn(echoPin, HIGH);
  distance = duration * 0.034 / 2; // speed of sound wave divided by 2 (trip)

  // if the distance is less than 20 cm, spray the mist
  if (distance < 20) {
    if (sprayTimer == 0) {
      Myservo.write(sprayServoAngle);
      delay(sprayServoDuration);
      Myservo.write(0);
      sprayTimer++;
    }
  }
  if (sprayTimer > 0) {
    sprayTimer++;
    if (sprayTimer == sprayTimerTh) {
      sprayTimer = 0;
    }
  }
}

void setup()
{
  pinMode(soundOnPin, OUTPUT);
  digitalWrite(soundOnPin, LOW);
  pinMode(lightOnPin, OUTPUT);
  digitalWrite(lightOnPin, LOW);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  
  Myservo.attach(servoPin);

  // for debugging
  // Serial.begin(9600);
}

void loop()
{
  doSound();
  doLight();
  doSpray();
  // timer interval is set at 300ms
  delay(300);
}