Published January 17, 2021 © GPL3+

Reaction Timer using 3x7 segment LED displays

Times how long you take to respond to the go signal. Uses 3x7 Segment LED displays driven by 3 4026B decade counters.

BeginnerFull instructions provided1,464

Reaction Timer using 3x7 segment LED displays

Things used in this project

Hardware components

Arduino UNO

Either a UNO or a NANO will work with this project

7 Segment LED Display, InfoVue

Must be low current as we are connecting direct to the 4026B. I used a Multicomp Pro LS0565SRWK

4026B Decade Counter

5 mm LED: Red

5 mm LED: Green

Tactile Switch, Top Actuated

Through Hole Resistor, 330 kohm

Resistor 1k ohm

Buzzer

Passive (not active) buzzer. This link does not work but any passive busser should work.

Story

I decided to make a reaction timer as I wanted to learn about and experiment with the 7 segment LED display driven by a 4026B decade counter and built it round the Arduino UNO/Arduino NANO.

The timer operates as follows:

1. On connecting power, the red Get Ready light flashes twice to show that the system has booted up and the LED displays shows 000.

2. Press the Start button and the red Get Ready light turns on for a random time between 1 and 5 seconds.

3. The red light goes out, the green Go light turns on and the LED displays start to count in milliseconds.

4. Press the Reaction button as quickly as possible and the time stops counting and the green light goes out. If the user takes longer than 999 milliseconds then the buzzer is sounded and the display reset to 000.

5. The time of the last reaction, in milliseconds, will remain on the display until the Start button is pressed again.

7 Segment display

The 7 segment display used has 2 rows of 5 pins located at the top and bottom. 7 pins are used for the 7 LED segments that form the number or letter to be displayed and the 8th pin controls the decimal point. The remaining 2 pins are common connections, in the middle of the top and bottom row. The display I used was a Multicomp Pro LS0565SRWK. The pin layout is as follows:

The LED segments must be protected with a series resistor to reduce the voltage. In theory, you should use a separate resistor for each segment to get a consistent brightness, however for simplicity I have used one resistor between the common pin and negative ground. This will mean that some numbers with fewer lit segments, e.g. 1, will be brighter than say the 8. If you are not happy with this then you can use 7 separate resistors, one on each of the segment pins.

I have used a 330 ohm resistor. Please adjust this as required to ensure that the voltage drop across the LED segments and the current are within the limits of the display you have used.

4026B Decade counter

The 4026B decade counter is an old style chip so it has limited power output but this is sufficient for our requirements. Most decade counters have coded output in binary, however the 4026B has seven output pins and powers them in a pattern that matches the pins of the 7 segment display. Hence, no driver is required to convert binary to the seven segment pattern.

The pin layout of the 4026B is as follows:

4026B Pin Layout

Pins are used as follows:

Pin 1 – Clock: Transitions when moved from Low to High and advances count by 1.

Pin 2 – Clock inhibit/disable: When High will stop counting. So connected to ground in our project.

Pin 3 – Display enable in: When High the current count is reflected in the display out pins a to g, so connected to the supply voltage in our project as we want the count displayed.

Pin 4 – Display enable out: Reflects the state of pin 3 to pass to other counters.

Pin 5 – Carry out: This pin shifts from Low to High when the counter reaches 9 and goes back to 0. This can act as a clock input for a second 4026B timer, for example to show the tens digit.

Pin 8 – 0v: The chip requires its own power connection and pin 8 is connected to ground (-ve terminal)

Pin 14 - Ungated “C” Segment: Can be used to restart the count after it has counted 0, 1 and 2. For use when displaying time in 12 hour format.

Pin 15 – Reset: Active on High. Resets the counter to 0 when this pin goes High.

Pin 16 - +V: Positive voltage supply. Normally from 3v to 15v but check the data sheet for the chip you have.

Other pins – Output pins: 7 output pins corresponding to the segments in the LED display.

The program

The program is commented so hopefully easy to follow. The only aspect to mention here is the clock output.

The tone() function generates a square wave, from LOW to HIGH and back, of the specified frequency. We are outputting a frequency of 1000hz which causes pin 7 to go high once a millisecond. This pin is connected to the clock input of the units counter resulting in the display counting in milliseconds.

No duration is set for the tone so it will continue until the user presses the reaction button and we call noTone() to stop the output.

Arduino pins used

I have not used pins D0 and D1 as these are also used for serial communication. Hence, if you wanted to change the program to use the serial monitor to display the value of “elapsed”, to check the timer was accurate, it would stop the timer working properly as it would change the INPUT_PULLUP setting for the pin.

Code

Reaction Timer

// Reaction Timer
// Paul Brace
// January 2021

#define START_BUTTON 2
#define REACTION_BUTTON 3
#define GET_READY_LIGHT 4
#define GO_LIGHT 5
#define BUZZER 6
#define TIME_DISPLAY 7
#define TIME_RESET 8
#define TOO_LONG 100  // Tone
#define DURATION 250  // Of tone

bool started; // True when timer running
int elapsed;  // Records the time taken in milliseconds to react 
              // will be same as time displayed on the 3 digits

void setup() {
  // Set Pins
  pinMode(START_BUTTON, INPUT_PULLUP);
  pinMode(GET_READY_LIGHT, OUTPUT);
  pinMode(GO_LIGHT, OUTPUT);
  pinMode(REACTION_BUTTON, INPUT_PULLUP);
  pinMode(TIME_DISPLAY, OUTPUT);
  pinMode(TIME_RESET, OUTPUT);
  // Flash light twice to show ready
  for (int i = 0; i < 2; i++){
    digitalWrite(GET_READY_LIGHT, HIGH);
    delay(500);
    digitalWrite(GET_READY_LIGHT, LOW);
    delay(500);
  }
  // Put into wait state
  started = false;
  ZeroTimer();
}

void ZeroTimer(){
      // This will zeroise the time displayed on the 3 digits
      digitalWrite(TIME_RESET, HIGH);
      delay(10);
      digitalWrite(TIME_RESET, LOW);
}

void WaitForStart(){
  // Will wait for the start button to be pressed
  // Note we are using PULLUP on the pin so will be HIGH by default
  // When pressed connects the pin to ground pulling it LOW
  while (started == false){
    if (digitalRead(START_BUTTON) == LOW){
      ZeroTimer();
      // Display the get ready light
      digitalWrite(GET_READY_LIGHT, HIGH);
      // Pause for a random delay between 1 and 5 seconds
      delay(random(1000, 5000));
      // Set started so will exit at end of loop
      started = true;
      //Turn out the get ready and turn on the go light 
      digitalWrite(GET_READY_LIGHT, LOW);
      digitalWrite(GO_LIGHT, HIGH);
      // Record time when start was pressed
      elapsed = millis();
      // Start the timer display
      // Output a square wave at 1000hz to record count of miliseconds
      // on the LED displays
      tone(TIME_DISPLAY, 1000);
    }
  }
}

void loop() {
  // If in wait state the wait for start to be preseed
  if (started == false){
    WaitForStart();
  }
  // Each loop check if the reaction button has been pressed
  if (digitalRead(REACTION_BUTTON) == LOW){
    // Stop the timer counting up
    noTone(TIME_DISPLAY);
    // Calculate the time it took to respond and check if greater than 999 milliseconds
    // 999 millisecionds being the maximum the 3 digits can show
    elapsed = millis() - elapsed;
    // Turn out go light
    digitalWrite(GO_LIGHT, LOW);
    // Check if took longer than 999 millisecons and, if so, sound buzzer and zero display
    if (elapsed > 999){
      ZeroTimer();
      tone(BUZZER, TOO_LONG, DURATION);
      delay(DURATION + 50);  // creates a very short pause between the tones
      tone(BUZZER, TOO_LONG, DURATION * 2);
    }
    // Go back into wait state
    // Timer will display last reaction time, if less that 999 millisconds,
    // until start pressed again
    started = false;
  }
}

Credits

paulsb

4 projects • 28 followers

Reaction Timer using 3x7 segment LED displays

Things used in this project

Hardware components

Story

7 Segment display

4026B Decade counter

The program

Arduino pins used

Schematics

Reaction Timer Schema

Code

Reaction Timer

Credits

paulsb

Comments

Embed the widget on your own site

Reaction Timer using 3x7 segment LED displays

Reaction Timer using 3x7 segment LED displays

Things used in this project

Hardware components

Story

7 Segment display

4026B Decade counter

The program

Arduino pins used

Schematics

Reaction Timer Schema

Code

Reaction Timer

Credits

paulsb

Comments

Related channels and tags