Published December 15, 2015 © MIT

Call Blocker / Telemarketer Stopper

Stop Those Cold Calls Cold!

IntermediateFull instructions provided6,012

Things used in this project

Hardware components

Relay (generic)

transformer

3.3V Zener Diode

ksp013 darlington

headphone jack

RJ11 Jack

22pf Capacitors

200K resistors

.1uF caps

HT9032D Caller ID Decoder

Prototype Shield w/ Headers

3.58Mhz Crystal

10Meg Resistor

Resistor 220 ohm

Resistor 1k ohm

1N4007 – High Voltage, High Current Rated Diode

Floppy drive molex power connector

Software apps and online services

Arduino IDE

Story

1 / 3

Some days it seems like the phone never stops ringing. The caller ID always says "Toll Free Call" or some other nonsense. I wanted a way to just drop these calls. I was going to use an Arduino to watch the caller ID and answer each one of these calls. I was looking at Audio recorder modules but then I got a Linkit One. With it's built in audio mp3 player it was perfect.

Best part is if you play the official "This number has been disconnected" message most telemarketer dialing machines recognize hose three tones at the beginning and remove you from their active dial list......

Step 1: Finding all the Parts

1 / 7

I use a VOIP system in my house but it supplies standard caller ID signaling on its POTS lines. If your going to use this on the PSTN you may want to go with an FCC approved interface or just grab an old US Robotics modem but I don't have to worry about that so I chose the HT9032D. I got these from Tayda Electronics. Really cheap but they only stock the surface mount package. You could pay more and get a dip package from another supplier but I had some oddball adapter boards on hand....

I used a blank Shield prototype board to hold all the parts. I had some RJ-11 connectors and 600 ohm matching transformers in the parts cabinet. I have a habit of buying stuff like this in bulk.....

Step 2: Making Sense of the Data

Live Data Dump from my PBX

A long time ago I got a development board from MeLabs called the Lab-XT. It was for pic micro-controllers and it had support chips for DTMF and CallerID. I was surprised that no one really has any examples for the Arduino world. There is one out there, repeated many times, but it just didn't work for me.

Using the MeLabs Caller ID info page as a guide I set out to build a simple state machine to parse the incoming packet. It may not look simple but I tried to stretch things out so you can follow along in the code. I only implemented the MDMF since that's whats in my house. The SDMF is simpler but don't have an actual dump to go by.

If somebody sends me a terminal log of an SDMF message I will add it to the code. I can replay dumps into the decoder to test it.

And that's the first thing to do. Get a data dump. I used a Prolific USB to serial breakout board to monitor the data out pin. I used Putty to log a few calls and Midnight Commander to view the log in HEX. There are plenty of other terminals and viewers. Use your favorite.

There is a lot of noise on the line but there is no mistaking those 30 U's in a row. Just in case I miss some I test for > 25 U's received. I then look for the 0x80 identifier of the MDMF packet. This is where you would look for a 0x04 if you wanted to also do SDMF decoding.

I then save the packet length so I know when were done.

There are 5 message ID's to watch for and I process each one separately. It ends with a check sum but I ignored that for now. Maybe later. I'd rather see a garbled name than an error message....

The date message seems to be local to the provider. One local voip server was off by 1hr but that was a daylight savings error on the server itself.

I tried a couple of different providers and the messages do not always come in the same order. Sometimes its "Date - Name - Number" and on others it was "Date - Number - Name". YMMV

Step 3: Schematic and Code

There are a lot of parts here but its really a very simple set of circuit blocks. A transistor driving a relay from a digital I/O pin, an analog modem chip and support components, a header for an I2C display, plus the usual decoupling capacitors and protection diodes.

I planned out a circuit board for the shield but I haven't had time to verify the design yet. I added a power jack for a future project with this shield. I may make a few for my friends......

Step 4: Assembling the Shield

1 / 4

I hand wired the prototype. It may not be pretty but it works. If I get some quiet time I'll work on Version 2. I am making two different boards. One for the Dip chip version and one for my oddball wired adapter boards. The blue post-it shows the odd pin-out of these adapters.Be careful what you buy on eBay. Sometimes 50 pieces for $2 is not a bargain.....

Step 5: Power it Up

1 / 5

Since I planned to tap off an existing PC power supply I use in my home monitoring system I got a floppy drive molex power connector from an old worn out PC fan. Just make sure you swap the power pin from the +12V side to the +5V side.

Step 6: Mounting It

1 / 3

I have an old alarm case on the wall in the basement. It houses a PIC micro-controller monitor board that communicates back to my server through an IP to Serial converter. It's been there for over a decade now and probably could use an update. There maybe a second Linkit One going in this cabinet soon......

Step 7: Testing It

1 / 3

I added a define at the top for debugging. If you set it to true it waits for the serial console before it starts up.

There is also an I2C port on the bottom You can connect an LCD with an I2C backpack. if your making a tabletop version this is a nice feature to have.

The debug output follows the machine state and shows the length of each message. I probably should put the "if (debug" thing around every serial.print but I'm lazy and it doesn't seem to bother the Linkit One

Right now its simply one message on a hard coded list. Just add more checks to the blocked callers function. You can use a separate message for each blocked number

With the capabilities on the Linkit One I can easily upgrade this to use the SD card and keep a log of all calls and add a csv file of blocked numbers vs mp3 file names. I just have to write a routine for handling the csv files then maybe a web update form.....

With a unique message for each number I can be sure that the more annoying the caller, the more appropriate will be the message they get!

Step 8: The Future?

1 / 3

What more is there?

I really didn't like the small display. I changed it to use a 20x4. A little bit better but I still will run it headless. This makes it more useful as a tabletop device.

Lately, I noticed that Community Blood Service calls me three times in a row for every blood drive. Maybe a block on the number of calls per day? Since we're all type O they seem to like us but I only need one call since we do talk to each other.

Maybe add a second relay to drive a piezo siren to give a local alert for high priority callers. It wouldn't pick up and play them anything just wake me up or get my attention over the noise in my shop.

Code

CallBlocker.ino

//****************************************************************
//*  Name    : Caller Blocker                                    *
//*  Author  : Robert Joseph Korn                                *
//*  Date    : 10/18/15                                          *
//*  Version : 1.6                                               *
//*  Notes   :                                                   *
//*          :                                                   *
//****************************************************************

#define Serial_Debug false 

#include <Wire.h>  
#include <LiquidCrystal_I2C.h>
#include <LAudio.h>
#define HOOK 2 

LiquidCrystal_I2C lcd(0x20, 20, 4); 
 
static int state=0;
static int o=0;
static int i=0;
static char nam[128];
static char num[25];
static char dat[25];
static int plen=0;
static int nlen=0;
static int dlen=0;
static int mlen=0;
static int len=0;
int SER = 0;
String str = "";


void BlockCallers() {
               if (str == "106"){
                  lcd.setCursor(0,0);
                  lcd.print("Last Call BLOCKED  :");
                  Play_MP3();
                }
}

void setup()
{

  if(Serial_Debug){
     Serial.begin(115200);  
     while(!Serial){
         delay(100);
     }
  }
  
  pinMode(HOOK, OUTPUT);
  digitalWrite(HOOK, LOW); 

  LAudio.begin();
  LAudio.setVolume(6);
  
  lcd.init();    
  lcd.noBacklight();
  delay(400);
  lcd.clear();
  lcd.backlight();
  lcd.setCursor(0,1);
  lcd.print("   Caller ID V1.6 ");
  lcd.setCursor(0,2);
  lcd.print(" Waiting for Caller");
  Serial.println("Waiting for next Caller");
  delay(3500);
 
  Serial1.begin(1200);
}
 
void loop()
{
  Ht9032_get();
  
          if( state == 10 ) 
          {      
            o=0;     
            Serial.println("State: 10 ");
            Serial.print("DATE: ");
            Serial.print(char(dat[0]));
            Serial.print(char(dat[1]));
            Serial.print('/');
            Serial.print(char(dat[2]));
            Serial.println(char(dat[3]));
            Serial.print("TIME: ");
            Serial.print(char(dat[4]));
            Serial.print(char(dat[5]));
            Serial.print(':');
            Serial.print(char(dat[6]));
            Serial.println(char(dat[7]));
            Serial.print("NAME: ");
            for(int i=0;i<nlen;i++)
             {
               Serial.print(char(nam[i]));
             }
            Serial.println("");
            Serial.print("NUMBER: ");
            for(int i=0;i<mlen;i++)
             {
               Serial.print(char(num[i]));
             }
             Serial.println("");

            state=0;
            
            lcd.clear();
            lcd.setCursor(0,0);
            lcd.print("Last Call Received :");
            lcd.setCursor(0,1);
            lcd.print("Date:");
            lcd.print(char(dat[0]));
            lcd.print(char(dat[1]));
            lcd.print('/');
            lcd.print(char(dat[2]));
            lcd.print(char(dat[3]));
            lcd.print(" ");
            lcd.print(char(dat[4]));
            lcd.print(char(dat[5]));
            lcd.print(':');
            lcd.print(char(dat[6]));
            lcd.print(char(dat[7]));
 
            lcd.setCursor(0,2);
            lcd.print("Name: ");
 
            for(int i=0;i<nlen;i++)
             {
               lcd.print(char(nam[i]));
             }
 
            lcd.setCursor(0,3);
            lcd.print("Num :");

            str = "";
 
            for(int i=0;i<mlen;i++)
             {
               lcd.print(char(num[i]));
               str += char(num[i]);
             }    

              BlockCallers();
       }
}

void Play_MP3()
{
      Serial.println("Blocked Caller Detected");
      digitalWrite(HOOK, HIGH); 
      Serial.println("Off Hook");
      delay(1500);  
      Serial.println("Playing message to caller");
      LAudio.playFile( storageFlash,(char*)"Klaxon.mp3");
      delay(7500);
      digitalWrite(HOOK, LOW); 
      Serial.println("On Hook");
      delay(5000);
} 


 
void Ht9032_get()
{
  if (Serial1.available() > 0)  
  {

  SER = Serial1.read(); 
    
   /*
    * states
    * 0 - waiting for U's
    * 1 - waiting for 25 U's and then an 0x80
    * 2 - waiting for packet len
    * 3 - waiting for message id
    * 4 - get name len
    * 5 - receiving name
    * 6 - get number len
    * 7 - receiving number
    * 8 - get date len
    * 9 - receiving date
    * 10 - packet complete
    * 
    * message ids
    * 1 - date
    * 2 - number
    * 4 - number not found reason
    * 7 - name
    * 8 - name not found reason
    * 
    * reasons
    * O - Out of area (no caller ID available)
    * P - Private party (Blocked)
    * 
    */
  switch(state)
  {
    case 0:if (SER==0x55)  
               {
                 state=1;
                 i=1;
 Serial.println("State: 0 ");
               }break;
 
    case 1:if (SER==0x55) 
               {
                 i++;
               }                        
                  
               if(SER==0x80)
               {
                 if(i > 25)
                   {
                      state=2;
                   }
               }
               Serial.println("State: 1 ");             
               break;
               
    case 2:plen = SER; 
               i=0;
               state=3;                                        
               Serial.println("State: 2 ");
               Serial.print("Packet Length: ");
               Serial.println(plen);
               break;
 
    case 3: o++;
              Serial.println("State: 3 ");
              Serial.print("MID: ");
              Serial.println(SER);
              if(SER==1) 
              {
                state=8;
              }
              else if(SER==2)
              {
                state=6;
              }
              else if(SER==4)
              {
                state=6;
              }
              else if(SER==7)
              {
                state=4;
              }
              else if(SER==8)
              {
                state=4;
              }
              break;
 
    case 4:len = SER;
               nlen = len ; 
               o++;
               i=0;
               state=5;                                        
               Serial.println("State: 4 ");
               Serial.print("Data Length: ");
               Serial.println(nlen);
               break;
 
    case 6:len = SER; 
               mlen = len ; 
               o++;
               i=0;
               state=7;                                        
               Serial.println("State: 6 ");
               Serial.print("Data Length: ");
               Serial.println(mlen);
               break;
 
    case 8:len = SER; 
               dlen = len ; 
               o++;
               i=0;
               state=9;                                        
               Serial.println("State: 8 ");
               Serial.print("Data Length: ");
               Serial.println(dlen);
               break;
 
  
    case 5:nam[i]=SER;  
            i++;
            o++;
              if( i > nlen - 1 ) 
          {  
            state=3;
            i=0;                              
          }

          if( o > plen - 1 ) 
          {  
            state=10;
          }
          Serial.println("State: 5 ");
          break;
          
    case 7:num[i]=SER;  
            i++;
            o++;
              if( i > mlen - 1 ) 
          {  
            state=3;
            i=0;                              
          }

          if( o > plen - 1 ) 
          {  
            state=10;
          }
          Serial.println("State: 7 ");
          break;
          
    case 9:dat[i]=SER;  
            i++;
            o++;
              if( i > dlen - 1 ) 
          {  
            state=3;
            i=0;                              
          }

          if( o > plen - 1 ) 
          {  
            state=10;
          }
          Serial.println("State: 9 ");
          break;
          
     default:break;
   }
  }
}

Credits

Robert Korn

15 projects • 27 followers

I Made the Internet of Things before people had a name for it.

Call Blocker / Telemarketer Stopper

Things used in this project

Hardware components

Software apps and online services

Story

Step 1: Finding all the Parts

Step 2: Making Sense of the Data

Step 3: Schematic and Code

Step 4: Assembling the Shield

Step 5: Power it Up

Step 6: Mounting It

Step 7: Testing It

Step 8: The Future?

Schematics

Schematic

Code

CallBlocker.ino

Credits

Robert Korn

Comments

Embed the widget on your own site

Call Blocker / Telemarketer Stopper

Call Blocker / Telemarketer Stopper

Things used in this project

Hardware components

Software apps and online services

Story

Step 1: Finding all the Parts

Step 2: Making Sense of the Data

Step 3: Schematic and Code

Step 4: Assembling the Shield

Step 5: Power it Up

Step 6: Mounting It

Step 7: Testing It

Step 8: The Future?

Schematics

Schematic

Code

CallBlocker.ino

Credits

Robert Korn

Comments

Related channels and tags