Overview
Things
Story

Overview
Build the breadboard
Update Arduino IDE with Blynk library
Add Blynk app to phone
Create Blynk app on phone
Download the Arduino programs
Test with interactive_servo
Test with blynk_joystick

Published July 8, 2019 © GPL3+

Control a Mini Pan-Tilt Camera Mount with Your Phone

This is a simple project to control a mini camera mount with your phone over WiFi.

IntermediateProtip2 hours2,099

Control a Mini Pan-Tilt Camera Mount with Your Phone

Things used in this project

Hardware components

Mini-Pan-Tilt-Camera-Mount with servos by Ximimark

4 channel logic level converter

Breadboard (generic)

Male/Male Jumper Wires

SparkFun break away header pins, long

Capacitor 1000 µF

Software apps and online services

Arduino IDE

Blynk

Story

Overview

This project uses Blynk and Servo libraries. The servo library is already part of Arduino IDE. You will need to download the Blynk library to Arduino IDE and the Blynk App to your phone. Blynk is free for small projects.
It is assumed you have some knowledge with Arduino IDE and ESP8266
A bi-directional 3.3v-5.0v logic level converter is needed for the servo signal pins. The ESP8266 runs at 3.3 volts, while the servo motors require 5 volts. The 5 volts comes from VIN, which is the USB power.
You need an assembled mini pan-tilt camera mount (like Ximimark), or similar. See my previous project on how to assemble the mount.

Build the breadboard

There is a Fritzing diagram you can download in addition to the pictures below.

Secure the pan-tilt mount to the motherboard with long male breakaway headers. Use 2 pins per corner, secure at lease 2 corners.

Secure the camera mount

Wire up the logic level converter. Be mindful of the low and high voltage sides.

Logic Level Converter Wiring

Add power and ground to the servos. Add the 1000uf capacitor (for stable power to servos).

Servo Power Wiring

Update Arduino IDE with Blynk library

Start Arduino
Go to Manage Libraries

Manage Arduino Libraries

Type in "blynk"
Find it.
Click on More Info, then click on "install"

Install Blynk

Add Blynk app to phone

Go to your favorite App store
Search for Blynk
Click on Install

Create Blynk app on phone

See picture below for some tips before you start.

Blynk Primer

Start the Blynk app.
Tap to add a new project.
Type in project name, Select ESP8266 device. Select WiFi connection type. Tap create. Blynk will send you an Auth Key which you will need for the Arduino program.

After you tap Create (project), you will be in the "Joystick Project".
Tap the + at the top right for the widget menu.
Select the joystick widget.

Add joystick widget to project

You will be back at the project screen
Tap the joystick widget to configure
Select Virtual Pins V0 & V1
Edit the ranges as shown in the picture below
Tap <- to return to the Joystick project.
The project is ready to run, but we still need to add and configure the Arduino program(s).

Configure joystick

Download the Arduino programs

Download/copy the 2 arduino programs; the interactive_servo and the blynk_joystick programs.
Edit and save the blynk_joystick program. Add your WiFi SSID and password. Add the Blynk auth key that was emailed to you when you created the Blynk joystick project.

Test with interactive_servo

The interactive_servo is a good first test to verify your breadboard buildout. The test only tests 1 servo, the servo connected to pin 12. You can plug in different servos for testing.

Start Arduino IDE
Select the interactive_servo test.
Select SparkFun ESP8266 Thing Dev, or similar ESP8266 device.
Select your Port
Click on Serial Monitor
Compile and download the test to the ESP8266 Thing.
Type in a value between 0 and 180 in the Serial Monitor and hit Enter/Send. The servo should move. Test the range of the servo, which is usually more that 0 and less than 180.

Test with blynk_joystick

The blynk_joystick should be updated with your ssid, password, and auth key.

From the Arduino IDE, select the blynk_joystick test.
Select SparkFun ESP8266 Thing Dev, or similar ESP8266 device.
Select your Port
Click on Serial Monitor
Compile and download the test to the ESP8266 Thing.
On your cell phone, select the Blynk Joystick project, and tap the run icon (upper right).
Move the joystick on your cell phone and the pan-tilt mount should move, and you should see the servo commands on the Serial Monitor.
If nothing works: a) retest with the interactive_servo program, b) recheck your SSID, PASSWORD, and AUTH KEY.
Good luck! :-)

Code

/*****************************************************************************
* Program Name: interactiveServo
* Author: Bob
* 
* Move a servo interactively with the Arduino IDE Serial Monitor
* 
* based upon  BARRAGAN <http://barraganstudio.com>
* and Scott Fitzgerald http://www.arduino.cc/en/Tutorial/Sweep
* 
* ----------------------------------------------------------------------------
* Change History
* Date         Ver    Description
* ----------   ----   --------------------------------------------------------
* 02/25/2019   V1.0   Initial development
*****************************************************************************/
#include <Servo.h>

int    servoPIN = 12; //servo signal pin
int    servoPos = 90; //initial servo position
String inString = ""; //string to hold incomming command
Servo  servo;         //create servo object to control the servo



/*********************************************************************
 *  setup()
 *  Called once at power on
 ********************************************************************/
void setup() {
  servo.attach(servoPIN); // attaches the servo pin to the servo object
  servo.write(servoPos);  // set servo to initial position
  
  Serial.begin(115200);
  Serial.println("");
  Serial.println("-----------------------------------------------------------------------");
  Serial.println("- Welcome to Interactive Servo");
  Serial.println("- Open the serial monitor and ensure the Line Ending option (at bottom");
  Serial.println("- of the monitor window) is set to NewLine. To move the servo, enter a ");
  Serial.println("- number from 0 to 180(at top of monitor window)and press ENTER/SEND");
  Serial.println("-----------------------------------------------------------------------");
  Serial.print("Servo at "); Serial.print(servoPos); Serial.println(".\tNew position?");
}



/*********************************************************************
 *  loop()
 *  Main processing loop. Called after setup()
 ********************************************************************/
void loop() {
  
  /*wait till we get a command from serial monitor*/
  while(Serial.available()) {
    char inChar = Serial.read();
    if(inChar == '\n')  {
      int num = inString.toInt();
      inString = "";

      /*if valid number move servo*/
      if((num >= 0) && (num <= 180)) {
        for(int i = servoPos; i != num; i += (servoPos < num? 1 : -1)) {
          servo.write(i); delay(15); //move servo +/- 1 degree every 15 msec
        }
        servoPos = num; //update servo position
        Serial.print("Servo at "); Serial.print(servoPos); Serial.println(".\tNew position?");
      }
      else { Serial.print(num); Serial.println(" not valid.  Must be between 0 and 180"); }
    }

    /*add char to string if string not too long and valid digit*/
    else {
      if(inString.length() > 2) continue;
      if(isDigit(inChar)) inString += inChar;
    }
  }
}

/*****************************************************************************
* Program Name: blink-joystick
* Author: Bob
* 
* Use the joystick widget in the Blynk app to conrol the mini pan tilt
* camera mount from your phone
* 
* ----------------------------------------------------------------------------
* Change History
* Date         Ver    Description
* ----------   ----   --------------------------------------------------------
* 04/07/2019   V1.0   Initial development
*****************************************************************************/
#define BLYNK_PRINT Serial
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <Servo.h>


// Your WiFi credentials.
// Set password to "" for open networks.
char ssid[] = "wifiname";
char pass[] = "wifipassword";
char auth[] = "Blynk auth key";


Servo pan;        // create servo object to control the yaw servo
Servo tilt;       // create servo object to control the pitch servo
int panPos  = 90; // initial/current pan servo position
int tiltPos = 90; //initial/current tilt servo position




/*********************************************************************
 *  Get phone app joystick position (pan)
 *  Move pan servo
 ********************************************************************/
BLYNK_WRITE(V0) // V0 is the number of Virtual Pin  for pan servo
{
  int num = param.asInt();
  if((num < 0) && (num > 180)) return; //make sure number is valid
  Serial.print("V0 = ");Serial.println(num);
  
  for(int i = panPos; i != num; i += (panPos < num? 1 : -1)) {
    pan.write(i);       //move servo +/- 1 degree every 15 msec
    delay(15); yield(); //use yied to allow background tasks to run
  }
  panPos = num;         //update servo position
}



/*********************************************************************
 *  Get phone app joystick position (tilt)
 *  Move tilt servo
 ********************************************************************/
BLYNK_WRITE(V1) // V1 is the number of Virtual Pin  for tilt servo
{
  int num = param.asInt();
  if((num < 0) && (num > 180)) return; //make sure number is valid
  Serial.print("V1 = ");Serial.println(num);

  for(int i = tiltPos; i != num; i += (tiltPos < num? 1 : -1)) {
    tilt.write(i);      //move servo +/- 1 degree every 15 msec
    delay(15); yield(); //use yied to allow background tasks to run
  }
  tiltPos = num;        //update servo position
}



/*********************************************************************
 *  setup()
 *  run once at power on
 ********************************************************************/
void setup()
{
  // Debug console
  Serial.begin(115200);

  Blynk.begin(auth, ssid, pass);

  pan.attach(12);   // attaches the servo on pin 12 to the servo object
  tilt.attach(13);  // attaches the servo on pin 13 to the servo object
}



/*********************************************************************
 *  loop()
 *  Main loop ... run blynk
 ********************************************************************/
void loop()
{
  Blynk.run();
}

Credits

Bob

4 projects • 2 followers

Hobbiest

Contact

Comments

Please log in or sign up to comment.

Control a Mini Pan-Tilt Camera Mount with Your Phone

Things used in this project

Hardware components

Software apps and online services

Story

Overview

Build the breadboard

Update Arduino IDE with Blynk library

Add Blynk app to phone

Create Blynk app on phone

Download the Arduino programs

Test with interactive_servo

Test with blynk_joystick

Schematics

blink-joystick-breadboard

Code

interactive_servo.ino

blynk_joystick.ino

Credits

Bob

Comments

Embed the widget on your own site

Control a Mini Pan-Tilt Camera Mount with Your Phone

Control a Mini Pan-Tilt Camera Mount with Your Phone

Things used in this project

Hardware components

Software apps and online services

Story

Overview

Build the breadboard

Update Arduino IDE with Blynk library

Add Blynk app to phone

Create Blynk app on phone

Download the Arduino programs

Test with interactive_servo

Test with blynk_joystick

Schematics

blink-joystick-breadboard

Code

interactive_servo.ino

blynk_joystick.ino

Credits

Bob

Comments

Related channels and tags