Whack-A-Button!

/*
  Whack-a-Button
  Sidekick Basic Kit for TI LaunchPad

  Modeled after Whack-a-Mole, press the button corresponding to the LED that lights up
  as many times as you can before the time runs out.

  Creators: Amar Moturu, Darren Corapcioglu, Elizabeth Sims, John Shieh, Manaal Khan, 
  Rob Gonzalez, Son Nguyen, and Sophia Hetts
*/
 #include "pitches.h"
 #include <stdio.h>
// Define the LED digit patterns for 0 - 9 in a 2 dimensional array.
// The 2D array (an array of arrays or a matrix) has 10 arrays that each
// contain 7 values.
// 1 = LED on, 0 = LED off, in this order:
// Common Anode version
byte seven_segment_digits[11][7] = { 
                                     { 0,0,0,0,0,0,1 }, // display '0'
                                     { 1,0,0,1,1,1,1 }, // display '1'
                                     { 0,0,1,0,0,1,0 }, // display '2'
                                     { 0,0,0,0,1,1,0 }, // display '3'
                                     { 1,0,0,1,1,0,0 }, // display '4'
                                     { 0,1,0,0,1,0,0 }, // display '5'
                                     { 0,1,0,0,0,0,0 }, // display '6'
                                     { 0,0,0,1,1,1,1 }, // display '7'
                                     { 0,0,0,0,0,0,0 }, // display '8'
                                     { 0,0,0,1,1,0,0 }, // display '9'  
                                     { 0,1,1,0,1,1,0 }  // display 'E'                                 
                                   };

//Ending Happy Birthday Song
int song[] = {
  NOTE_G6, NOTE_G6, NOTE_A6, NOTE_G6,NOTE_C7, NOTE_B6,
  NOTE_G6, NOTE_G6, NOTE_A4, NOTE_G4,NOTE_D5, NOTE_C5,
  NOTE_G4, NOTE_G4, NOTE_G5, NOTE_E5,NOTE_C5, NOTE_B4, NOTE_A4,
  NOTE_F5, NOTE_F5, NOTE_E5, NOTE_C5,NOTE_D5, NOTE_C5

  };

// note durations: 4 = quarter note, 8 = eighth note, etc.:
int noteDurations[] = {
  3, 4, 4, 4, 4, 2,
  3, 4, 4, 4, 4, 2,
  3, 4, 4, 4, 4, 4, 2,
  3, 4, 4, 4, 4, 2};

//Frequencies for notes from buzzer
int melody[] ={NOTE_B0, NOTE_A3, NOTE_FS6, NOTE_DS8};
//Start at 400ms between each count
int initial_interval = 400;
int interval = 400;
//Set score to 1
int score = 1;
//Decrement in ms when correct button is pressed
int decrement = 6;
//Set the LED off to start
int LED_state = LOW;
//Set random LED to turn on
int LED = rand() % 4 + 11;
int other_LEDs[3]; //The buttons that player should not push.
int buzzer = 33; // Buzzer connected to port 33

void setup() {
  
  //Set up the 7-segment display
  pinMode(3, OUTPUT); // set segment A as output
  pinMode(4, OUTPUT); // set segment B as output
  pinMode(5, OUTPUT); // set segment C as output
  pinMode(6, OUTPUT); // set segment D as output
  pinMode(7, OUTPUT); // set segment E as output
  pinMode(8, OUTPUT); // set segment F as output
  pinMode(9, OUTPUT); // set segment G as output
  pinMode(10, OUTPUT); // set dot as output
  for(int i = 3; i < 10; i++) { // start with segments off
    digitalWrite(i, HIGH);
  }
  digitalWrite(10, HIGH);  // start with the dot off

  //Set up the LEDs
  Serial.begin(9600); 
  int i= 0;
  for(int i=11;i<15;i++){
    pinMode(i, OUTPUT);    
  }
  //Set up the buttons
  pinMode(15, INPUT_PULLUP);   
  pinMode(17, INPUT_PULLUP);   
  pinMode(18, INPUT_PULLUP);   
  pinMode(19, INPUT_PULLUP); 

  //Set up the tilt switch
  pinMode(28, INPUT_PULLUP);
  
}

//Gets the pin number of button associated with each LED
int LED_to_push(int LED){
  switch(LED){
    case 11:
      return 15;
    case 12:
      return 17;
    case 13:
     return 18;
     case 14:
      return 19;
  }
}

//Gets the note frequency associated with each LED
int LED_to_note(int LED){
  switch(LED){
    case 11:
      return melody[0];
    case 12:
      return melody[1];
    case 13:
     return melody[2];
     case 14:
      return melody[3];
  }
}

//Displays the count number on the 7-segment display using the array above and setting each pin
void display(int count){
  int pin = 3;
    for (int segCount = 0; segCount < 7; ++segCount) {
      digitalWrite(pin, seven_segment_digits[count][segCount]);
      ++pin;
    }
}

//Switches the value of the pin associated with the LED (switches LED on and off)
void LED_switch(int LED){
  if (LED_state == LOW)
      LED_state = HIGH;
    else
      LED_state = LOW;
  digitalWrite(LED, LED_state); 
}

//Update the other_LED array
void update_LEDs(int LED){
  int count=0, port=11;
  for(int count=0; count<4; count++){
    if (count+11 != LED){
      other_LEDs[count]= port;
      port++;
    }else{
      other_LEDs[count]= port+1;
      port+=2;
    }
  }

}

void loop() {
  Serial.print("Interval");
  Serial.println(interval);
  boolean flag = true;
  //Generates random pin number for LED to display
  LED = (LED - 10 + rand()%3 )%4+11; //Make sure the same LED does light up twice in a row
  update_LEDs(LED);
  int but0 = LED_to_push(other_LEDs[0]);
  int but1 = LED_to_push(other_LEDs[1]);
  int but2 = LED_to_push(other_LEDs[2]);
  Serial.print(but0);
  Serial.print(but1);
  Serial.print(but2);
  //Counts down time to press correct button
  for (int count = 9; count >= 0; --count) {
    //Turn on/change LED, tone, and display
    LED_switch(LED);
    tone(buzzer, LED_to_note(LED),interval);
    display(count);
    int delay_interval = 50;
    //Checks every 50ms if correct button is pressed
    for (int delay_cnt = 0; delay_cnt < interval; delay_cnt += delay_interval){
      //Checks if correct button corresponding to LED is pressed
      if (!digitalRead(LED_to_push(LED))){
        Serial.print("~");
        //Turns LED off
        digitalWrite(LED, LOW);
        LED_state = LOW;
        //Decreases time between counts
        if (interval > 80) interval -= decrement;
        flag = false;
        break;
      }else if(!digitalRead(but0)| !digitalRead(but1) | !digitalRead(but2) ) break; //Wrong buttons => End GAME
      delay(delay_interval);
    }
    if (!flag) { //Right button --> Increment score
      score++;
      Serial.print("SCORE");
      Serial.println(score);
      delay(250);
      break;
    }
  }

  //If correct button was not pressed, game is over
  //Flag is still true
  if(flag){
    display(10);
    
    // Calculate the score
    int size = (int)(log10(score)+1); // Size of the array to store score
    int score_array[size];
    int i =0;
    //populate the array with the right score
    for (int i=size-1; i>=0; i--){
       score_array[i] = score%10; 
       score=(int)score/10;
   }
   
   delay(100);
   
    while(flag){
      //Play Happy Birthday song and display the score.
      for (int thisNote = 0; thisNote < 25; thisNote++) {
        //Display score
         if (thisNote%(size+1)<size) display(score_array[thisNote%(size+1)]); 
         else display(10);
         //Turn on LED
         int LED = rand() % 4+11;
         digitalWrite(LED,HIGH);
         //Sound
         int noteDuration = 1000/noteDurations[thisNote];
         tone(buzzer, song[thisNote],noteDuration);
         int pauseBetweenNotes = noteDuration * 1.30;
         delay(pauseBetweenNotes);
         noTone(33);
         //Turn off LED
         digitalWrite(LED,LOW);
         if (digitalRead(28)){//Check tilt switch
          flag = false;
          break;
        }
      }
      if(!flag){
        //Reset the interval, score and break to start game
          interval = initial_interval;
          delay(303);
          score = 1;
          Serial.print(score);
          break;
      }
      delay(100);   
    }
  }
}