Published July 10, 2016 © GPL3+

Blynk Lock

A lock which allows remote locking and un-locking. An user does not need to walk to the door to open or lock a door.

IntermediateFull instructions provided3,252

Things used in this project

Hardware components

SparkFun Blynk Board - ESP8266

Alligator Clips

Jumper wires (generic)

Door Latch

SparkFun Magnetic Door Switch Set

Software apps and online services

Blynk

Arduino IDE

Story

Blynk Lock provides the convenience of monitoring, locking and unlocking a door from a distance. You do not need to walk to the door to open or close it.

Blynk Lock has the following features:

(1) It allows you to lock and unload a door remotely using a Blynk app.

(2) It shows door states (open or closed) on the Blynk app.

(3) It uses a LED to indicate if a door is open or closed.

(4) It sends a notification to the Blynk app whenever the door is open or closed.

(5) It shows a terminal with logs of door open and closed.

Blynk Lock has two parts. A hardware part which consists of the Blynk board, magnetic door switch set, door latch, servo, LED and a wooden bar which controls the door latch.

The second part is a Blynk app which shows the door states, open and close the door button and logs.

Video Links

Follows are some videos recording while building the Blynk Lock:

(1) Blynk Lock - testing the door latch with servo video

(2) Blynk Lock - locking and unlocking door latch video

(3) Blynk Lock - showing door switch set, LED and door latch movements video

Connecting the components

Get these parts: door latch, wooden bar to move the latch and box to house the latch and other parts.

Fix the door latch to the box and make a hole at big enough for the latch to move forward and backward.

Have the Blynk board, door switch set, LED, servo and alligator clips ready.

Connect all the above parts according to the diagram provided in the Schematics and circuit diagrams section.

The box with the latch, and door switch set and LED on the cover of the box.

The Blynk board and the App.

Building the Blynk Lock App

We will use the Arduino IDE to develop the app. Refer to the following resources to get to know how to prepare for the development environment:

(1) Blynk board Arduino Development Guide

(2) Blynk board Arduino Development 101

This project uses four widgets: Push (notification), Terminal, Button and Value.

Add the Push Widget

Push widget is under Notification section. After adding it, configure its setting as below. This diagram shows its setting on a Android device. It looks slightly different on an iOS device.

Add the Value Widget

Set the Value widget to V25. The widget will show the current state of the door switch sensor.

Add the Terminal Widget

Configure the Terminal widget to use pin V21. Set its setting the same as the following diagram.

Add the Button Widget

Set the Button widget to use pin V26. Configure it as a Switch. The widget is used to lock and unlock the door with a latch.

The Look of the App

Finally, the App should look like the following before running it.

Configure the Code

Cut and paste the source codes from the Code section below into your Arduino IDE. Change these lines of code.

char BlynkAuth[] = "blynk auth code";  // cloud
char WiFiNetwork[] = "wifi network";
char WiFiPassword[] = "wifi password";

Running the App

Once everything is ready, upload and run the project. Open the Serial Monitor by clicking the magnifying glass icon on the upper-right corner of your IDE. Some debug information will be displayed on the serial monitor.

Run your Blynk Lock app by clicking the arrow icon on the upper-right corner of Blynk.

Putting the door switches close to each other or pulling them apart. You will notice a few events should happen.

(1) When putting the switches close, the LED will be OFF, the door state will change to Close and the event will be logged on the Terminal. You may get a "door close" notification on Blynk.

(2) When pulling the switches apart, the LED will be ON, the door state will change to Open and the event will be logged on the Terminal. You may get a "door open" notification on Blynk.

From Blynk Lock app, you can remotely lock and unlock the door by pressing the Door Knob button. Checkout the video links above to find out how it works.

About the Code

This configure the Blynk setting.

char BlynkAuth[] = "blynk auth code";  // cloud
char WiFiNetwork[] = "wifi network";
char WiFiPassword[] = "wifi password";

This setup the hardware pins.

#define LED_PIN  5
#define SERVO_PIN  12
#define DOOR_STATE_VIRTUAL        V25
#define SERIAL_VIRTUAL            V21
#define LOCK_BUTTON_PIN           0
#define BUTTON_VIRTUAL            V26

This defines the terminal and a function that is called when device receives an update of Virtual Pin value of SERIAL_VIRTUAL which is V21.

WidgetTerminal terminal(SERIAL_VIRTUAL);
BLYNK_WRITE(SERIAL_VIRTUAL)
{
String incoming = param.asStr();
Serial.println(incoming);
// do other tasks
...
}

This reads the DOOR_SWITCH_PIN and update the door state and toggle the LED according to read value. It too prints logs to the terminal and send notifications if the state change interval is longer than the NOTIFICATION_LIMIT.

#define DOOR_SWITH_PIN  16
#define NOTIFICATION_LIMIT 60000
unsigned long lastDoorSwitchNotification = 0;
uint8_t lastSwitchState = 255;
BLYNK_READ(DOOR_STATE_VIRTUAL)
{
uint8_t switchState = digitalRead(DOOR_SWITCH_PIN); // Read the door switch pin
if (switchState) {
  Blynk.virtualWrite(DOOR_STATE_VIRTUAL, "Close"); // Update virtual variable
  digitalWrite(LED_PIN, 0);
}
else {
  Blynk.virtualWrite(DOOR_STATE_VIRTUAL, "Open");
  digitalWrite(LED_PIN, 255);
}
if (lastSwitchState != switchState) // If the state has changed
{
  if (switchState) // If the switch is closed (door shut)
  {
    BB_DEBUG("Notified closed.");
    if (lastDoorSwitchNotification && (lastDoorSwitchNotification + NOTIFICATION_LIMIT > millis()))
    {
      int timeLeft = (lastDoorSwitchNotification + NOTIFICATION_LIMIT - millis()) / 1000;
      BB_DEBUG("Can't notify for " + String(timeLeft) + "s");
      terminal.println("Door closed. Can't notify for " + String(timeLeft) + "s");
      terminal.flush();
    }
    else
    {
      Blynk.notify("Door closed\r\nFrom: " + boardName + "\r\n[" + String(millis()) + "]");
      terminal.println("Door closed!");
      terminal.flush();
      lastDoorSwitchNotification = millis();
    }
  }
  else
  { 
    BB_DEBUG("Notified opened.");
    // Send the notification
    if (lastDoorSwitchNotification && (lastDoorSwitchNotification + NOTIFICATION_LIMIT > millis()))
    {
      int timeLeft = (lastDoorSwitchNotification + NOTIFICATION_LIMIT - millis()) / 1000;
      BB_DEBUG("Can't notify for " + String(timeLeft) + "s");
      terminal.println("Door open. Can't notify for " + String(timeLeft) + "s");
      terminal.flush();
    }
    else
    {
      Blynk.notify("Door open\r\nFrom: " + boardName + "\r\n[" + String(millis()) + "]");
      terminal.println("Door opened!");
      terminal.flush();
      lastDoorSwitchNotification = millis();
    }
  }
  lastSwitchState = switchState;
}  
}

This code move the door latch between lock and unlock positions. Whenever the Blynk button (labeled Door Knob) is pressed, the virtual pin V26 will activate the toggle() function which will put the latch to "lock/unlock" position. A variable called pos is used to track the position.

Servo servo1;
int pos;
...
void toggle() {
if (pos == 0) {
pos = 15;
} else {
pos = 0;
}
servo1.write(pos);
delay(20);
}
BLYNK_WRITE(V26)
{
int pinValue = param.asInt(); // assigning incoming value from pin V26 to a variable
Serial.print("V26 Button value is: ");
Serial.println(pinValue);
toggle();
}

Code

blynk_lock.ino

#define BLYNK_PRINT Serial    // Comment this out to disable prints and save space
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <Servo.h>  // servo library

#ifdef DEBUG_ENABLED
#define BLYNK_PRINT Serial
#define BB_DEBUG(msg) {\
  Serial.print("[" + String(millis()) + "] "); \
  Serial.println(msg); }
#else
#define BB_DEBUG(msg)
#endif

////////////////////
// Blynk Settings //
////////////////////

char BlynkAuth[] = "blynk auth code";  // cloud
char WiFiNetwork[] = "wifi network";
char WiFiPassword[] = "wifi password";

///////////////////////
// Hardware Settings //
///////////////////////
#define LED_PIN    5
#define SERVO_PIN  12

#define DOOR_STATE_VIRTUAL        V25
#define SERIAL_VIRTUAL            V21
#define LOCK_BUTTON_PIN           0
#define BUTTON_VIRTUAL            V26


Servo servo1;
int pos;

void unlock() {
  if (pos == 0) {
    pos = 15;
    servo1.write(pos);
    delay(20);
  }
}

void lock() {
  if (pos == 15) {
    pos = 0;
    servo1.write(pos);
    delay(20);
  } 
}

void toggle() {
  if (pos == 0) {
    pos = 15;
  } else {
    pos = 0;
  }

  servo1.write(pos);
  delay(20);
}

/* 12 12 12 12 12 12 12 12 12 12 12 12 12
 12 Experiment 12: Terminal            12
 12 Widget(s):                         12
 12  - Terminal: V21, On, On           12
 12 12 12 12 12 12 12 12 12 12 12 12 12 */
String emailAddress = "";
String boardName = "Blynk Lock";

WidgetTerminal terminal(SERIAL_VIRTUAL);

BLYNK_WRITE(SERIAL_VIRTUAL)
{
  String incoming = param.asStr();
  Serial.println(incoming);
  
  if (incoming.charAt(0) == '!')
  {
    String emailAdd = incoming.substring(1, incoming.length());
    for (int i=0; i<emailAdd.length(); i++)
    {
      if (emailAdd.charAt(i) == ' ')
        emailAdd.remove(i, 1);
    }
    terminal.println("Your email is:" + emailAdd + ".");
    emailAddress = emailAdd;
    terminal.flush();
  }
  if (incoming.charAt(0) == '$')
  {
    String newName = incoming.substring(1, incoming.length());

    boardName = newName;
    terminal.println("Board name set to: " + boardName + ".");
    terminal.flush();
  }
}


/* 14 14 14 14 14 14 14 14 14 14 14 14 14
 14 Experiment 14: Push                14
 14 Widget(s):                         14
 14  - Push: Off, On (iPhone)          14
 14  - Value: DoorState, V25, 1sec     14
 14  - Button: PushEnable, V26, Switch 14
 14 14 14 14 14 14 14 14 14 14 14 14 14 */
#define DOOR_SWITCH_PIN 16
#define NOTIFICATION_LIMIT 60000
unsigned long lastDoorSwitchNotification = 0;
uint8_t lastSwitchState = 255;

BLYNK_READ(DOOR_STATE_VIRTUAL)
{
  uint8_t switchState = digitalRead(DOOR_SWITCH_PIN); // Read the door switch pin
  // Pin 16 is pulled low internally. If the switch (and door) is open,
  // pin 16 is LOW. If the switch is closed (door too), pin 16 is HIGH.
  // LOW = open
  // HIGH = closed
  if (switchState) {
    Blynk.virtualWrite(DOOR_STATE_VIRTUAL, "Close"); // Update virtual variable
    digitalWrite(LED_PIN, 0);
  }
  else {
    Blynk.virtualWrite(DOOR_STATE_VIRTUAL, "Open");
    digitalWrite(LED_PIN, 255);
  }
    
  if (lastSwitchState != switchState) // If the state has changed
  {
    if (switchState) // If the switch is closed (door shut)
    {
      BB_DEBUG("Notified closed.");
      
      if (lastDoorSwitchNotification && (lastDoorSwitchNotification + NOTIFICATION_LIMIT > millis()))
      {
        int timeLeft = (lastDoorSwitchNotification + NOTIFICATION_LIMIT - millis()) / 1000;
        BB_DEBUG("Can't notify for " + String(timeLeft) + "s");
        terminal.println("Door closed. Can't notify for " + String(timeLeft) + "s");
        terminal.flush();
      }
      else
      {
        Blynk.notify("Door closed\r\nFrom: " + boardName + "\r\n[" + String(millis()) + "]");
        terminal.println("Door closed!");
        terminal.flush();
        lastDoorSwitchNotification = millis();
      }
    }
    else
    { 
      BB_DEBUG("Notified opened.");
      // Send the notification
      if (lastDoorSwitchNotification && (lastDoorSwitchNotification + NOTIFICATION_LIMIT > millis()))
      {
        int timeLeft = (lastDoorSwitchNotification + NOTIFICATION_LIMIT - millis()) / 1000;
        BB_DEBUG("Can't notify for " + String(timeLeft) + "s");
        terminal.println("Door open. Can't notify for " + String(timeLeft) + "s");
        terminal.flush();
      }
      else
      {
        Blynk.notify("Door open\r\nFrom: " + boardName + "\r\n[" + String(millis()) + "]");
        terminal.println("Door opened!");
        terminal.flush();
        lastDoorSwitchNotification = millis();
      }
    }
    lastSwitchState = switchState;
  }  
}



BLYNK_WRITE(V26)
{
  int pinValue = param.asInt(); // assigning incoming value from pin V26 to a variable
  // You can also use:
  // String i = param.asStr();
  // double d = param.asDouble();
  Serial.print("V26 Button value is: ");
  Serial.println(pinValue);

  toggle();
}

void setup()
{
  // Initialize hardware
  Serial.begin(9600); // Serial
  pinMode(LED_PIN, OUTPUT); // LED output

  // Set up the pin 16 door switch input:
  pinMode(DOOR_SWITCH_PIN, INPUT_PULLDOWN_16);
  lastSwitchState = digitalRead(DOOR_SWITCH_PIN);

  // Initialize Blynk
  Blynk.begin(BlynkAuth, WiFiNetwork, WiFiPassword);
//  Blynk.begin(BlynkAuth, WiFiNetwork, WiFiPassword, IPAddress(192,168,1,4));

  servo1.attach(SERVO_PIN);
  pos = 15;
  servo1.write(pos);

  
}

void loop()
{
  // Execute Blynk.run() as often as possible during the loop
  Blynk.run(); 


}

Credits

vincent wong

81 projects • 205 followers

Blynk Lock

Things used in this project

Hardware components

Software apps and online services

Story

Video Links

Connecting the components

Building the Blynk Lock App

About the Code

Schematics

Blynk Lock Diagram

Code

blynk_lock.ino

Credits

vincent wong

Comments

Embed the widget on your own site

Blynk Lock

Blynk Lock

Things used in this project

Hardware components

Software apps and online services

Story

Video Links

Connecting the components

Building the Blynk Lock App

About the Code

Schematics

Blynk Lock Diagram

Code

blynk_lock.ino

Credits

vincent wong

Comments

Related channels and tags