1024 LED Matrix WiFi Message Board with Menu + Web Interface

/*
***************************************************************************
  A 1024 (16x8x8) LED matrix WiFi message board with rotary encoder,
  BME280 sensor and a web interface with new message notification
  by ericBcreator

  It connects to Wifi and a timeserver and then displays date, time,
  sunrise and sunset for a set location, sensors reading of the 
  temperature, humidity and air pressure, current weather and forecasts 
  from openweather.map for multiple cities, top headlines from 
  NewsApi.org, stock data from Alpha Vantage and random Wikipedia items.
  
  A rotary encoder selects between the default display 'carousel',
  one news category, stock or weather data, no messages or it resets 
  the ESP.

  There is web access (enter the IP address of the ESP32 which is 
  displayed at startup in a browser) for displaying custom texts and 
  access to some controls. A buzzer plays a notification sound whenever 
  a new message is received.
***************************************************************************
  components:
  - ESP32
  - 16 x 8x8 MAX7219 LED matrices
  - BME280 sensor
  - rotary encoder
  - buzzer
  - light sensor
***************************************************************************
 last updated 20190411 by ericBcreator
  20181231: solved Raeren Openweather error
  20190126: added Youtube api support
  20190202: added IP to menu and menuItem numbers
  20190328: fixed webinterface for menuItem numbers
  20190406: added na_maxCallsPerDay for newsapi
            added clickable urls for newsapi and wikipedia for the webserver
  20190410: added light sensor support for setting the brightness of the leds
  
  TODO: adding buffering for newsapi
***************************************************************************
  This code is free for personal use, not for commercial purposes.
  Please leave this header intact.

  contact: ericBcreator@gmail.com
***************************************************************************
*/

#define FN_ARRAY_SIZE(x) (sizeof(x)/sizeof(x[0]))  // Generic macro for obtaining number of elements of an array

//#define DEBUG                                 // enable debugging messages
//#define DEBUG_FAST                            // skip wifi/timeserver connect messages
//#define DEBUG_NEWSAPI_NC                      // do not connect to Newsapi.org (to save the number of daily requests)

//#define LOCAL_LANG                              // @EB-setup use local language (user-definable, otherwise use English)
#define CONVERT_UTF8                            // @EB-setup converts UTF8 'special' characters to the Parola font set
#define WEBSERVER                               // @EB-setup enable webserver and web access
#define BUZZER                                  // @EB-setup use buzzer for new messages from the webserver

//
// Include libraries
//

#include <Adafruit_BME280.h>                    // BME280 library
#include <ArduinoJson.h>                        // Arduino Json library
#include <Dusk2Dawn.h>                          // Dusk2Dawn sunrise sunset library
#include <MD_MAX72xx.h>                         // Needed for Parola
#include <MD_Parola.h>                          // Parola LED library
#include <RotaryEncoder.h>                      // Rotary encoder library
#include <SPI.h>                                // Needed for the radiohead library
#include <TimeLib.h>                            // Time library
#include <WiFiClientSecure.h>                   // WiFi library
#include <WiFiUdp.h>                            // Udp library
#include <YoutubeApi.h>                         // YouTube library

#include "Font_Data_Numeric.h"                  // local file: font data for time

#ifdef CONVERT_UTF8
  #include "Font_Data_UTF8.h"                   // local file: font data for UTF8 support
#endif


//
// LED matrix setup and pins definition
//

#define HARDWARE_TYPE MD_MAX72XX::FC16_HW       // @EB-setup define the type of hardware connected
#define CLK_PIN     18                          // @EB-setup CLK / SCK pin number  (EB setup: yellow)
#define DATA_PIN    23                          // @EB-setup DIN / MOSI pin number (EB setup: brown)
#define CS_PIN      5                           // @EB-setup LOAD / SS pin number  (EB setup: green)
#define MAX_DEVICES 16                          // @EB-setup num of LED matrices
#define MAX_ZONES   3                           // num of zones
MD_Parola PD = MD_Parola(HARDWARE_TYPE, CS_PIN, MAX_DEVICES);

//
// BME280 setup
//

Adafruit_BME280 bme;                            // connect via I2C pin 21 SDA and 22 SCL
uint8_t bme_address = 0x76;                     // @EB-setup set to 0x76 or 0x77

//
// Rotary encoder setup
//

#define RE_PINA 16                              // @EB-setup pinA / clock pin number
#define RE_PINB 17                              // @EB-setup pinB / data pin number
#define RE_SWITCH 4                             // @EB-setup switch / switch pin number
RotaryEncoder RE_encoder(RE_PINA, RE_PINB);     // initialize the rotary encoder
int reLastPos = 0;
int reLastSwitchState = 0;

//
// Buzzer setup
//

#define BUZZER_PIN 15                           // @EB-setup buzzer pin
int buzz_volume = 50;                           // @EB-share buzzer volume (duty cycle 0-100)
int buzz_channel = 0;
int buzz_resolution = 8;

//
// Light sensor setup
//

//#define LS_ACTIVE                               // @EB-setup comment this line when not using a light sensor (set the brightness with pd_brightness instead)
#define LS_PIN 36                               // @EB-setup light sensor pin

int ls_minValue = 0;                            // @EB-setup min brightness (0-15)
int ls_maxValue = 15;                           // @EB-setup max brightness (0-15)
int ls_delay = 250;                             // @EB-setup delay time for checking the light sensor (in milliseconds)
int ls_triggerStep = 1;                         // @EB-setup if value 1 causes flickering try 2 or 3

long ls_lastTime = 0;

//
// Initialize variables
//

/* WiFi connection */
const char * ssid     = "######################";                   // @EB-setup set your WiFi SSID
const char * password = "######################";                   // @EB-setup set your WiFi password
int wifiTimeout = 30000;                                            // WiFi timeout (in milliseconds)

/* location for sunrise and sunset */
char d2d_City[] = "Amsterdam";                                      // @EB-share City name
float d2d_longitude = 52.37936;                                     // @EB-share
float d2d_lattitude = 4.900293;                                     // @EB-share
int d2d_timezone = 1;                                               // @EB-share UTC timezone offset

/* openweathermap connection */
const char * ow_servername = "api.openweathermap.org";              // remote server openweathermap.org
const int ow_port = 80;                                             // port
const String ow_APIKEY = "################################";        // @EB-setup personal api key for retrieving the weather data. leave empty to skip

#ifdef LOCAL_LANG
  const String ow_language = "NL";                                  // @EB-setup openweather language
#else
  const String ow_language = "EN";
#endif

int ow_cityIDLoop = 0;

// get the ID at https://openweathermap.org/ type the city, click search and click on the town
// then check the link, like this: https://openweathermap.org/city/5128581 5128581 is the ID for New York
// @EB-share 

String ow_cityIDs[] = {
  "2759794",      // Amsterdam
  "264371",       // Athens
  "3513090",      // Willemstad
  "524901",       // Moscow
  "5128581",      // New York
  "3369157",      // Cape Town 
};

/* newsapi connection */
const char * na_servername = "newsapi.org";                         // remote server newsapi.org
const int na_port = 80;                                             // port
const int na_maxCallsPerDay = 1000;                                 // @EB-setup limit the calls per day. set to zero to disable
                                                                    // 1000 max calls per day for free developer plan;

const String na_APIKEY = "################################";        // @EB-setup personal api key. leave empty to skip

#ifdef LOCAL_LANG
  const String na_country = "NL";                                   // @EB-setup country code for news
#else
  const String na_country = "US";
#endif

int na_article = 0;

/* alpha vantage stock connection */
const char * av_servername = "www.alphavantage.co";                 // remote server alphavantage
const int av_port = 443;                                            // port for secure connection

const String av_APIKEY = "################################";        // @EB-setup personal api key. leave empty to skip

// @EB-share
String av_symbolIDs[] = { "DJIA", "IXIC", "SPX", "AAPL", "GOOGL", "BTCUSD" } ;
String av_symbolName[] = { "Dow Jones index", "Nasdaq index", "S&P 500 index", "Apple", "Google", "Bitcoin" } ;

int av_symbolIDLoop = 0;

/* wikipedia connection */
const int wp_port = 443;                                            // port for secure connection

#ifdef LOCAL_LANG
  const char * wp_servername = "nl.wikipedia.org";                  // @EB-setup country code for wikipedia
#else
  const char * wp_servername = "en.wikipedia.org";
#endif

/* youtube connection */
const String yt_APIKEY = "";                                        // @EB-setup personal api key. leave empty to skip
const String yt_CHANNELID = "################################";     // @EB-setup personal channel ID

/* message definitions */
#ifdef LOCAL_LANG // @EB-share
  char msgWifiConnecting[] =                    "...wifi verbinden...";
  char msgWifiConnected[] =                     "verbonden met";
  char msgWifiFailed[] =                        "* wifi verbinding mislukt *";
  char msgConnectToTimeserver[] =               "...verbinden met de tijdserver...";
  char msgTimeserverFailed[] =                  "* verbinding met tijdserver mislukt *";
  char msgDSTon[] =                             "verbonden,   zomertijd  ";
  char msgDSToff[] =                            "verbonden,  wintertijd  ";  
  char msgResetting[] =                         "...auto reset...";
  char msgOpenweatherFailed[] =                 "* verbinding met Openweathermap mislukt *";
  char msgNewsapiFailed[] =                     "* verbinding met Newsapi.org mislukt *";
  char msgNewsapiError[] =                      "* fout bij ophalen van nieuws van Newsapi.org *";
  char msgAlphaVantageFailed[] =                "* verbinding met AlphaVantage.co mislukt *";
  char msgWikipediaFailed[] =                   "* Wikipedia *"; 
  
  char msgNews[] =                              "Laatste nieuws van";
  char msgSunrise[] =                           "Zonsopkomst";
  char msgSunset[] =                            "Zonsondergang";
  char msgCurrentWeather[] =                    "Het weer in";
  char msgForecast[] =                          "Weersverwachting voor";
  char msgTemp[] =                              "temperatuur";
  char msgHumidity[] =                          "vochtigheid";
  char msgClouds[] =                            "bewolking";
  char msgRain[] =                              "neerslag";
  char msgWind[] =                              "wind";
  char msgAVPrevious[] =                        "vorige slotkoers";
  char msgAVCurrent[] =                         "laatste koers";
  
  char msgSelected[] =                          "OK";
#else
  char msgWifiConnecting[] =                    "...wifi connecting...";
  char msgWifiConnected[] =                     "connected to";
  char msgWifiFailed[] =                        "*failed connecting to wifi*";
  char msgConnectToTimeserver[] =               "...connecting to the timeserver...";
  char msgTimeserverFailed[] =                  "* failed connecting to the timeserver *";
  char msgDSTon[] =                             "connected, DST active";
  char msgDSToff[] =                            "connected, no DST";
  char msgResetting[] =                         "...auto reset...";
  char msgOpenweatherFailed[] =                 "* failed connecting to Openweathermap *";
  char msgNewsapiFailed[] =                     "* failed connecting to Newsapi.org *";
  char msgNewsapiError[] =                      "* failed retrieving news from Newsapi.org ";
  char msgAlphaVantageFailed[] =                "* failed connecting to AlphaVantage.co *";
  char msgWikipediaFailed[] =                   "* failed connecting to Wikipedia *"; 
  
  char msgNews[] =                              "Latest news from";
  char msgSunrise[] =                           "Sunrise";
  char msgSunset[] =                            "Sunset";
  char msgCurrentWeather[] =                    "Current weather in";
  char msgForecast[] =                          "Weather forecast for";
  char msgTemp[] =                              "temperature";
  char msgHumidity[] =                          "humidity";
  char msgClouds[] =                            "clouds";
  char msgRain[] =                              "rain";
  char msgWind[] =                              "wind";
  char msgAVPrevious[] =                        "previous close";
  char msgAVCurrent[] =                         "latest";
  
  char msgSelected[] =                          "OK";
#endif

/* menu setup */
// @EB-share
#ifdef LOCAL_LANG
  const String menu[] { 
    "Standaard mozaek", 
    "Nieuws headlines", 
    "Economie", 
    "Technologie", 
    "Algemeen", 
    "Entertainment", 
    "Gezondheid", 
    "Wetenschap", 
    "Sport", 
    "Wikipedia willekeurig item",
    "Beursinfo van Alpha Vantage", 
    "Weerberichten", 
    "Youtube", 
    "Eigen bericht", 
    "IP adres", 
    "Geen berichten", 
    "- Reset" 
  } ;
#else
  const String menu[] { 
    "Default carousel",                         //  0
    "Top headlines",                            //  1
    "Business",                                 //  2
    "Technology",                               //  3
    "General",                                  //  4
    "Entertainment",                            //  5
    "Health",                                   //  6
    "Science",                                  //  7
    "Sports",                                   //  8
    "Wikipedia random item",                    //  9
    "Stock information from Alpha Vantage",     // 10
    "Weather information",                      // 11
    "Youtube",                                  // 12
    "User defined message",                     // 13
    "IP Address",                               // 14
    "No messages",                              // 15
    "- Reset"                                   // 16
  } ;
#endif

#define menuItemDefault    0
#define menuItemNews       1                    // 2 to 8 are news categories
#define menuItemWiki       9
#define menuItemStock     10
#define menuItemWeather   11
#define menuItemYouTube   12
#define menuItemUser      13
#define menuItemIP        14
#define menuItemNoMess    15
#define menuItemReset     16

const String menuNewsApi[] { "", "&category=business", "&category=technology", "&category=general", "&category=entertainment", "&category=health", "&category=science", "&category=sports" } ;

int menuItem0 = menuItemDefault;                // @EB-share default menu selection
int menuReturnDelay = 10000;                    // @EB-share delay before the menu exits

int prevMenuItem0 = menuItem0;
int menuLen = FN_ARRAY_SIZE(menu);
int menuNewsCat = 0;

/* time server */
int timeServerDelay = 1000;                     // delay for the time server to reply
int timeServerPasses = 4;                       // number of tries to connect to the time server before timing out
boolean timeServerConnected = false;            // is set to true when the time is read from the server

unsigned int localPort = 2390;                  // local port to listen for UDP packets
IPAddress timeServerIP;                         // IP address of random server
const char* ntpServerName = "pool.ntp.org";     // server pool
byte packetBuffer[48];                          // buffer to hold incoming and outgoing packets
int timeZoneoffsetGMT = d2d_timezone * 3600;    // offset from Greenwich Meridan Time
boolean DST = false;                            // daylight saving time
WiFiUDP clockUDP;                               // initialize a UDP instance

/* web server */
WiFiServer webServer(80);
int webpageRefreshTime = 15;                    // @EB-share delay time before the webserver page will auto refresh

/* Parola */
#define BUF_SIZE 250                            // @EB-share buffer size for zone 2

char pd_message0[9] = { "" };                   // message buffer zone 0 (time)
char pd_message1[20] = { "" };                  // message buffer zone 1
char pd_message2[BUF_SIZE] = { "" };            // message buffer zone 2
char tmpBuffer[BUF_SIZE] = { "" };

char pd_messageUser[BUF_SIZE] = { "--- set your message here ---" }; // @EB-share

char pd_url[BUF_SIZE] = { "" };                 // url (for newsapi and wikipedia)

uint8_t degC[] = { 6, 3, 3, 56, 68, 68, 68 };   // Deg C character
uint8_t degF[] = { 6, 3, 3, 124, 20, 20, 4 };   // Deg F character
uint8_t degCascii = 0x8F;
uint8_t degFascii = 0x90;

int pd_brightness = 3;                          // @EB-share brightness (0-15)
int scrollSpeedSetup = 20;                      // @EB-share frame delay setup
int scrollSpeedMain = 40;                       // @EB-share frame delay main loop
int scrollPause = 1500;                         // @EB-share delay after displaying the message (in milliseconds)
textEffect_t scrollEffect = PA_SCROLL_LEFT;     // @EB-share default effect
textPosition_t scrollAlign = PA_CENTER;         // @EB-share default align
textEffect_t zone1ScrollEffect = PA_SCROLL_UP;  // @EB-share default effect
int zone1Pause = 10000;                         // @EB-share delay after displaying the zone 1 message (in milliseconds)

/* general */
boolean tempCelsius = true;                     // @EB-setup set false for Fahrenheit

boolean colonFlag = true;
static uint8_t loopCounter1 = 0;
static uint8_t loopCounter2 = 0;
static uint32_t lastZone0Time = 0;
static uint32_t lastZone1Time = 0;

//
// Setup
//

void setup() {
#ifdef DEBUG
  Serial.begin(57600);                          // for debugging
  Serial.println("");
  Serial.println("Setup...");
#endif

#ifdef BUZZER  
  ledcSetup(buzz_channel, 0, buzz_resolution);  // setup the buzzer
#endif

  pinMode(RE_SWITCH, INPUT_PULLUP);             // setup the encoder button as input high

#ifdef LS_ACTIVE
//  pinMode(LS_PIN, INPUT_PULLDOWN);              // setup the light sensor input as input low
  checkLightSensor();
#endif

  setupPD();                                    // start the Parola display

  bme.begin(bme_address);                       // start the BME280 sensor

  connectToWifi();                              // connect to Wifi

  if (WiFi.status() == WL_CONNECTED) {
    getTimeFromServer();                        // connect to the timeserver and get the local time

#ifdef WEBSERVER
    webServer.begin();
    #ifdef DEBUG
      Serial.println("Webserver started");
    #endif
#endif
  }
  
  PD.setSpeed(2, scrollSpeedMain);
}

//
// Main loop
//

void loop() { 
  if ((millis() - lastZone0Time >= 1000)) {                                         // wait for 1 second before displaying the time
    displayTime();
    lastZone0Time = millis();
  }

  if ((millis() - lastZone1Time >= zone1Pause)) {                                   // display the zone 1 animation after a pause
    lastZone1Time = millis();

    switch (loopCounter1) {
      case 0:     displayDateShort();           loopCounter1++;   break;            // display short date
      case 1:     displayTemp();                loopCounter1++;   break;            // display temperature
      case 2:     displayHumidity();            loopCounter1++;   break;            // display humidity
      case 3:     displayPressure();            loopCounter1 = 0; break;            // display pressure
    }
  }

  if (readRotEnc() != 0) {                                                          // if the rotary encoder is turned go to the menu
    selectMenu0();
    if (menuItem0 == menuItemReset)                                                 // reset the ESP
      ESP.restart();
      
    if (menuItem0 != prevMenuItem0) {
      na_article = 0;
      menuNewsCat = 0;
      loopCounter2 = 0;
      prevMenuItem0 = menuItem0;
    }
  } else if (readRotEncSwitch() == true)                                            // if the rotary encoder is pushed go to the next item to display
    resetDisplayZone2();

#ifdef WEBSERVER
  checkWebAccess();                                                                 // display the website and check for input
#endif

  if (WiFi.status() != WL_CONNECTED) {                                              // if there is no wifi connection reset after 2 minutes to try to reconnect
    if (millis() > (2 * 60000)) {
      PD.setPause(2, 0);
      displayMessage(msgResetting);
      ESP.restart();
    }
  } else if (menuItem0 != menuItemNoMess) {	                                        // only display if menu item 'No messages' is not selected
    if (PD.getZoneStatus(2)) {                                                      // display the next item when the animation of the current item has finished
      sprintf(pd_url, "");                                                          // reset the url

#ifdef DEBUG
      if (loopCounter2 == 0) {
        Serial.println("");
        Serial.println(pd_message0);
      }
#endif

      if (menuItem0 == menuItemDefault) {                                           // default setting, loop trough all items
        switch (loopCounter2) {
          case 0:     displayDate();            loopCounter2++; break;              // display date
          case 1:     displaySunrise();         loopCounter2++; break;              // display sunrise time
          case 2:     displaySunset();          loopCounter2++; break;              // display sunset time
          case 3:     displayWeatherData();     loopCounter2++; break;              // 1st loop current weather, 2nd loop weather forecast
          case 4:     displayNewsapiData();     loopCounter2++; break;              // display newsapi items
          case 5:     displayAVStockData();     loopCounter2++; break;              // display alpha vantage stock data
          case 6:     displayWikipedia();       loopCounter2++; break;              // display a random Wikipedia item
          case 7:     displayYT();              loopCounter2++; break;              // display YouTube          
          default:    loopCounter2 = 0;
        }

      } else {
          if (loopCounter2 == 10)
            displayDate();
          else {
            switch (menuItem0) {
              case menuItemUser:      displayUserMessage();  break;                 // user defined message (or posted on the webserver)
              case menuItemIP:        displayIP();           break;                 // only show IP
              case menuItemYouTube:   displayYT();           break;                 // only show YouTube
              case menuItemWeather:   displayWeatherData();  break;                 // only show weather data
              case menuItemStock:     displayAVStockData();  break;                 // only show stock data
              case menuItemWiki:      displayWikipedia();    break;                 // only show Wikipedia
              
              default:                                                              // only show news                  
                menuNewsCat = menuItem0 - 1;
                displayNewsapiData();
            }
          }
        loopCounter2 = (++loopCounter2) % 11;                                       // show 10 items and then display the date again
      }
      
#ifdef CONVERT_UTF8
      if (menuItem0 != menuItemUser)                                                // don't do a double conversion of the webserver text, it will erase the UTF characters
        utf8AsciiStr(pd_message2).toCharArray(pd_message2, BUF_SIZE);               // convert UTF8 characters
#endif
    }
  }

  PD.displayAnimate();

#ifdef LS_ACTIVE
  if (millis() - ls_lastTime > ls_delay) {                                         // check the light sensor every quarter second
    checkLightSensor();
    ls_lastTime = millis();
  }
#endif
}

//
// Display functions
//

void setupPD() {
  PD.begin(MAX_ZONES);                          // start the Parola display

  PD.setZone(0, 0, 3);                          // zone 0 time
  PD.setZone(1, 4, 7);                          // zone 1 date, temperature, humidity
  PD.setZone(2, 8, MAX_DEVICES - 1);            // zone 2 messages

  PD.setFont(0, numeric7Seg);                   // set numeric font for the time

#ifdef CONVERT_UTF8
  PD.setFont(2, ExtASCII);                      // Parola font set with UTF8 support
#endif

  PD.setIntensity(pd_brightness);               // brightness (0-15)
  PD.setInvert(0, false);                       // invert false (text on, background off)
  PD.setInvert(1, false);                       // invert false (text on, background off)
  PD.setInvert(2, false);                       // invert false (text on, background off)

  PD.displayZoneText(0, pd_message0, PA_CENTER, 0, 0, PA_PRINT, PA_NO_EFFECT);
  PD.displayZoneText(1, pd_message1, PA_CENTER, scrollSpeedMain, scrollPause, zone1ScrollEffect, PA_NO_EFFECT);
  PD.displayZoneText(2, pd_message2, scrollAlign, scrollSpeedSetup, scrollPause, scrollEffect, scrollEffect);

  PD.addChar(degCascii, degC);
  PD.addChar(degFascii, degF);
}

void checkLightSensor() {
  int tmpValue;

  tmpValue = analogRead(LS_PIN);
  tmpValue = map(tmpValue, 0, 4095, ls_minValue, ls_maxValue);

  if (abs(tmpValue - pd_brightness) >= ls_triggerStep) {
    if (tmpValue < pd_brightness)
      pd_brightness--;      
    else
      pd_brightness++;
    PD.setIntensity(pd_brightness);
      
#ifdef DEBUG
    Serial.print("Brightness set to ");
    Serial.println(pd_brightness);
#endif
  }
}

void displayMessage(char * message) {
  snprintf(pd_message2, sizeof(pd_message2), "%s", message);

#ifdef DEBUG
  Serial.println(pd_message2);
#endif

#if !defined (DEBUG_FAST)
  PD.displayReset(2);
  while (!PD.getZoneStatus(2))
    PD.displayAnimate();
#endif
}

void displayTime() {
  time_t t = now();

  if (hour(t) == 3 && minute(t) == 0)           // at 03:00 get the current time from the timeserver for readjusting and rereading DST
    getTimeFromServer();

  snprintf(pd_message0, sizeof(pd_message0), "%02d%c%02d", hour(t), (colonFlag ? ':' : ' '), minute(t));
  PD.displayReset(0);

  colonFlag = !colonFlag;
}

void displayDateShort() {
  time_t t = now();
  String monthStr = monthAsStringShort(month(t));
  snprintf(pd_message1, sizeof(pd_message1), "%d %s", day(t), monthStr.c_str());
  PD.displayReset(1);
}

void displayTemp() {
  float bmeTemp = bme.readTemperature();
  if (tempCelsius)
    sprintf(pd_message1, "%2.1f %c", bmeTemp, degCascii);
  else {
    bmeTemp = (bmeTemp * 9 / 5) + 32;
    sprintf(pd_message1, "%2.1f %c", bmeTemp, 129);
  }

#ifdef DEBUG
  Serial.println(pd_message1);
#endif
  PD.displayReset(1);
}

void displayHumidity() {
  float bmeHumidity = bme.readHumidity();
  sprintf(pd_message1, "%2.0f%% rh", bmeHumidity);
  
#ifdef DEBUG
  Serial.println(pd_message1);
#endif
  PD.displayReset(1);
}

void displayPressure() {
  float bmePressure = bme.readPressure() / 100.0f;
  sprintf(pd_message1, "%4.0f h", bmePressure); // hPa doesn't fit...
  
#ifdef DEBUG
  Serial.println(pd_message1);
#endif
  PD.displayReset(1);
}

void displayDate() {
  time_t t = now();
  String dayStr = dayAsString(weekday(t));
  String monthStr = monthAsString(month(t));
  sprintf(pd_message2, "%s %d %s %04d", dayStr.c_str(), day(t), monthStr.c_str(), year(t));
  PD.displayReset(2);

#ifdef DEBUG
  Serial.println(pd_message2);
#endif
}

void displaySunrise() {
  time_t t = now();
  char d2dSunrise[] = "00:00";

  Dusk2Dawn d2d(d2d_longitude, d2d_lattitude, d2d_timezone);
  Dusk2Dawn::min2str(d2dSunrise, d2d.sunrise(year(t), month(t), day(t), DST));
  sprintf(pd_message2, "%s : %s %s", d2d_City, msgSunrise, d2dSunrise);
  PD.displayReset(2);

#ifdef DEBUG
  Serial.println(pd_message2);
#endif
}

void displaySunset() {
  time_t t = now();
  char d2dSunset[] = "00:00";

  Dusk2Dawn d2d(d2d_longitude, d2d_lattitude, d2d_timezone);
  Dusk2Dawn::min2str(d2dSunset, d2d.sunset(year(t), month(t), day(t), DST));
  sprintf(pd_message2, "%s : %s %s", d2d_City, msgSunset, d2dSunset);
  PD.displayReset(2);

#ifdef DEBUG
  Serial.println(pd_message2);
#endif
}

void displayUserMessage() {
  strcpy(pd_message2, pd_messageUser);
  PD.displayReset(2);

#ifdef DEBUG
  Serial.println(pd_message2);
#endif
}

void displayIP() {
  sprintf(pd_message2, "%s (%d dBm)  %s ", msgWifiConnected, WiFi.RSSI(), WiFi.localIP().toString().c_str());
  PD.displayReset(2);

#ifdef DEBUG
  Serial.println(pd_message2);
#endif
}

void resetDisplayZone2() {
  strcpy(pd_message2, "");
  PD.displayClear(2);
  PD.displayReset(2);
}

//
// menu functions
//

void selectMenu0() {
#ifdef DEBUG
  Serial.println("Entering menu");
#endif

  int reResult;
  int lastReResult;
  int menuStartTime = millis();
  bool reSwitchPressed = false;

//  resetDisplayZone2;  // @EB: () missing, no use?? check

  PD.displayZoneText(2, pd_message2, PA_LEFT, scrollSpeedSetup, scrollPause, PA_PRINT, PA_CLOSING);
  displayMenuItem0();

  do {
    reResult = readRotEnc();

    if (reResult < 0) {             // down
      --menuItem0;
      if (menuItem0 < 0)
        menuItem0 = FN_ARRAY_SIZE(menu) - 1;
      PD.displayZoneText(2, pd_message2, PA_LEFT, scrollSpeedSetup, scrollPause, PA_SCROLL_UP, PA_SCROLL_UP);

    } else if (reResult > 0) {      // up
      menuItem0 = (++menuItem0) % FN_ARRAY_SIZE(menu);
      PD.displayZoneText(2, pd_message2, PA_LEFT, scrollSpeedSetup, scrollPause, PA_SCROLL_DOWN, PA_SCROLL_DOWN);
    }

    if (reResult != 0) {
      menuStartTime = millis();
      displayMenuItem0();
      lastReResult = reResult;
    } else {
      if (PD.getZoneStatus(2)) {
        if (lastReResult < 0)
          PD.setTextEffect(2, PA_SCROLL_LEFT, PA_SCROLL_UP);
        else
          PD.setTextEffect(2, PA_SCROLL_LEFT, PA_SCROLL_DOWN);
        PD.displayReset(2);
      }
    }

    reSwitchPressed = readRotEncSwitch();

    if (millis() - lastZone0Time >= 1000) {
      displayTime();
      lastZone0Time = millis();
    }

    PD.displayAnimate();

  } while ((millis() - menuStartTime < menuReturnDelay) && reSwitchPressed == false);

  if (reSwitchPressed == true) {
    strcpy(pd_message2, msgSelected);
    PD.displayZoneText(2, pd_message2, PA_LEFT, scrollSpeedSetup, 1000, PA_PRINT, PA_NO_EFFECT);
    while (!PD.getZoneStatus(2))
      PD.displayAnimate();

#ifdef DEBUG
    Serial.println(pd_message2);
#endif
  } else
    menuItem0 = prevMenuItem0;

  resetDisplayZone2();
  PD.displayZoneText(2, pd_message2, scrollAlign, scrollSpeedMain, scrollPause, scrollEffect, scrollEffect);

#ifdef DEBUG
  Serial.println("Exiting menu");
#endif
}

void displayMenuItem0() {
  sprintf(pd_message2, "%2d %s", menuItem0, menu[menuItem0].c_str());

#ifdef CONVERT_UTF8
  utf8AsciiStr(pd_message2).toCharArray(pd_message2, BUF_SIZE);
#endif
 
  PD.displayReset(2);

#ifdef DEBUG
  Serial.print("Menu: ");
  Serial.println(pd_message2);
#endif
}

int readRotEnc() {
  int reCurrentPos;
  int reResult = 0;

  RE_encoder.tick();

  reCurrentPos = RE_encoder.getPosition();
  if (reCurrentPos < reLastPos)
    reResult = -1;
  else if (reCurrentPos > reLastPos)
    reResult = 1;

  reLastPos = reCurrentPos;
  return reResult;
}

bool readRotEncSwitch() {
  int reSwitchState = digitalRead(RE_SWITCH);
  if (reSwitchState == LOW && reLastSwitchState == HIGH) {
    reLastSwitchState = reSwitchState;
    return true;
  }
  reLastSwitchState = reSwitchState;
  return false;
}

//
// web server
//

void checkWebAccess() {
  String currentLine = "";
  char oldMessage[BUF_SIZE] = { "" };
  char c;
  int customText, endOfText;  
  WiFiClient client = webServer.available();

  if (!client)
    return;
    
#ifdef DEBUG
  Serial.println("Webserver client connected");
#endif

  strcpy(oldMessage, pd_message2);
  
  for (int i = 0; i < BUF_SIZE; i++) {
    if (oldMessage[i] == '\0') break;
    if (oldMessage[i] == degCascii) oldMessage[i] = 'C';                    // replace Celsius symbol with C for web page
  }
  
  for (int i = 0; i < BUF_SIZE; i++) {
    if (oldMessage[i] == '\0') break;
    if (oldMessage[i] == degFascii) oldMessage[i] = 'F';                    // replace Fahrenheid symbol with F for page
  }
  
  while (client.connected()) {
    if (client.available()) {
      c = client.read();

      if (c == '\n') {
        
#ifdef DEBUG
  if (currentLine.indexOf("GET /") >= 0) {
    Serial.print("Webserver client request: ");
    Serial.println(currentLine);
  }
#endif

        // check the GET statemnt

        customText = currentLine.indexOf("GET /?customtext=");
        if (customText >= 0) {
          endOfText = currentLine.indexOf("HTTP") - 1;
          parseGet((customText + 17), endOfText, currentLine).toCharArray(pd_messageUser, BUF_SIZE);

#ifdef DEBUG
          Serial.print("Webserver custom text: ");
          Serial.println(pd_messageUser);
#endif
          strcpy(oldMessage, pd_messageUser);
          menuItem0 = menuItemUser;
          loopCounter2 = 0;
          resetDisplayZone2();
          
#ifdef BUZZER
          playBuzzer();
#endif

        } else if (currentLine.indexOf("GET /nextItem") >= 0)
          resetDisplayZone2();
        else if (currentLine.indexOf("GET /carousel") >= 0)
          menuItem0 = menuItemDefault;
        else if (currentLine.indexOf("GET /nomessages") >= 0) {
          resetDisplayZone2();
          menuItem0 = menuItemNoMess;
        } else if (currentLine.indexOf("GET /youtube") >= 0)
          menuItem0 = menuItemYouTube;
        else if (currentLine.indexOf("GET /weather") >= 0)
          menuItem0 = menuItemWeather;
        else if (currentLine.indexOf("GET /stock") >= 0)
          menuItem0 = menuItemStock;
        else if (currentLine.indexOf("GET /wikipedia") >= 0)
          menuItem0 = menuItemWiki;
        else if (currentLine.indexOf("GET /reset") >= 0)
          ESP.restart();
      
        // display the web page
        if (currentLine.length() == 0) {
#ifdef DEBUG
  Serial.println("Displaying website");
#endif

          client.println("HTTP/1.1 200 OK");
          client.println("Content-type:text/html");
          client.println("Connection: close");
          client.println();
        
          // display the HTML web page
          client.println("<!DOCTYPE html><html>");
          client.println("<head>");
          client.println("<meta http-equiv=\"Content-Type\" content=\"text/html;charset=ISO-8859-1\">");
          client.print("<meta http-equiv=\"refresh\" content=\"");
          client.print(webpageRefreshTime);
          client.print(";http://");
          client.print(WiFi.localIP());
          client.println("\" >");
          client.println("<style>html { font-family: Helvetica; margin: 0px 25%; text-align: center; } body { background-color: #EEEEEE; }");
          client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 6px 16px;");
          client.println("text-decoration: none; font-size: 14px; font-weight: bold; margin: 4px; cursor: pointer;}");
          client.println("</style>");
          client.println("</head>");
        
          client.println("<body>");
          client.println("<h2>LED Message Board Web Interface</h2>");
          client.println("<h4>by ericBcreator</h4><br>");
          client.println("<p>Last displayed: </p>");
          client.println("<font color=\"red\"><b><p>");

          if (strlen(pd_url) == 0)
            client.println(oldMessage);
          else {
            client.print("<a href=\"");
            client.print(pd_url);
            client.print("\" target=\"_blank\">");
            client.print(oldMessage);
            client.println("</a>");
          }
            
          client.println("</b></p></font><br>");
          
          client.println("<form action=\"/\" method=\"get\">");
          client.println("<br>Input your message to display and click 'Send'<br><br>");
          client.println("<INPUT type=\"text\" size=\"60\" name=\"customtext\"<br>");
          client.println("<INPUT type=\"submit\" value=\"Send\">");
          client.println("</form><br>");

          client.print("<p>");
          client.println("<a href=\"/nextItem\"><button class=\"button\">Next item</button></a>");
          client.println("<a href=\"/carousel\"><button class=\"button\">Default carousel</button></a>");
          client.println("<a href=\"/wikipedia\"><button class=\"button\">Wikipedia</button></a>");
          client.println("<a href=\"/weather\"><button class=\"button\">Weather</button></a>");
          client.println("<a href=\"/stock\"><button class=\"button\">Stock info</button></a>");
          client.print("</p><p>");
          client.println("<a href=\"/youtube\"><button class=\"button\">Youtube</button></a>");
          client.println("<a href=\"/\"><button class=\"button\">Refresh</button></a>");
          client.println("<a href=\"/nomessages\"><button class=\"button\">No messages</button></a>");
          client.println("<a href=\"/reset\"><button class=\"button\">Reset the ESP32</button></a>");
          client.print("<p>");
          
          client.println("</body></html>");
          client.println();

          break;
        } else
          currentLine = "";

      } else if (c != '\r')
        currentLine += c;
    }
  }
 
  client.stop();

...

This file has been truncated, please download it to see its full contents.