SCADA Using Cellular IoT with MKR GSM 1400

// ---------------------------------------------------------------------------
// Include the base required libraries
// ---------------------------------------------------------------------------
#include <ArduinoMqttClient.h>
#include <MKRGSM.h>
#include <Arduino.h>
#include <SensorModbusMaster.h>
#include "arduino_secrets.h" 

// ---------------------------------------------------------------------------
// Set up the MT-102 Modbus slave information
// ---------------------------------------------------------------------------

// Define the RTU's modbus address
byte modbusAddress = 0x01;    // The RTU's modbus address, or SlaveID
long modbusBaudRate = 9600;   // The baud rate the sensor uses

// Define pin number variables
const int DEREPin = 7;       // The pin controlling Recieve Enable and Driver Enable

// Serial1 is the serial port used on the MKR 1400
HardwareSerial* modbusSerial = &Serial1;

// Construct the modbus instance
modbusMaster modbus;

// ---------------------------------------------------------------------------
// Set up the information for 2G/3G data connection
// ---------------------------------------------------------------------------

// Please enter your sensitive data in the Secret tab or arduino_secrets.h
// PIN Number
const char PINNUMBER[]     = SECRET_PINNUMBER;
// APN data
const char GPRS_APN[]      = SECRET_GPRS_APN;
const char GPRS_LOGIN[]    = SECRET_GPRS_LOGIN;
const char GPRS_PASSWORD[] = SECRET_GPRS_PASSWORD;

// To connect with SSL/TLS:
// 1) Change GSMClient to GSMSSLClient.
// 2) Change port value from 1883 to 8883.
// 3) Change broker value to a server with a known SSL/TLS root certificate 
//    flashed in the WiFi module.

GPRS gprs;
GSM gsmAccess;
GSMClient gsmClient;
MqttClient mqttClient(gsmClient);

const char broker[] = "mqtt.eclipse.org";
int        port     = 1883;
const char topic[]  = "eackbarali/to";
const char publishTopic[]  = "eackbarali/analog";

// ---------------------------------------------------------------------------
// Main setup function
// ---------------------------------------------------------------------------

void setup() {
  
  //Initialize serial and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // attempt to connect to GSM and GPRS:
  Serial.print("Attempting to connect to GSM and GPRS");
   // connection state
  bool connected = false;

  // After starting the modem with GSM.begin()
  // attach the shield to the GPRS network with the APN, login and password
  while (!connected) {
    if ((gsmAccess.begin(PINNUMBER) == GSM_READY) &&
        (gprs.attachGPRS(GPRS_APN, GPRS_LOGIN, GPRS_PASSWORD) == GPRS_READY)) {
      connected = true;
    } else {
      Serial.println("Not connected");
      delay(1000);
    }
  }

  Serial.println("You're connected to the network");
  Serial.println();

  Serial.print("Attempting to connect to the MQTT broker: ");
  Serial.println(broker);

  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1);
  }

  Serial.println("You're connected to the MQTT broker!");
  Serial.println();

  pinMode(DEREPin, OUTPUT);

  // Turn on your modbus serial port
  Serial1.begin(modbusBaudRate, SERIAL_8N1);

  // Start the modbus instance
  modbus.begin(modbusAddress, modbusSerial, DEREPin);

}

void loop() {

  uint16_t analog01 = 0;
  
  // call poll() regularly to allow the library to receive MQTT messages and
  // send MQTT keep alives which avoids being disconnected by the broker
  mqttClient.poll();

  // read the first Analog pin
  //int sensorVal = analogRead(0);
  analog01 = modbus.int16FromRegister(0x04, 0x04, bigEndian);
  
  // Publish our sensor value
  mqttClient.beginMessage(publishTopic);
  mqttClient.print(analog01);
  mqttClient.endMessage();

  // Print results
  Serial.print("Analog_Input_01: ");
  Serial.println(analog01);

  // Set the rate at which we send our values
  delay(5000);
  
}