Published October 30, 2017 © GPL3+

Automate Bluesound's Node with Amplifier and Alexa Control

The Node is an audiophile streamer. However the convenience is hampered by the need to switch on/off the amplifier. This automates the task.

IntermediateFull instructions provided4 hours2,793

Automate Bluesound's Node with Amplifier and Alexa Control

Things used in this project

Hardware components

Particle Photon

ns-rs232

Software apps and online services

Amazon Web Services AWS Lambda

Amazon Alexa Alexa Skills Kit

Story

What's this?

The Node is an audiophile streamer, that you can connect to any existing stereo system. That's the advantage, as you can use whatever your setup you so much painstakingly put together, adding modern, high quality streaming. However, the convenience is hampered by the need to switch on/off the amplifier. This automates the task, by detecting when the Node is playing or not and accordingly switching the amplifier. Additionally, I added some simple commands for Amazon's Alexa to be able to pause the music, skip to the next song, or back.

This project builds on and enhances on previous projects I did, and please refer to those for detailed explanations and instructions:

The Alexa serial controller https://www.hackster.io/saka/alexa-voice-control-for-almost-any-amplifier-tv-cd-dvd-87fff1

Sonos controller https://www.hackster.io/saka/sonos-controller-with-wemo-switch-and-alexa-echo-speech-16a794

My Setup

I have an amplifier with 3 inputs:

turntable

Node

Alexa (for convenience, when it is more important for me to quickly ask to play something than quality).

I have built a controller for the amplifier, see the description of the project under the link I posted in the intro. The controller helps me with functions like turning on the amplifier, changing volume, etc. through Alexa voice control. However, I realized that when using the Node, even if I don't have to look anymore for the remote, still there are two separate functions I need to do perform: ask Alexa to turn on the amp and use the BlueOS app to select the music I want to stream. Previously, I built a Sonos controller and using some principles and modified code from that project, I was able to completely automate the functionality; now it's enough for me to start playing a song on the Node and the amp turns on automatically. While I was at that I also added some simple voice control, I can ask Alexa to e.g. skip to next song.

Bluesound apparently does not support APIs. However, I found a post on a forum with quite detailed description: https://helpdesk.bluesound.com/discussions/viewtopic.php?f=4&t=2293

I did not test them all, and seems there are some changes (e.g. at least when playing on Spotify, the status is "stream" not "play". Overall, just works for for the purpose of the scope of this project.

Changes to Lambda

This project relies mainly on firmware in the Particle, which is documented in the next section. In principle, one could not touch at all the Alexa functionality, as this project could be thought as orthogonal to that one (apart from controller hardware, that's shared). However, if you want to kill two birds with one stone the cherry on the cake is the ability to use Alexa for few simple commands, like going to the next song. With such evocation, the Lambda code triggers a new function on the Particle ("Node").

       else if (namespace === "Alexa.PlaybackController") { 
           krellSerialCommand = event.directive.header.name 
           name = krellSerialCommand; 
           funcName = "Node"; 
       }

In order for the above to work, it is necessary to also modify the device discovery by adding the Playback controller:

           { 
             "type": "AlexaInterface", 
             "interface": "Alexa.PlaybackController", 
             "version": "1.0", 
             "supportedOperations" : ["Play", "Pause", "Stop", "Next", "Previous"] 
           }

I have additionally done a change, where instead of creating one device, I effectively copied the discovery for each input on the amplifier, with different names ("Record Player", "Music Player, "Stereo"). This is a small twist but again enables to save one step by evoking a specific device, the amplifier input is also accordingly adjusted. That change is in turn utilized in the Particle firmware (where instead of just passing the command for on/off, I append to which device it refers to (e.g. "1PWRZbluesoundOn"). This is however optional, so I'm not copying the Lambda code for it.

Particle firmware

The full code is saved in this project. Few explanations.

byte nodeIP[] = { 192, 168, 1, 182 }; //put your Node_IP_address

Here you need to change to the IP address of your Node. You can find it in the BlueOS app under Settings/ Diagnostics. You also need to go to your router and make sure you assign the address as a static one; each router would have different menu for it but likely you find it under DHCP settings.

Otherwise, main routine it to check every 1 second what's the status on the Node. The controller send the inquiry http://192.168.1.182:11000/Status, and looks at the response between <state> and </state>. If it detects a change to a previous states, it acts accordingly, by e.g. switching on the amp if the state changed to "stream".

The function controlNode:

int controlNode(String command) 
{ 
   if (command != NULL) { 
       if (command == "Play") nodeCommand(nodePlay); 
       else if (command == "Pause") nodeCommand(nodePause); 
       else if (command == "Stop") nodeCommand(nodePause); 
       else if (command == "Next") nodeCommand(nodeSkip); 
       else if (command == "Previous") nodeCommand(nodeBack); 
       return 1; 
   } 
   else return -1; 
}

Is the one called by the Lambda function, triggered by Alexa (as described in the previous chapter).

Code

Particle Photon firmware

/*
  Krell- serial controller
  Waldemar Sakalus - SAKA
  version 10272017
 */

unsigned long resetTimer = millis();

TCPClient node;
byte nodeIP[] = { 192, 168, 1, 182 }; //put your Node_IP_address
String nodeResponse;

String nodeStatus = "Status";
String nodePlay = "Play";
String nodePause = "Pause";
String nodeSkip = "Skip";
String nodeBack = "Back";

const unsigned long smartInterval = 1000; //1s probing time, how often Node is checked whether playing/ stopped
unsigned long smartTimer = millis();

String nodeState = "";
String previousState = "";


void setup() {
    Serial1.blockOnOverrun(false);
    Serial1.begin(9600, SERIAL_8N1);
    Particle.function("KrellSerial", controlAmplifier);
    Particle.function("Node", controlNode);
}

void loop() {
    if (smartTimer < millis()) {
        nodeCommand(nodeStatus);
        nodeState = tryExtractString(readNodeResponse(),"<state>","</state>");
        if (previousState != nodeState) {
            if (nodeState == "play" || nodeState == "stream") {
                Serial1.println("1PWRZ");
                Serial1.println("SS2MZ");
            }
            else if (nodeState == "pause") {
                Serial1.println("0PWRZ");
            }
            previousState = nodeState;
        }
        smartTimer = millis() + smartInterval;
    }
    
    // Reset after 12h of operation
    // ==================================
    if (millis() - resetTimer > 43200000) {
        System.reset();
    }
}

int controlAmplifier(String command)
{
    if (command != NULL) {
        if (command.startsWith("0PWRZ")) {
            Serial1.println("SS1MZ"); //defaults to input S1 before switching amplifier off
            Serial1.flush();
            //if (command.endsWith("bluesoundOff")) {
            stopNode();
            //}
            Serial1.println("0PWRZ");
        }
        else if (!(command.startsWith("1PWRZ"))) {
            Serial1.println(command);
            if (command.startsWith("SS2MZ")) startNode();
            else if (command.startsWith("SS1MZ") || command.startsWith("SS2MZ")) stopNode();
        }
        else if (command.startsWith("1PWRZ")) {
            Serial1.println("1PWRZ");
            Serial1.flush();
            if (command.endsWith("stereoOn")) Serial1.println("SS3MZ"); //defaults to input S3
            else if (command.endsWith("recordOn")) Serial1.println("SS1MZ"); //defaults to input S1
            else if (command.endsWith("bluesoundOn")) {
                Serial1.println("SS2MZ"); //defaults to input S2
                startNode();
            }
            else if (command.endsWith("echoOn")) Serial1.println("SS3MZ"); //defaults to input S3
        }
        return 1;
    }
    else return -1;
}

int controlNode(String command)
{
    if (command != NULL) {
        if (command == "Play") nodeCommand(nodePlay);
        else if (command == "Pause") nodeCommand(nodePause);
        else if (command == "Stop") nodeCommand(nodePause);
        else if (command == "Next") nodeCommand(nodeSkip);
        else if (command == "Previous") nodeCommand(nodeBack);
        return 1;
    }
    else return -1;
}

void startNode() {
    nodeCommand(nodeStatus);
    nodeState = tryExtractString(readNodeResponse(),"<state>","</state>");
    if (nodeState == "pause") nodeCommand(nodePlay);
}

void stopNode() {
    nodeCommand(nodeStatus);
    nodeState = tryExtractString(readNodeResponse(),"<state>","</state>");
    if (nodeState == "play" || nodeState == "stream") nodeCommand(nodePause);
}

void nodeCommand(String command)
{
    if (node.connect(nodeIP, 11000))
    {
        String post = "GET /";
        post += command;
        post += " HTTP/1.1\r\n";
        post += "Host: ";
        post += nodeIPString();
        post += ":1400\r\n";
        post += "Cache-Control: no-cache\r\n\r\n";
        //Serial.println(post);
        node.print(post);

        delay(10);
    }
    else Serial.println("connection failed");
}

String readNodeResponse() {
    unsigned long lastdata = millis();
    String nodeResponse = "";
    while (node.connected()  || (millis()-lastdata < 500)) { //500ms timeout
        if (node.available()) {
            char c = node.read();
            nodeResponse += c;
            lastdata = millis();
        }
    }
    node.flush();
    node.stop();
    return nodeResponse;
}


String nodeIPString(){
    String addressIP = "";
    for (int i = 0; i < 4; i++) {
        addressIP += nodeIP[i];
        if (i < 3) {
            addressIP += ".";
        }
    }
    return addressIP;
}

String tryExtractString(String str, const char* start, const char* end) {
    if (str == NULL) {
        return "";
    }

    int idx = str.indexOf(start);
    if (idx < 0) {
        return "";
    }

    int endIdx = str.indexOf(end);
    if (endIdx < 0) {
        return "";
    }

    return str.substring(idx + strlen(start), endIdx);
}

Automate Bluesound's Node with Amplifier and Alexa Control

Things used in this project

Hardware components

Software apps and online services

Story

What's this?

My Setup

Changes to Lambda

Particle firmware

Schematics

Seral controller

Code

Particle Photon firmware

Credits

Waldemar Sakalus

Comments

Embed the widget on your own site

Automate Bluesound's Node with Amplifier and Alexa Control

Automate Bluesound's Node with Amplifier and Alexa Control

Things used in this project

Hardware components

Software apps and online services

Story

What's this?

My Setup

Changes to Lambda

Particle firmware

Schematics

Seral controller

Code

Particle Photon firmware

Credits

Waldemar Sakalus

Comments

Related channels and tags