Published March 6, 2018 © GPL3+

Stream Your Audio on the ESP32

Use the ESP32 to play audio data from a custom stream.

IntermediateFull instructions provided1 hour149,453

Things used in this project

Hardware components

Speaker: 3W, 4 ohms

Espressif ESP32S

I really recommend using an ESP32 Developer Board from your favourite brand

Solderless Breadboard Full Size

Jumper wires (generic)

Adafruit Stereo 3.7W Class D Audio Amplifier - MAX98306

Software apps and online services

Arduino IDE

with the esp32 core from espressif

Java

Audacity

Story

I showed you in my last project how to stream voice data to your computer. This time I will show you how to stream data in the ESP32 and play it. Let's get started.

1. Build the circuit

Connect the Amplifier like shown in the picture below. Now you just have to connect the red wire to 5V, black to GND and the yellow to the DAC_1 (GPIO25) of your ESP32 developer board. With the potentiometer, you can control the volume of the sound. You don't need it but it's very practical because otherwise it' very loud.

2. Setting up the code

Open the Arduino software on your computer. Paste the Arduino code from the CODE section below in the editor. (Don't forget to remove the standard code before!) Now change your WiFi credentials in the following path of the code:

const char* ssid     = "YOUR SSID";
const char* password = "YOUR PASSWORD";

Furthermore, you have to set the IP Address of your Raspberry Pi.

const char* host     = "YOUR SERVER IP ADDRESS";

Now you can upload the code to your ESP32 board. To Tools → Board and select your ESP32 board. Now select the Port at Tools → Port. Now you click "upload" to upload your Sectch.

3. How does it work?

I used a so-called "circular buffer", which is an array which end is connected to the beginning. Therefore the name "circular buffer". You can see a demonstration picture below or visit https://en.wikipedia.org/wiki/Circular_buffer for more information. The main loop checks if 800 bytes are free in the buffer. When this applies, the ESP32 sends a request to the server, consisting of 0xFF(11111111binary). The server responses the next 800 bytes and the ESP32 store them in the buffer.

https://upload.wikimedia.org/wikipedia/commons/f/fd/Circular_Buffer_Animation.gif

4. Convert the audio file you want to play

Open Audacity. Open your file by dragging your file into the window.

Set the "Project Rate(Hz)" in the left corner to 8000.

Select your audio track and go to "Tracks" → "Mix" → "Mix Stereo down to Mono". After processing you should have one channel audio.

Now click "Tracks" → "Resample". A box should pop up. Set the "New sample rate: " to 8000 and click OK.

Now you export the audio by clicking "File" - > "Export" → "Export Audio". Select the directory where the file should be saved. Besides set "File type" to "Other uncompressed files", "Header" to "Raw(Header-less)" and "Encoding" to "Unsigned 8-bit PCM". When you are sure that you have chosen the right options, you click Export. The following information can be ignored and accepted.

5. Let's test it!

Download the "Voice_Server.jar" file and the "demo.raw" file form the code section below. You need Java to be installed! Copy the Voice_Server.jar, demo.raw and your raw file in a new directory named "Voice-Server".

Mac:

Open the Terminal Application.

Type in "cd ". Drag and drop the directory icon in the Terminal window. And it should look something like this:

cd /Users/julian/Desktop/Voice-Server

Now hit enter. Now you are in your directory. Now you type in

java -jar "Voice_Server.jar" "YourFileName.raw"

or just try the demo file:

java -jar "Voice_Server.jar" "demo.raw"

After hitting enter the program reads the file. This can take a few seconds, depending on your file size.

Plug in the ESP32 and now you should hear your audio data.

Code

#include <Arduino.h>
#include <WiFi.h>
#include <driver/dac.h>

const char* ssid     = "YOUR SSID";
const char* password = "YOUR PASSWORD";
const char* host     = "YOUR SERVER IP ADDRESS"; 

WiFiClient client;

hw_timer_t * timer = NULL; 
portMUX_TYPE timerMux = portMUX_INITIALIZER_UNLOCKED; 

#define BUFFFERMAX 8000

uint8_t dataBuffer[BUFFFERMAX];
int readPointer = 0, writePointer = 1;

bool play = false;

void IRAM_ATTR onTimer() {
  portENTER_CRITICAL_ISR(&timerMux);
  
  // play data: 
  if (play) {
    dac_output_voltage(DAC_CHANNEL_1, dataBuffer[readPointer]);

    readPointer++;
    if (readPointer == BUFFFERMAX) {
      readPointer = 0;
    }

    if ( getAbstand() == 0 ) {
      Serial.println("Buffer underrun!!!");
      play = false;
    }
  }


  portEXIT_CRITICAL_ISR(&timerMux);
}

int getAbstand() {
  int abstand = 0;
  if (readPointer < writePointer ) abstand =  BUFFFERMAX - writePointer + readPointer;
  else if (readPointer > writePointer ) abstand = readPointer - writePointer;
  return abstand;
}

void setup() {
  Serial.begin(115200);

  dac_output_enable(DAC_CHANNEL_1);
  pinMode(33, INPUT_PULLUP);
  pinMode(32, INPUT_PULLUP);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());


  const int port = 4444;
  while (!client.connect(host, port)) {
    Serial.println("connection failed");
    delay(1000);
  }

  timer = timerBegin(0, 2, true); // use a prescaler of 2
  timerAttachInterrupt(timer, &onTimer, true);
  timerAlarmWrite(timer, 5000, true);
  timerAlarmEnable(timer);


}

void loop() {
  int abstand = getAbstand();
  if (abstand <= 800) play = true;

  if ( abstand >= 800) {
    client.write( B11111111 ); // send the command to send new data
    
    // read new data: 
    while (client.available() == 0);
    while (client.available() >= 1) {
      uint8_t value = client.read();
      dataBuffer[writePointer] = value;
      writePointer++;
      if (writePointer == BUFFFERMAX) writePointer = 0;
    }

  }

}

Credits

Julian

2 projects • 19 followers

Stream Your Audio on the ESP32

Things used in this project

Hardware components

Software apps and online services

Story

1. Build the circuit

2. Setting up the code

3. How does it work?

4. Convert the audio file you want to play

5. Let's test it!

Schematics

Schematics

Code

esp32_java_voice_server.ino

Voice_Server.jar

demo.raw

raw server java code

Credits

Julian

Comments

Embed the widget on your own site

Stream Your Audio on the ESP32

Stream Your Audio on the ESP32

Things used in this project

Hardware components

Software apps and online services

Story

1. Build the circuit

2. Setting up the code

3. How does it work?

4. Convert the audio file you want to play

5. Let's test it!

Schematics

Schematics

Code

esp32_java_voice_server.ino

Voice_Server.jar

demo.raw

raw server java code

Credits

Julian

Comments

Related channels and tags