Mewzk Layzer

The highest quality sound in a small. lightweight package.

BeginnerShowcase (no instructions)734

Things used in this project

Hardware components

Seeed Studio Grove - Ultrasonic Ranger

Breadboard (generic)

Jumper wires (generic)

Buzzer

Display Driver, LCD 4 Digits

Seeed Studio Grove Starter Kit for LaunchPad

Texas Instruments EK-TM4C123GXL TM4C Tiva LaunchPad

Software apps and online services

Texas Instruments Energia

Hand tools and fabrication machines

Breadboard, Plain

Tape Measure, Manual

Story

Have you ever wondered what would happen if you combined a mediocre distance sensor with an even more mediocre buzzer? We have. And we found the answer! A machine so beautiful, so eloquent that not only your socks, but both of you parents' and their parents' socks would be knocked off. Using the music of math we produce beautiful sound waves that can only be pleasing to your ears. With our highly talented team of computer scientists and electrical engineers, a collection of electrical components, and a little bit of musical inspiration we produced a laser based musical instrument created for the user by the user. A true Instrument for the 22nd century.

Code

#ifndef MUSICLASER_H_
#define MUSICLASER_H_

#include "Energia.h"
#include "Ultrasonic.h"

class MusicLaser {
private:
	/*
	 * Initializes the necessary information for buzzer to play notes, as well as preset tempo and note frequency.
	 */
	int buzzerPin;
	int tempo = 200;
	int tones[13] = { 1915, 1804, 1700, 1607, 1519, 1432, 1351, 1275, 1204, 1136, 1073, 1014, 956 };
	Ultrasonic ultrasonic;
public:
	int note = 13;

	MusicLaser(int buzzerPin, Ultrasonic ultrasonic): buzzerPin(buzzerPin), ultrasonic(ultrasonic){};

	void setUp ();

	void playTone (int tone, int duration);

	void playNote (int noteKey, int duration);

	int getDistance ();

	void loopFunc();
};

#endif /* MUSICLASER_H_ */

#include "MusicLaser.h"
#include "Ultrasonic.h"

void MusicLaser::setUp() {
	/*
	 * Completes setup by initializing buzzer pins.
	 */
	pinMode(buzzerPin, OUTPUT);
}

void MusicLaser::playTone (int tone, int duration) {
	/*
	 * Plays note by turning on and off buzzer with durations corresponding to the frequency of the note.
	 */
	for (long i = 0; i < duration * 1000L; i += tone * 2) {
	    digitalWrite(buzzerPin, HIGH);
	    delayMicroseconds(tone);
	    digitalWrite(buzzerPin, LOW);
	    delayMicroseconds(tone);
	    }
}

void MusicLaser::playNote(int noteKey, int duration){
	/*
	 * Calls play tone with a specfied note key as input that will access an item in the array.
	 */
	this->playTone(tones[noteKey], duration);
}

int MusicLaser::getDistance() {
	  /*
	  * Takes distance from distance sensor and then determines the coresponding note bin.
	  * Returns the note bin.
	  */
	  float distance = ultrasonic.MeasureInCentimeters();
	  if(distance > 103){
	    distance = 103;
	    }
	  int noteKey = distance / 8;
	  this->note = noteKey + 1;
	  return noteKey;
	}

void MusicLaser::loopFunc() {
	/*
	 * Call this function in the void loop section.
	 * Calls get distance to determine distance and then plays the note for the bin returned by getDistance.
	 * Calls playNote to play note.
	 */
	int noteKey = this->getDistance ();
	playNote (noteKey, this->tempo);
	delay (this->tempo);
}

#include <MusicLaser.h>
#include "TM1637.h"

/*
 * Defines constants for pins
 */
#define ULTRASONIC_PIN 24
#define DIO 38
#define CLK 39

/*
 * Initializes the 4 digit display
 */
TM1637 tm1637(CLK, DIO);
int8_t bits[4] = {0};


/*
 * Initializes instance of musicLaser
 */
Ultrasonic ultrasonic(ULTRASONIC_PIN);
MusicLaser musicLaser(5, ultrasonic);

void setup() {
  /*
   * Calls setup method on musicLaser and sets up 4 digit display.
   */
  musicLaser.setUp();
  
  tm1637.init();
  tm1637.set(BRIGHT_TYPICAL);
}

void loop() {
  /*
   * Calls musicLaser loop fundtion to play notes and displays note bin on 4 digit display.
   */
  musicLaser.loopFunc();
  
  showDist ();
}

void showDist() {
  /*
   * Prints bin number to 4 digit display.
   */
  int number_dist = musicLaser.note;
  memset(bits, 0, 4);
  for (int i = 3; i >= 2; i--){
    bits[i] = number_dist % 10;
    number_dist = number_dist / 10;
    tm1637.display(i, bits[i]);
  }
}