Published March 9, 2016 © MIT

D Watch

First attempt at extending O Watch sample code to include display of Temp (in C and F) and RH.

IntermediateFull instructions provided30 minutes2,280

Things used in this project

Hardware components

O Watch Sensor Kit

Software apps and online services

Arduino IDE

TinyCircuits-TinyScreen_Lib-master Library

Time-master Library

Adafruit_Sensor-master Library

Adafruit_BMP280 Library

Adafruit_HMC5883 Library

SI7021-master Library

Story

This is a simple extension of the O Watch sample code from this project.

It's a simple proof-of-concept to demonstrate the ease with which the O Watch can be customized and extended.

Prerequisites (What you'll need to get started)

In addition to the O Watch (with Sensor) Kit listed below, you will also need the Arduino IDE installed on your computer. If you haven't already done so, I highly recommend you read the Getting Started with Arduino page as well as O Watch's Introduction to Arduino. These pages will walk you though downloading, installing, and configuring the Arduino IDE.

This project also requires the following Arduino Libraries:

As with any Arduino library, unzip the archive file and place the resultant directory/folder in your Arduino/Libraries/ directory, then restart the IDE. The IDE won't use the new libraries until you do so! If you need a little more help, please read Installing Additional Arduino Libraries.

Putting it all together

At this point, you should be able to download/copy the program code (called a Sketch in Arduino) I've provided, compile it, and upload it to your O Watch.

Step 1. Launch the Arduino IDE and open a new sketch (File | New). There will be some default code automatically inserted – it's not needed, so go ahead and delete all of it, leaving a blank editor window.

Step 2. Copy the sketch code (D Watch v0.1) from the Code section below and paste it into the editor window. Save the sketch (File | Save As...), replacing the default name (based on the current date) with one that makes sense. How about DWatch_0.1 ?

Step 3. Set the current date and time in the code. The O Watch cannot determine the current date and time on its own, so look for the following two lines in the sketch:

  // Set the time and date. Change this to your current date and time.
  setTime(07,42,00,9,3,2016);    //values in the order hr,min,sec,day,month,year

and carefully edit it to reflect your local time and date, then re-save your sketch.

Step 4. Verify/compile your sketch. This sounds scary to new users, but is very important and not that hard once you've done it a couple of times. Look for the checkmark button at the to left of the IDE window and click it. The IDE will check your code for syntax errors and compile the code (make it ready for uploading to the O Watch). Pay very close attention to any error messages. They may sound confusing, but read them carefully – they will tell you exactly where the error is and what went wrong. If you don't understand the error message, google is your friend.

Step 5. Upload your sketch to the O Watch. Connect the O Watch to your computer using a USB cable, turn it on, and make sure the Arduino IDE recognizes both its board "TinyScreen+" and its Port (something like cu.usbmodem1411 on a Mac, or COM:3 on a PC, remembering that the numbers at the end may be different on your computer). Remember the checkmark button you used Step 4? Right next to it is an arrow pointing right — click on it to upload your sketch to the O Watch. After a few moments, the IDE will display a number of messages, ending with CPU Reset. Congratulations! You've successfully uploaded your sketch and it should be running.

Troubleshooting hint: If the IDE reports there is no device on cu.usbmodem1411 (or whatever port your O Watch is using), go to "Tools | Port:" and select any other port (it doesn't matter which one), wait a few seconds, and reselect the correct one.

Great, but what does it do?

After restarting, the setup menu will appear for a few seconds:

D Watch Initial Menu

As you'll note, the Time and Set (time) buttons remain the same, but I've repurposed the lower right button to display the local temp and RH ("Wx").

The time screen is unchanged (for now):

Time display

The new Wx screen takes readings from the temperature and humidity sensors and displays them:

Wx display

The temperature sensor (through its library) reports in Celsius by default, but the O Watch sample code included the simple C-to-F conversion. To add the Celsius reading, I simply copied the appropriate block of code, removed the conversion, and changed the cursor start point.

Obviously, there is nothing earth-shattering about this project — as I mentioned, this is a very simple extension of the O Watch code and it meant to be a proof-of-concept to show how this device can be customized in as little as 30 minutes by anyone who was able to install and run the O Watch sample code.

Next Step: Customize your watch!

Ok, you've successfully downloaded, edited, saved, compiled, and uploaded your sketch — now comes the fun part!

You don't want your watch to say "D Watch" at startup, so find the line that reads display.print("D Watch v0.1"); and change it!

Don't like which buttons do what? Poke around in the code and change what they do.

How about a quick demo of TinyScreen's full-color graphics? That would be a great function for the upper left button!

It's not hard once you understand the basics of Arduino programming. Just remember that you must save, verify, and upload your code every time you make a change!

Are you going to make mistakes? Yep – and you'll learn something every time you do! Just remember to save your work and use Save As... to make a new version every time you reach a milestone. This allows you to go back to a version that you know works.

The most important step: Have Fun!

"If you're not having fun, you're not doing it right!"

D Watch v0.1

/*
 * My Watch 1 ( D Watch, v0.1)
 *
 * Extending O Watch smaple code to include temp and humidity
 *
 * This example is created by dwardio on 9 March 2016
 * 
*/

#include <TinyScreen.h> //include TinyScreen library
#include <TimeLib.h> //include the Arduino Time library
#include <SPI.h> //include this library for communication with OLED screen
#include <SI7021.h> //include the sensor library
SI7021 sensor; //declare the sensor

TinyScreen display = TinyScreen(TinyScreenPlus); //Create the TinyScreen object

void setup()
{
  
  Wire.begin();
  sensor.begin();
  display.begin();                            //Initializes TinyScreen board
  display.setFlip(1);                         //Flips the TinyScreen rightside up for O Watch
  display.on();                               //Turns TinyScreen display on
  display.fontColor(TS_8b_White,TS_8b_Black); //Set the font color, font background
  display.setBrightness(10);                  //Set display brightness 0 - 15
  
  // Set the time and date. Change this to your current date and time.
  setTime(07,42,00,9,3,2016);    //values in the order hr,min,sec,day,month,year

  //Show info at start to say what each button does
  display.setFont(liberationSansNarrow_12ptFontInfo);
  display.setCursor(8,25);
  display.print("D Watch v0.1");
  display.setFont(liberationSansNarrow_10ptFontInfo);
  display.setCursor(60,7);
  display.print("Time>");
  display.setCursor(64,45);
  display.print("Wx>");  
  display.setCursor(5,45);
  display.print("<Set");
  delay(2000);
  display.clearScreen();
}

void loop()
{

  //Switch statement to select part of code to run based on button selection
  switch (display.getButtons()) 
  {

    //Run updateTime function 
    case TSButtonLowerLeft:
      display.on();
      updateTime();
      delay(200);
      display.off();
      break;

    //Run showWx function
    case TSButtonLowerRight:
      delay(200);
      display.on();
      showWx();
      delay(200);
      display.off();
      break;

    //Show time for 4 seconds 
    case TSButtonUpperRight:
      display.on();
      for(int i=0; i<5; i++)
      {
        display.setFont(liberationSansNarrow_12ptFontInfo);   //Set the font type
        // Print date in US format MM:DD:YY (Switch the order in which day, month, year that you like to use)
        display.setCursor(15,8); //Set the cursor where you want to start printing the date
        display.print(monthShortStr(month()));
        display.print(" ");
        display.print(day()); 
        display.print(", ");
        display.print(year());
      
        display.setCursor(30,25); //Set the cursor where you want to start printing the date  
        display.print(dayStr(weekday()));
      
        display.setFont(liberationSansNarrow_16ptFontInfo);   //Set the font type
      
        // display time in HH:MM:SS 24 hour format
        display.setCursor(20,45); //Set the cursor where you want to start printing the time
        if(hour()<10) display.print(0); //print a leading 0 if hour value is less than 0
        display.print(hour());
        display.print(":");
        if(minute()<10) display.print(0); //print a leading 0 if minute value is less than 0
        display.print(minute());
        display.print(":");
        if(second()<10) display.print(0); //print a leading 0 if seconds value is less than 0
        display.print(second());
        display.print(" "); //just a empty space after the seconds
        delay(1000); //delay 1 second           
      }
      delay(200);
      display.clearScreen();
      display.off();
      break;
    
  }
  delay(200);
}


//Function to update time
void updateTime()
{

  //Set hour
  display.clearScreen();
  display.setFont(liberationSansNarrow_8ptFontInfo);   //Set the font type
  display.setCursor(2,15);
  display.print("<Save | Change>");
  display.setCursor(15,40);
  display.setFont(liberationSansNarrow_12ptFontInfo);   //Set the font type
  display.print("Set Hour:");
  int myhour=hour();
  while(!display.getButtons(TSButtonUpperLeft))
  {
    display.setCursor(75,40);
    if(myhour<10) display.print("0");
    display.print(myhour);
    if(display.getButtons(TSButtonUpperRight))
      myhour++;
    if(display.getButtons(TSButtonLowerRight))
      myhour--;
    if(myhour<0) myhour=24;
    if(myhour>24) myhour=0;
    delay(200);
  }
  setTime(myhour, minute(), second(), day(), month(), year());
  delay(500);
  display.clearScreen();
  display.setCursor(10,25);
  display.print("Hour Saved");
  delay(1000);

  
  //Set minute
  display.clearScreen();
  display.setFont(liberationSansNarrow_8ptFontInfo);   //Set the font type
  display.setCursor(2,15);
  display.print("<Save | Change>");
  display.setCursor(15,40);
  display.setFont(liberationSansNarrow_12ptFontInfo);   //Set the font type
  display.print("Set Mins:");
  int myminute=minute();
  while(!display.getButtons(TSButtonUpperLeft))
  {
    display.setCursor(75,40);
    if(myminute<10) display.print("0");
    display.print(myminute);
    if(display.getButtons(TSButtonUpperRight))
      myminute++;
    if(display.getButtons(TSButtonLowerRight))
      myminute--;
    if(myminute<0) myminute=60;
    if(myminute>60) myminute=0;
    delay(200);
  }
  setTime(hour(), myminute, second(), day(), month(), year());
  delay(500);
  display.clearScreen();
  display.setCursor(10,25);
  display.print("Minute Saved");
  delay(1000);

  //Set second
  display.clearScreen();
  display.setFont(liberationSansNarrow_8ptFontInfo);   //Set the font type
  display.setCursor(2,15);
  display.print("<Save | Change>");
  display.setCursor(15,40);
  display.setFont(liberationSansNarrow_12ptFontInfo);   //Set the font type
  display.print("Set Secs:");
  int mysecond=second();
  while(!display.getButtons(TSButtonUpperLeft))
  {
    display.setCursor(75,40);
    if(mysecond<10) display.print("0");
    display.print(mysecond);
    if(display.getButtons(TSButtonUpperRight))
      mysecond++;
    if(display.getButtons(TSButtonLowerRight))
      mysecond--;
    if(mysecond<0) mysecond=60;
    if(mysecond>60) mysecond=0;
    delay(200);
  }
  setTime(hour(), minute(), mysecond, day(), month(), year());
  delay(500);
  display.clearScreen();
  display.setCursor(10,25);
  display.print("Second Saved");
  delay(1000);
  display.clearScreen();
  
}

//Function to show Wx (Temp & Humidity) for 4 seconds
void showWx()
{
  //get the temperature using the library function 
  //temperature is an integer in hundredths
  int tempHundredths = sensor.getCelsiusHundredths();
  float temperature = tempHundredths / 100.0;

  //get humidity from the libdary function
  // humidity is an integer representing percent
  int humidityvalue = sensor.getHumidityPercent();
  
  
  display.setFont(liberationSansNarrow_12ptFontInfo);   //Set the font type
    
  //print humidity value
  display.setCursor(20,10);
  display.print("RH: ");
  display.print(humidityvalue);
  display.print("%  ");
  
  //print temperature value F
  display.setCursor(5,30);
  display.print("Temp: ");
  display.print((temperature*9/5+32-13)); //printing value converted to Fahrenheit
  display.print("º F  ");

  //print temperature value C
  display.setCursor(5,50);
  display.print("Temp: ");
  display.print(temperature); //printing value in C
  display.print("º C  ");

  //clear display after delay
  delay(4000);  
  display.clearScreen();

}