Published May 19, 2020 © MIT

M5StickC with HomeKit Automation

Used StickC with ESPHap library to connect to HomeKit

IntermediateShowcase (no instructions)2 hours5,271

Things used in this project

Hardware components

M5Stack ENV Unit

M5Stack M5StickC ESP32-PICO Mini IoT Development Board

Software apps and online services

Apple HomeKit

Arduino IDE

Story

In the past, if you want to access Apple's homekit, you need to use homeassistant, homebridge and other services to realize it. The complexity of configuration is not friendly to beginner. At the same time, building a connected server is not a small overhead. Now you can easily access the homekit service by using the ESPHap library. You can control the M5Stack through related Apple products.

Take M5StickC as an example to show how to use the ESPHap library file. First, we need to download the related file https://github.com/yurik72/esphap from GitHub. After downloading, find the wolfssl folder, under this file, there is a wolfssl -13-3-0.rar package. Extract the compression package to Arduino library as an independent wolfssl library.

Operation process:connected WIFI->Register configuration status indicator pin (can be omitted)->Initialize SPIFFS, store homekit pairing information->Set the callback function to remove the device (it must be added, otherwise the Apple HomeKit cannot be paired again after deleting the device, and the NVS partition must be erased and upload code again) ->Set device type (32 types enumerated) ->Register homekit hardware (Sensor, manufacturer, serial number, model, firmware information) ->Add homekit service information->Final initialization. Code Homekit code is set to 111-11-111 by default.

For the first use, you need to format the spiffs storage configuration file, about 30 seconds, and wait patiently. The following example is connected to ENV-Unit to display temperature and humidity.

Thanks to yurik72

ENV-Hap

#include <M5StickC.h>
#include "DHT12.h"
#include <Wire.h> //The DHT12 uses I2C comunication.
#include <WiFi.h>
#include <FS.h>
#include <SPIFFS.h>
 
const char* ssid     = "YOURSSID";
const char* password = "YOURPASSWORD";
 
const int identity_led=10;
const int led_gpio = 10;
 
extern "C"{
#include "homeintegration.h"
}
homekit_service_t* hapservice={0};
String pair_file_name="/pair.dat";
 
void Format(){
  // Next lines have to be done ONLY ONCE!!!!!When SPIFFS is formatted ONCE you can comment these lines out!!
  Serial.println("Please wait 30 secs for SPIFFS to be formatted");
  SPIFFS.format();
  Serial.println("Spiffs formatted");
}
 
void init_hap_storage(){
 
  Serial.print("init_hap_storage");
  if (!SPIFFS.begin(true)) {
       Serial.print("SPIFFS Mount failed");
    }
    
  
    File fsDAT=SPIFFS.open(pair_file_name, "r");
  if(!fsDAT){
      Serial.println("Failed to read pair.dat");
      return;
  }
  int size=hap_get_storage_size_ex();
  char* buf=new char[size];
  memset(buf,0xff,size);
  int readed=fsDAT.readBytes(buf,size);
  Serial.print("Readed bytes ->");
  Serial.println(readed);
  hap_init_storage_ex(buf,size);
  fsDAT.close();
  delete []buf;
}
 
void storage_changed(char * szstorage,int size){
  SPIFFS.remove(pair_file_name);
  File fsDAT=SPIFFS.open(pair_file_name, "w+");
  if(!fsDAT){
    Serial.println("Failed to open pair.dat");
    return;
  }
  fsDAT.write((uint8_t*)szstorage, size);
 
  fsDAT.close();
}
 
DHT12 dht12;
homekit_service_t* temperature;
homekit_service_t* humidity;
void setup() {
    M5.begin();
    Wire.begin(32, 33, 100000);
    M5.Lcd.setRotation(3);
    // We start by connecting to a WiFi network
    Serial.println();
    Serial.println();
    Serial.print("Connecting to ");
    Serial.println(ssid);
 
    WiFi.begin(ssid, password);
 
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }
    Serial.println("");
    Serial.println("WiFi connected");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());
 
   pinMode(led_gpio,OUTPUT);
    hap_set_identity_gpio(identity_led);
 
    init_hap_storage();
    set_callback_storage_change(storage_changed);
 
    hap_setbase_accessorytype(homekit_accessory_category_thermostat);
    hap_initbase_accessory_service("Sensor","M5Stack","20200513","StickC-ENV","1.0.1");
 
    temperature = hap_add_temperature_service("Temperature Sensor");
    humidity = hap_add_humidity_service("Humidity Sensor");
        
   //and finally init HAP
    hap_init_homekit_server();
 
}
 
void loop() {
 
    float tmp = dht12.readTemperature();
    float hum = dht12.readHumidity();
 
    M5.Lcd.setCursor(0, 6, 2);
    M5.Lcd.setTextColor(WHITE, BLACK);
    M5.Lcd.setTextSize(2);
    M5.Lcd.printf("Temp: %2.1fC\n", tmp);
    M5.Lcd.printf("Humi: %2.0f%%\n", hum);
     homekit_characteristic_t * ch= homekit_service_characteristic_by_type(temperature, HOMEKIT_CHARACTERISTIC_CURRENT_TEMPERATURE);
     ch->value.float_value=tmp;
     homekit_characteristic_notify(ch,ch->value);
     homekit_characteristic_t * ch2= homekit_service_characteristic_by_type(humidity, HOMEKIT_CHARACTERISTIC_CURRENT_RELATIVE_HUMIDITY);
     ch2->value.float_value=hum;
     homekit_characteristic_notify(ch2,ch2->value);
      
    delay(500);
}