Tiny Cheese Maker

This project is a mechanism to automate the process of making simple cheeses.

Hacking Story

This was most of our team's first experience with a hackathon, so it was an exciting and educational experience for all of us.

Inspired by the above video and our recent experience with cheesemaking, we decided to pursue the goal of creating a tiny cheese making machine with the easiest cheese we could make: Goat Cheese. Cheesemaking is a fun and easy hobby for anyone with a kitchen and a probe thermometer.
We used this recipe for simple fresh goat cheese. 

The basic recipe is very easy: Heat goat milk to 180°F, add lemon juice at 8% of the milk volume, strain.

Fabrication Hacking Story

We knew only one sensor was needed - the temperature sensor. However making a mechanism that would allow us to heat a liquid, mix in another, and then drop it into the cheese cloth was an interesting fabrication experience. We went through several steps to work out our final scheme.

At first, our plan was to move the milk around, heating it, then moving it off of heat, dumping it into lemon juice, then dumping that into the strainer. However, this would have required a complicated series of servos to move a container on many dimensions.

From there, we realized we could change our approach: we didn't need to move the milk, we needed to move the heat and milk away from each other, this inspired the next iteration: where we would rotate the fire away from the milk, and the juice underneath by using a single rotating platform, then we could move the juice/milk over the strainer

Finally, we turned it around again: we just needed a way to put the juice and milk together, it didn't need to move the containers around at all - we could dump the juice into the cooked milk without moving anything, then simply dump that directly into the strained cloth, giving us the final product.

Instructions

Device Construction

The device is made of a simple wooden frame with a rotating platform at the bottom that supports the heat source and strainer.

Two wires attached to servos are suspended above the platform, holding 2 condiment cups to contain liquids.

Code

#include "rgb_lcd.h"
#include <Servo.h>

rgb_lcd lcd;
const int colorR = 255;
const int colorG = 0;
const int colorB = 0;

const int pinTemp = A0;  // pin of temperature sensor
const int pinCandle = 6; // bottom, swaps heat source with strainer
const int pinLemon = 3; // top, dumps lemon juice
const int pinCheese = 5; // middle, dumps cheese to strainer
const int pinButton = 2; // manually rotate and reset servos

const int minRotation = 0;
const int maxRotation = 180;

Servo servoCandle;
Servo servoLemon;
Servo servoCheese;

double TempC, TempF, Setpoint;
int B = 3975; // B value of the thermistor
float resistance;

boolean rotated;
boolean pinButtonWasPressed;

void setup()
{
    Serial.begin(9600);
    pinMode(pinButton, INPUT);
    servoCandle.attach(pinCandle);
    servoLemon.attach(pinLemon);
    servoCheese.attach(pinCheese);
    Setpoint = 180; // temp needed to produce milk coagulation
    rotated = false;
    pinButtonWasPressed = false;
    delay(1000);

    lcd.begin(16, 2);
    lcd.setRGB(colorR, colorG, colorB);
    lcd.print("#TheTinyCheese");
}

void Unrotate()
{
  if (rotated)
  {
    servoCandle.write(minRotation);
    servoLemon.write(minRotation);
    servoCheese.write(minRotation);
    rotated = false;
  }
}

void Rotate()
{
  if (!rotated)
  {
    delay(500);
    servoCandle.write(maxRotation);
    delay(1000);
    servoLemon.write(maxRotation);
    delay(1000);
    servoCheese.write(maxRotation);
    rotated = true;
  }
}

void loop()
{
    int val = analogRead(pinTemp); // get analog value
    resistance = (float)(1023-val)*10000/val; // get resistance
    TempC = 1/(log(resistance/10000)/B+1/298.15)-273.15; // calc temperature
    TempF = (TempC * 9.0)/5.0+32.0;

    lcd.setCursor(0, 1);
    lcd.print(TempF);

    delay(1000);

    if (digitalRead(pinButton)) {
      delay(500);
      Rotate();
      pinButtonWasPressed = true;
    }
    else if (pinButtonWasPressed)
    {
      delay(500);
      pinButtonWasPressed = false;
      Unrotate();
    }
    else if (TempF > Setpoint) {
      delay(5000);
      Rotate();
    }
}