WiFi Messenger

#include <Wire.h> 
#include <LiquidCrystal_I2C.h>
#include <ESP8266WiFi.h>
#include <WiFiUDP.h>

// wifi connection variables
const char* ssid = "xxxxxxx";
const char* password = "xxxxxxxxx";
boolean     wifiConnected = false;

// berichten             0123456789012345
const char bericht0[] = "                ";
const char bericht1[] = "Eten !          ";
const char bericht2[] = "Komen nu!       ";
const char bericht3[] = "Kom je zo?      ";
const char bericht4[] = "GSM aan lader   ";
const char bericht5[] = "Wij zijn ff weg ";
const char bericht6[] = "We gaan !!      ";
const char bericht7[] = "Kom je tv kijken?";
const char bericht8[] = "Laat maar !!!   ";

const char* berichten[]= { bericht0, bericht1, bericht2, bericht3, bericht4, bericht5, bericht6, bericht7,bericht8}; 
const byte Max_berichten = 9;

// pin definitions
byte LedPin = 2;
byte Button1 = 13;

byte RotA = 12;
byte RotB = 14;
byte RotS = 16;

// Rotary enc
static volatile int globalCounter = 0 ;
byte flag;
byte Last_RoB_Status;
byte Current_RoB_Status;

// LCD
LiquidCrystal_I2C lcd(0x27,16,2);

// UDP variables
unsigned int  localPort = 8888;
WiFiUDP       UDP;
boolean       udpConnected = false;
char          packetBuffer[UDP_TX_PACKET_MAX_SIZE]; //buffer to hold incoming packet,
char          SendBuffer[256] ; // a string to send back
char          delivered[] = "Ack";
char          uitgezet[]  = "uitgezet";
IPAddress     ip(192, 168, 0, 102); 


void setup() {
  Serial.begin(115200);

  // initialize LCD
  lcd.begin();
  lcd.backlight();
  lcd.clear();
  
  // Initialise wifi connection
  wifiConnected = connectWifi();
  // only proceed if wifi connection successful
  if (wifiConnected) {
    udpConnected = connectUDP();
    if (udpConnected) {
      // nothing all is done in functions
    }
  }
  // initialise pins
  pinMode(LedPin, OUTPUT);
  pinMode(Button1, INPUT_PULLUP);
  pinMode(RotA, INPUT);
  pinMode(RotB, INPUT);
  pinMode(RotS, INPUT);

  lcd.setCursor(0,0);
  lcd.println("Wifi verbinding ");
}


void loop() {
  // Handle Rotary Encode input
  rotaryDeal();
  rotaryClear();

  // Handle Wifi
  if (wifiConnected) {
    if (udpConnected) {
      // if there’s data available, read a packet
      int packetSize = UDP.parsePacket();
      if (packetSize)
      {
         UDP.read(packetBuffer, UDP_TX_PACKET_MAX_SIZE);
         int i=0;
         // check if previous message was received
         while(i<3 && packetBuffer[i] == delivered[i]) 
         {
          Serial.print(packetBuffer[i]);
          i++;
         }
         if(i==3)
         {
          lcd.setCursor(0,1);
          lcd.print("Ontvangen");
          Serial.print("Ontvangen");
         }
         else
         {  // other packet 
            // check if tone is turned off
          i=0;
          while(i<3 && packetBuffer[i] == uitgezet[i]) 
          {
            Serial.print(packetBuffer[i]);
            i++;
          }
          if(i==3)
          { 
            lcd.setCursor(0,1);
            lcd.print("Uitgezet ");
            Serial.print("Uitgezet");
          }
         }
      }

      // Send the selected message on button press
      if(!digitalRead(Button1))
      {
        if(globalCounter==0)
        {
          lcd.setCursor(0,0);
          lcd.print("geen bericht ");
          lcd.setCursor(0,1);
          lcd.print("gekozen !!!");
        }
        else
        {
          byte l = strlen(berichten[globalCounter]);
          SendBuffer[0] = globalCounter;
          SendBuffer[1] = l;
          for(int i = 0; i<l; i++)
          {
            SendBuffer[i+2] = berichten[globalCounter][i];
          }
          
          bool success = UDP.beginPacket(ip,8888);
          if(success) Serial.println("Succes ...");
  
          UDP.write(SendBuffer,l+2);
            if(UDP.endPacket())
            {
              Serial.print("Send succes : ");
            }
            else
            {
              Serial.println("Not Sent : ");
            }
           lcd.setCursor(0,1);
           lcd.print("               ");
        }
      }
    }
  }
}

void rotaryClear(void)
{ // reset rotary encode when pressed
  if(digitalRead(RotS) == 0)
  {
    globalCounter = 0;
    Serial.println(globalCounter);
    delay(1000);
    
    lcd.setCursor(0,0);
    lcd.print(berichten[globalCounter]);
    lcd.setCursor(0,1);
    lcd.print(berichten[globalCounter]);
  }
}


void rotaryDeal(void)
{ // handle turning the rotary encode
  Last_RoB_Status = digitalRead(RotB);

  while(!digitalRead(RotA)){
    Current_RoB_Status = digitalRead(RotB);
    flag = 1;
  }

  if(flag == 1){
    flag = 0;
    if((Last_RoB_Status == 0)&&(Current_RoB_Status == 1)){
      globalCounter ++;
    }
    if((Last_RoB_Status == 1)&&(Current_RoB_Status == 0)){
      globalCounter --;
    }
  
    if(globalCounter<0) globalCounter = Max_berichten-1;
    if(globalCounter>=Max_berichten) globalCounter = 0;
    lcd.setCursor(0,0);
    lcd.print(berichten[globalCounter]);
  }
}


// connect to wifi – returns true if successful or false if not
// came from standaard example
boolean connectWifi() {
  boolean state = true;
  int i = 0;
  WiFi.begin(ssid, password);
  Serial.println("");
  Serial.println("Connecting to WiFi");

  // Wait for connection
  Serial.print("Connecting");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
    if (i > 10) {
      state = false;
      break;
    }
    i++;
  }
  if (state) {
    Serial.println("");
    Serial.print("Connected to ");
    Serial.println(ssid);
    Serial.print("IP address: ");
    Serial.println(WiFi.localIP());
  }
  else {
    Serial.println("");
    Serial.println("Connection failed.");
  }
  return state;
}

// connect to UDP – returns true if successful or false if not
// came from standard example
boolean connectUDP() {
  boolean state = false;

  Serial.println("");
  Serial.println("Connecting to UDP");

  if (UDP.begin(localPort) == 1) {
    Serial.println("Connection successful");
    state = true;
  }
  else {
    Serial.println("Connection failed");
  }
  return state;
}