Skeet Shooting Game

/*
Shoot - Button support
Schematic, Board design, Code: John Bradnam (jbrad2089@gmail.com)
*/

#pragma once

#define F_CPU 8000000UL
#include <avr/io.h>
#include <util/delay.h>

/*
Pin Definitions
---------------
PB0 - LOAD
PB1 - DATA
PB2 - CLOCK
PB3 - SPEAKER
PB4 - SWITCHES (ADC2) => SHOOT - 0V (0), LEVEL - 2.5V (127), NO_BUTTON - 5V (255)
*/

enum ButtonEnum { NO_BUTTON, LEVEL, SHOOT };
#define EPSILON 50
#define ADC_NO_BUTTON 255
#define ADC_LEVEL 127
#define ADC_SHOOT 0

// Initialise Buttons
void initButtons(uint8_t pin);

// Tests if any of the buttons have been pressed and released
//  returns the button that was pressed
ButtonEnum ButtonPressed();

// Read the button pin and return current state
//  returns either NO_BUTTON, LEVEL or SHOOT
ButtonEnum readButtonState();

// Read analog pin
//  returns a number between 0 and 255
int avrAnalogRead();

//------------------------------------------------------------------------------------------------------------------

// Initialise Buttons (PB4 - ADC2 pin)
//   pin - not used, hard coded to use ADC2 (PB4)
void initButtons(uint8_t pin)
{
  //Setup analog pin for switches
  ADMUX = 0b00100010;   //sets VCC as VREF, sets ADC2 (PB4) as input channel, and left adjusts
  ADCSRA = 0b10000011;  //turn on ADC, keep ADC single conversion mode,
                        //and set division factor-8 for 125kHz ADC clock
}

//--------------------------------------------------------

// Tests if any of the buttons have been pressed and released
//  returns the button that was pressed
ButtonEnum ButtonPressed()
{
	ButtonEnum button = NO_BUTTON;
	int btn = readButtonState();
  if (btn != ADC_NO_BUTTON)
	{
		_delay_ms(10);
	  if (readButtonState() == btn)
		{
			while (readButtonState() == btn)
      {
      }
			button = btn;
		}
	}
	return button;
}

//--------------------------------------------------------

// Read the button pin and return current state
//  returns either NO_BUTTON, LEVEL or SHOOT
ButtonEnum readButtonState()
{
  int state = avrAnalogRead();
  if (abs(state - ADC_SHOOT) <= EPSILON)
  {
    return SHOOT;
  }
  else if (abs(state - ADC_LEVEL) <= EPSILON)
  {
    return LEVEL;
  }
  else
  {
    return NO_BUTTON;
  }
}

//--------------------------------------------------------

// Read analog pin
//  returns a number between 0 and 255
int avrAnalogRead()
{
  ADCSRA |= (1 << ADSC);         //start conversion
  while (ADCSRA & (1 << ADSC))
  {
    _delay_ms(1);
  }
  return ADCH;              //store data in analogData variable
}

/*
Shoot - Display support
Schematic, Board design, Code: John Bradnam (jbrad2089@gmail.com)
*/

#pragma once

#define F_CPU 8000000UL
#include <avr/io.h>
#include <util/delay.h>
#include <LedControl.h>

/*
Pin Definitions
---------------
PB0 - LOAD
PB1 - DATA
PB2 - CLOCK
PB3 - SPEAKER
PB4 - SWITCHES (ADC2) - 0V (0), LEVEL - 2.5V (127), NO_BUTTON - 5V (255)

DIG_0 - LED 1 .. 8
DIG_1 - LED 9 .. 16
DIG_2 - LED 17 .. 34
DIG_3 - LED 25 .. 32
DIG_4 - LED 33 .. 40
DIG_5 - Level 7 Segment
DIG_6 - Score Units 7 Segment
DIG_7 - Score Tens 7 Segment

Segment order for each row is SEG_DP, SEG_A, SEG_B, SEG_C, SEG_D, SEG_E, SEG_F, SEG_G
*/

//Because there is no default constructor for he LedControl, we can't create an instance of it
//without passing some parameters. This instance will be replaced in initDisplay and the garbage
//collector can clean up this instance.
LedControl _lc = LedControl(11, 13, 12);

//Initilaise MAX7219. This drives all LEDs via a MAX7219.
void initDisplay(uint8_t dataPin, uint8_t clockPin, uint8_t loadPin);

//Clear all target LEDs
void clearAllTargetLeds();

// Turn on or off a target LED
// pos - 0..39
// on - true is on
void showTargetLed(int pos, bool on);

// Show level value
// value - 0..9
// on - true is on
void showLevel(int value, bool on);

// Show Score value
// value - 0..99
// on - true is on
void showScore(int value, bool on);

//Flashes a score on the display
// value - number to flash
// repeat - number of times to flash
// delta - time in mS between each state
void flashScore(int value, int repeat, int delta);

// Show a number between 0 and 999 across all displays
// pos - 0..39
// on - true is on
void showValue(int value, bool on);

//Display a animation from inside to outside
// delta - time in mS between frames
void animateInsideOut(int delta);

//Display a animation from outside to inside
// delta - time in mS between frames
void animateOutsideIn(int delta);

//------------------------------------------------------------------------------------------------------------------

//Initilaise MAX7219. This drives all LEDs via a MAX7219.
void initDisplay(uint8_t dataPin, uint8_t clockPin, uint8_t loadPin)
{
  _lc = LedControl(dataPin,clockPin,loadPin,1);
  
  //Setup LEDs
  _lc.shutdown(0,false);     //Wakeup call
  _lc.setScanLimit(0, 7);    //Number of digits
  _lc.setIntensity(0, 15);    //Brightness
  _lc.clearDisplay(0);

}

//-------------------------------------------------------

//Clear all target LEDs
void clearAllTargetLeds()
{
  for (int i = 0; i < 40; i++)
  {
    showTargetLed(i, false);
  }
}

//-------------------------------------------------------

// Turn on or off a target LED
// pos - 0..39
// on - true is on
void showTargetLed(int pos, bool on)
{
	if (pos >= 0 && pos < 40)
	{
		int seg = pos & 0x07;
		int dig = pos >> 3;
		_lc.setLed(0, dig, seg, on);
	}
}

//-------------------------------------------------------

// Show level value
// value - 0..9
// on - true is on
void showLevel(int value, bool on)
{
  value = min(value, 9);
  if (on)
  {
    _lc.setDigit(0,5,value,false);
  }
  else 
  {
    _lc.setChar(0,5,' ', false);
  }
}

//-------------------------------------------------------

// Show Score value
// value - 0..99
// on - true is on
void showScore(int value, bool on)
{
  value = min(value, 99);
  int tens = value / 10;
  int units = value % 10;
  if (on)
  {
    _lc.setDigit(0,6,units,false);
  }
  else 
  {
    _lc.setChar(0,6,' ', false);
  }
  if (on && tens != 0)
  {
    _lc.setDigit(0,7,tens,false);
  }
  else
  {
    _lc.setChar(0,7,' ', false);
  }
}

//-------------------------------------------------------

// Show a number between 0 and 999 across all displays
// pos - 0..39
// on - true is on
void showValue(int value, bool on)
{
  value = min(value, 999);
  int hundreds = value / 100;
  int tens = (value % 100) / 10;
  int units = value % 10;
  if (on)
  {
    _lc.setDigit(0,6,units,false);
  }
  else 
  {
    _lc.setChar(0,6,' ', false);
  }
  if (on && (tens != 0 || hundreds != 0))
  {
    _lc.setDigit(0,7,tens,false);
  }
  else
  {
    _lc.setChar(0,7,' ', false);
  }
  if (on && hundreds != 0)
  {
    _lc.setDigit(0,5,hundreds,false);
  }
  else
  {
    _lc.setChar(0,5,' ', false);
  }
}

//--------------------------------------------------------------------------------------

//Flashes a score on the display
// value - number to flash
// repeat - number of times to flash
// delta - time in mS between each state
void flashScore(int value, int repeat, int delta)
{
  for (int x=0; x < repeat;x++)
  {
    showScore(value, (x & 1) != 0);
    delay(delta);
  }
  showScore(value, true);
}


//--------------------------------------------------------------------------------------

//Display a animation from inside to outside
// delta - time in mS between frames
void animateInsideOut(int delta)
{
  for (int i = 0; i < 40; i++)
  {
    if (i < 20)
    {
      showTargetLed(i + 20, true);
      showTargetLed(19 - i, true);
    }
    else
    {
      showTargetLed((i - 20) + 20, false);
      showTargetLed(19 - (i - 20), false);
    }
    delay(delta);
  }
}

//--------------------------------------------------------------------------------------

//Display a animation from outside to inside
// delta - time in mS between frames
void animateOutsideIn(int delta)
{
  for (int i = 0; i < 40; i++)
  {
    showTargetLed(i, (i < 20));
    showTargetLed(39-i, (i < 20));
    delay(delta);
  }
}

#pragma once

uint8_t _speakerPin;

// Initialise Music player
void initMusic(uint8_t speakerPin);

//Play a sound of a frequency in Hz for a duration in mS
void playSound(double freqHz, int durationMs);

//Play turn tone
void playHitTone();

//Play turn tone
void playMissTone();

//Play wah wah wah wahwahwahwahwahwah
void playLoseMusic();

//Play winning music
void playWinMusic();

//------------------------------------------------------------------------------------------------------------------

// Initialise Music player
void initMusic(uint8_t speakerPin)
{
  _speakerPin = speakerPin;
  pinMode(_speakerPin, OUTPUT);
}

//------------------------------------------------------------------------------------------------------------------

//Play a sound of a frequency in Hz for a duration in mS
void playSound(double freqHz, int durationMs)
{
  //Calculate the period in microseconds
  int periodMicro = int((1/freqHz)*1000000);
  int halfPeriod = periodMicro/2;
   
  //store start time
  long startTime = millis();
   
  //(millis() - startTime) is elapsed play time
  while((millis() - startTime) < durationMs)
  {
    digitalWrite(_speakerPin, HIGH);
    delayMicroseconds(halfPeriod);
    digitalWrite(_speakerPin, LOW);
    delayMicroseconds(halfPeriod);
  }
}

//------------------------------------------------------------------------------------------------------------------

//Play turn tone
void playHitTone()
{
  playSound(523,50); 
}

//------------------------------------------------------------------------------------------------------------------

//Play turn tone
void playMissTone()
{
  playSound(110,50); 
}

//------------------------------------------------------------------------------------------------------------------

//Play wah wah wah wahwahwahwahwahwah
void playLoseMusic()
{
  delay(400);
  //wah wah wah wahwahwahwahwahwah
  for(double wah=0; wah<4; wah+=6.541)
  {
    playSound(440+wah, 50);
  }
  playSound(466.164, 100);
  delay(80);
  for(double wah=0; wah<5; wah+=4.939)
  {
    playSound(415.305+wah, 50);
  }
  playSound(440.000, 100);
  delay(80);
  for(double wah=0; wah<5; wah+=4.662)
  {
    playSound(391.995+wah, 50);
  }
  playSound(415.305, 100);
  delay(80);
  for(int j=0; j<7; j++)
  {
    playSound(391.995, 70);
    playSound(415.305, 70);
  }
  delay(400);
}

//------------------------------------------------------------------------------------------------------------------

//Play winning music
void playWinMusic()
{
  playSound(880,100); //A5
  playSound(988,100); //B5
  playSound(523,100); //C5
  playSound(988,100); //B5
  playSound(523,100); //C5
  playSound(587,100); //D5
  playSound(523,100); //C5
  playSound(587,100); //D5
  playSound(659,100); //E5
  playSound(587,100); //D5
  playSound(659,100); //E5
  playSound(659,100); //E5
  playSound(880,100); //A5
  playSound(988,100); //B5
  playSound(523,100); //C5
  playSound(988,100); //B5
  playSound(523,100); //C5
  playSound(587,100); //D5
  playSound(523,100); //C5
  playSound(587,100); //D5
  playSound(659,100); //E5
  playSound(587,100); //D5
  playSound(659,100); //E5
  playSound(659,100); //E5
  delay(250);
}