Published September 5, 2022 © GPL3+

Holo Clock

3D printed and run by a single stepper motor, this unique clock's hands float in a hollow frame.

AdvancedFull instructions provided12 hours1,349

Things used in this project

Hardware components

Digilent Stepper Motor

Microchip ATtiny1614 Microprocessor

Tactile Switch, SPST

AO3400 N-Channel MOSFET

78M05 5V SMD regulator

LED 0805 SMD

Passive Components

4 x 1K 0805 resistors, 4 x 10K 0805 resistors, 1 x 330 ohm 0805 resistor, 1 x 0.1uF 0805 ceramic capacitor, 1 x 100uF/10V 6032 Tantalum capacitor

DC Power Connector, Socket

Software apps and online services

Arduino IDE

Hand tools and fabrication machines

3D Printer (generic)

Soldering iron (generic)

Story

This is my build and changes to Ekaggrat's Holo Clock published on Thingiverse.

Ekaggrat's Holo Clock (you can also purchase it as a kit)

The changes that I made were:

Use of a cheap 28BYJ-48 stepper motor
New electronics based around a ATtiny1614 microprocessor
New software

3D printing

This build uses a 28BYJ-48 stepper motor so "frame_1__n.stl" and "motor_gear.stl" are replaced with "Motor Plate V1.stl" and "Motor_Gear_V1.stl" respectively.

Also "Rollers.stl" and "Spacers.stl" replace "p1.stl" and "SPACERS.stl" respectively.

Also "Button.stl" replaces "botton.stl".

As the gears need to rotate freely, I inserted 4mm brass tubes into each of the gears ("big_gear_1" to "big_gear_3"). You can buy these brass tubes from most hobby shops.

4mm OD, 0.45mm wall brass tube

Electronics

The circuit is built around a ATtiny1614 microprocessor. As the stepper motor is unipolar, it is driven by four N-Channel MOSFETs. A 5V regulator provides power from a 7V-12V power brick.

Schematic for the Holo Clock

All the components are surface mounted. I have included the Eagle files in case you want to get the board commercially made or do as I did and make it yourself. I used the Toner method.

PCB layout

Assembly

I won't go into assembling the clock here as Ekaggrat's instructions are attached. Instead I will cover the PCB assembly and any special changes I had to make to the original design.

Start by adding SMD components.

Add the 3 pin header for the UPDI programmer and the 5 pin header for the stepper motor connection.

Add SMD components and pin headers

Next add the tactile switch.

Add the DC power socket. If your board is single-sided, super glue the socket to the copper side and flatten the pins on the component side of the PCB. Solder two wires from the socket pins to the holes provided (see picture).

Add Switch and DC panel socket

The DC panel socket gets in the way of one of the gears so you need to file down the inside back corner (see picture).

Insert "Button.stl" into the base ("base.stl") and glue the PCB to the base using hot glue.

File down edge of DC Power Socket & glue onto base

Assemble the clock base using Ekaggrat's instructions that are attached.

Assemble the clock base

One of the issues I came across is the 25mm bolts used to hold the rollers that will guide the two big rings stick out too far. When the rings are installed, the end of the bolts hit the hands of the clock. To remedy this, I designed new rollers and used 22mm bolts. The roller allows the hex end to be sunk into the roller and the other end of the bolt not to stick out past the nut.

New rollers sink the bolt head and stops the bolt thread sticking out past the nut

Add the rings to the base.

Add the rings to the base

Finally glue on the clock hands.

Glue on the clock hands

Programming the clock

The ATtiny1614 is part of the new breed of ATtiny microprocessors. Unlike the earlier series such as the ATtiny85, the new breed use the RESET pin to program the CPU. To program it you need a UPDI programmer. I made one using a Arduino Nano. You can find complete build instructions at Create Your Own UPDI Programmer. it also contains the instructions for adding the megaTinyCore boards to your IDE.

Connect UPDI programmer and upload sketch

Connect the UPDI programmer

Once the board has been installed in the IDE, select it from the Tools menu.

Select board, chip (ATtiny1614), clock speed (20MHz) and the COM port that the Arduino Nano is connected to.

The Programmer needs to be set to jtag2updi (megaTinyCore).

Open the sketch and upload it to the ATtiny1614.

Conclusion

As a talking piece, it succeeds 😃. As a time piece, it won't win any awards 🙁. Still it was an interesting and challenging build and I have to admit, it does look pretty cool 😎.

Schematics

Code

HoloClockV3.ino

/**
 * HOLO CLOCK V3
 * 
 * 2022-19-02 John Bradnam (jbrad2089@gmail.com)
 * 
 * ATTiny1614 Pins mapped to Ardunio Pins
 *
 *             +--------+
 *         VCC + 1   14 + GND
 * (SS)  0 PA4 + 2   13 + PA3 10 (SCK)
 *       1 PA5 + 3   12 + PA2 9  (MISO)
 * (DAC) 2 PA6 + 4   11 + PA1 8  (MOSI)
 *       3 PA7 + 5   10 + PA0 11 (UPDI)
 * (RXD) 4 PB3 + 6    9 + PB0 7  (SCL)
 * (TXD) 5 PB2 + 7    8 + PB1 6  (SDA)
 *             +--------+
 *             
 * BOARD: ATtiny1614/1604/814/804/414/404/214/204
 * Chip: ATtiny1614
 * Clock Speed: 20MHz
 * Programmer: jtag2updi (megaTinyCore)
 *
 * Teeth in big gear 178
 * Teeth in small gear 20
 * Gear ratio 8.9
 * Motor steps per revolution 400 (28BYJ-48 is 2037.8864)
*/

#include <Stepper.h>

#define IN_1 0        //PA4
#define IN_2 1        //PA5
#define IN_3 2        //PA6
#define IN_4 3        //PA7
#define SWITCH_PIN 4  //PB3
#define LED_PIN 5     //PB2

#define GEAR_RATIO 8.9
#define NUMBER_OF_STEPS 2038
//STEPS_PER_MINUTE (int)((GEAR_RATIO * NUMBER_OF_STEPS) / 60) = 302.303
//Add extra step every 3 seconds
//Add extra step every 10 seconds
#define STEPS_PER_MINUTE 302
#define BLINK_DELAY 1000
#define MOVE_DELAY 60000

Stepper myStepper(NUMBER_OF_STEPS, IN_1, IN_3, IN_2, IN_4);

bool ledState = false;
unsigned long previousMillis = 0;
unsigned long previousMillisMotor = 0;
int moveCount = 0;

//---------------------------------------------------------------------
//Set up clock
void setup() 
{
  myStepper.setSpeed(15); // speed for movement
  pinMode(SWITCH_PIN,INPUT_PULLUP);
  pinMode(LED_PIN, OUTPUT);
}

//---------------------------------------------------------------------
//Main program loop
void loop() 
{
  blink();
  if (digitalRead(SWITCH_PIN) == LOW)
  {
    digitalWrite(LED_PIN,HIGH);
    //myStepper.step(60 * STEPS_PER_MINUTE + 20);
    myStepper.step(STEPS_PER_MINUTE + (((moveCount % 3) == 2) ? 1 : 0) + (((moveCount % 10) == 9) ? 1 : 0));
    motorOff();
    moveCount = (moveCount + 1) % 60;
    digitalWrite(LED_PIN,HIGH);
    //delay(2000);
    delay(10);
  }
  else
  {
    unsigned long currentMillisMotor = millis();
    if ((unsigned long)(currentMillisMotor - previousMillisMotor) >= MOVE_DELAY) 
    {
      myStepper.step(STEPS_PER_MINUTE + (((moveCount % 3) == 2) ? 1 : 0) + (((moveCount % 10) == 9) ? 1 : 0));
      motorOff();
      moveCount = (moveCount + 1) % 60;
      previousMillisMotor = currentMillisMotor;
    }
  }
}

//---------------------------------------------------------------------
//Turn off the motor

void motorOff()
{
  digitalWrite(IN_1, LOW);
  digitalWrite(IN_2, LOW);
  digitalWrite(IN_3, LOW);
  digitalWrite(IN_4, LOW);
}

//---------------------------------------------------------------------
//Blink the LED

void blink()
{
  unsigned long currentMillis = millis();
  if ((unsigned long)(currentMillis - previousMillis) >= BLINK_DELAY) 
  {
    ledState = !ledState; 
    digitalWrite(LED_PIN, ledState); 

    previousMillis = currentMillis;
  } 
}

Credits

John Bradnam

145 projects • 178 followers

Thanks to ekaggrat.

Holo Clock

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

3D printing

Electronics

Assembly

Programming the clock

Conclusion

Custom parts and enclosures

STL files

Clock assembly instructions

Schematics

Schematic

PCB

Eagle Files

Code

HoloClockV3.ino

Credits

John Bradnam

Comments

Embed the widget on your own site

Holo Clock

Holo Clock

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

3D printing

Electronics

Assembly

Programming the clock

Conclusion

Custom parts and enclosures

STL files

Clock assembly instructions

Schematics

Schematic

PCB

Eagle Files

Code

HoloClockV3.ino

Credits

John Bradnam

Comments

Related channels and tags