Published December 6, 2022

Castlevania (NES) Motion Controller

A strange controller designed to use motion to control the original Castlevania for the NES. Made for my Physical Computing class.

AdvancedShowcase (no instructions)59

Story

1 / 7 • 1. Attaching a safety pin to the bottom left corner of the bracer to act as a securing point.

https://www.youtube.com/watch?v=_7HmcG0lToU

This is the Castlevania (NES) Motion Controller. Its a Circuit Playground Express incorporated into an arm brace in order to use its buttons and accelerometer to control an emulated version of the original Castlevania for the NES. The goal for this was to make the game more interactive, immersing, and make you feel the cool effect of whipping the undead in real life. Making several gestures or moving your arm in certain directions will control the player character.

Having your forearm straight up, in a ready to whip stance, is going to be your default position for using the controller. Tilting your forearm to the right or left will make the playing turn/move in the correlated direction. Extending your arm out quickly in a whipping motion will engage attack mode, where the player will continuously attack. In this mode the player can still turn left or right. While the controller in earlier parts of development was being designed for each whip to be done by the player, this method resulted in inconsistencies with how well the controller could detect the player's individual whips as well as ultimately being very exhausting and strenuous to whip that many times so quickly. Thus a more user friendly approach was developed henceforth. To get out of attack mode the player need just aim their arm straight down, similar to lowering your weapon in real life. Holding this position and/or covering the controller at the same time will also result in the player crouch or enable them to go down stairs. Whipping the arm at a high angle with enough force will lead the character to do a forward whip jump and enable attack mode. Pumping a fist straight up will result in a regular jump however it is more consistent to whip jump by whipping upward. To use the character's items the player need just hold their arm straight up and cover their controller in a powerful stance to enable the use of those special weapons. This will continue until the player lowers their arm. This stance is also how the player climbs stairs.

Under the hood, three key ideas make the controller work: sending the right amount of keyboard input messages to have the game detect controls, working with gravity in mind, and designing the gestures to work along the XYZ axis. In development a lot of testing went into figuring out the appropriate amount of "Keyboard.write()" commands to send in order for an action to be executed consistently enough when gestured as well as enough to where no duplicate inputs would be executed. Since the controller is using an accelerometer to receive inputs, different ranges of acceleration in each of the dimensional axes need to be figured out through constant testing. The ranges that accept input aren't consistent due to the different angles that the human arm reaches with as well. For example, in tilting your arm you have a greater natural range of motion when tilting your arm to the left and not the right. For attacks the controller is looking for a minimum amount of force to be detected in the X axis, the axis that follows the path of gravity given how the CPX is mounted on the bracer and how a person positions their hand to hold a weapon. When a large enough force is detected in the X axis, attack mode is entered. If this force is accompanied by a large enough acceleration in the Y direction as well, then this leads to the whip jump. The crouch and item gestures function using the light sensor on the controller to detect when there is no light, thus telling the game to receive the down and up keys respectively.

Castlevania_Motion_Controller.ino

#include <Keyboard.h>
#include <Adafruit_CircuitPlayground.h>

bool rightButtonPressed;
bool leftButtonPressed = true;
bool hasPauseBeenPressed = false;
bool isWhipping = false;
int pauseBufferCounter = 0;
int lightValue;

float X, Y, Z;

void setup() {
  Serial.begin(9600);
  CircuitPlayground.begin();
  Keyboard.begin();
}

void loop() {
  X = CircuitPlayground.motionX();
  Y = CircuitPlayground.motionY();
  Z = CircuitPlayground.motionZ();

  rightButtonPressed = CircuitPlayground.rightButton();
  leftButtonPressed = CircuitPlayground.leftButton();

  if(rightButtonPressed || leftButtonPressed) {    
    if (hasPauseBeenPressed == false) {
      hasPauseBeenPressed = true;
      InputKey('s', false);
      Serial.println("Pause pressed!");
      Keyboard.releaseAll();
    }
  }
  else if (hasPauseBeenPressed == true) {
    pauseBufferCounter++;    
    Serial.print("Pause Buffer: ");
    Serial.println(pauseBufferCounter);
    if (pauseBufferCounter == 42) {
      hasPauseBeenPressed = false;
      pauseBufferCounter = 0;      
    }
  }
  
  if (X <= -18.0) {
    isWhipping = true;
    CircuitPlayground.playTone(450, 20);
  }
  
  if (WithinMarginOfError(X, -2, 3) && WithinMarginOfError (Y, 6.5, 2.8)){
    if (Z > 4) {
      Keyboard.release(KEY_RIGHT_ARROW);
      InputKey(KEY_LEFT_ARROW, true);
    }
    else if (Z < -2) {
      Keyboard.release(KEY_LEFT_ARROW);
      InputKey(KEY_RIGHT_ARROW, true);
    }
  }

  if (WithinMarginOfError(Y, 9.8, 1)){
    lightValue = CircuitPlayground.lightSensor();
    if(lightValue == 0) {
      InputKey(KEY_UP_ARROW, true);
    } 
  }
  else {
    Keyboard.release(KEY_UP_ARROW);
  }

  if (WithinMarginOfError(Y, -9.8, 1)){
    Keyboard.release('d');
    isWhipping = false;

    lightValue = CircuitPlayground.lightSensor();
    if(lightValue == 0) {
      InputKey(KEY_DOWN_ARROW, true);
    } 
  }
  else {
    Keyboard.release(KEY_DOWN_ARROW);
  }

  if (Y > 14) {
    InputKey('f', false);
    Serial.println("Jump pressed!");
    Keyboard.release('f');
  }

  if (isWhipping) {
    InputKey('d', false);
  }
  
  //PrintAcceleration();
}

void PrintAcceleration() {
  Serial.print("X: ");
  Serial.print(X);
  Serial.print("  Y: ");
  Serial.print(Y);
  Serial.print("  Z: ");
  Serial.println(Z);
  delay(200);
}

bool WithinMarginOfError(float value, float target, float margin) {
  float floor = target - margin;
  float ceiling = target + margin;
  if (value < ceiling && value > floor) {
    return true;
  }
  else {
    return false;
  }
}

void InputKey (char character, bool press) {
  int numberOfInputs = 21;
  if (press) {
      Keyboard.press(character);
  }
  else {
    for(int i = 0; i < numberOfInputs; i++){
    Keyboard.write(character);
    }
  }
}

Credits

TriOmega

4 projects • 0 followers

Castlevania (NES) Motion Controller

Story

Code

Castlevania_Motion_Controller.ino

Credits

TriOmega

Comments

Embed the widget on your own site

Castlevania (NES) Motion Controller

Castlevania (NES) Motion Controller

Story

Code

Castlevania_Motion_Controller.ino

Credits

TriOmega

Comments

Related channels and tags