Daniel Fritz, Raphael Andree, Janfabian Fabriczek, Dionysios Satikidis

Published January 28, 2023

Dusch-o-Meter

Track your water consumption and save money with Dusch-o-meter, the smart device for eco-friendly showers.

BeginnerProtip291

Things used in this project

Hardware components

Particle Photon

Breadboard (generic)

Jumper wires (generic)

Water Flow Sensor

Software apps and online services

IFTTT Maker service

ThingSpeak API

Story

Intro

This project was developed as part of a course called "Internet of Things Ecosystems" at the University of Applied Science Esslingen. Through this project, students have the opportunity to build their own IoT application from the ground up and gain an understanding of the associated business aspects.

Motivation

High bills due to prolonged shower times can be frustrating, especially when finances are tight. Long warm showers worsen the situation, especially during the energy crisis. But that doesn't mean that the problem is caused by you. Maybe you have family members or roommates and one of them spends way too much time in the bathroom to shower. But don't blame them. People spend a lot of time in shower and at some point just lose the sense of time. However, with our product, you now have a solution for that problem.

Solution

Our Dusch-o-Meter IoT device and accompanying app aim to reduce water consumption and minimize shower time with features such as:

Tracking of the water consumption during shower and upload of the data to the cloud
Also tracking of the water temperature to consider the water consumption with warm water (not implemented yet)
Sending of an alert to the IFTT-App if a specific water limit is reached during shower
Statistics about the water consumption over different time ranges (days, weeks, months and years) in the Web-Dashboard and the Dusch-o-Meter app
Integrated cost calculator for calculating the exact costs of the wasted water (not implemented yet)

How to use?

Before the first use, install the Dusch-o-meter water flow sensor between the shower tap's water outlet and the hose connected to the shower head. Then, connect the water flow sensor to the Particle Photon following the wiring scheme included in this article. After these steps, the Dusch-o-meter device is ready to use.

Before showering, ensure to press the play button in our app, as our backend needs to know who is showering in order to assign the water consumption to the appropriate person. If this step is not taken, the water consumption will still be monitored, however, it will not be linked to a specific person.

Upon completing your shower, simply press the pause button in the app and the water consumption value will be uploaded to the Dusch-o-meter cloud and credited to your account. Forgot to hit the pause-button? Not an issue, there is a timeout implemented which performs an automatic reset and upload of your water consumption after you stopped showering.

Backend/Implementation

The main code of the program is located in the loop() function of the program.

When water is flowing, the sensor measures the water consumption by returning pulses. The higher the frequency of the pulses, the greater the water flow. The formula below demonstrates how to calculate the water consumption per hour using the Pulse_count value provided by the water flow sensor:

Liter_per_hour = (Pulse_Count * 60 / 6.6);

This calculation is triggered once a second. The variable Pulse_Count contains the number of pulses from the sensor within this second. This value will be multiplied with 60 to convert its value from Liter/min to Liter/hour. Then, it will be divided by 6.6 which is a sensor specific constant. The formula is provided in the datasheet of the sensor.

After the calculation, the amount of used water within one second is calculated and added to the variable used_water, which holds the total water consumption of the current showering session.

used_water += calc_used_water_1s(Liter_per_hour);

When the water usage exceeds a predetermined limit of e.g. 150 liters, the Dusch-o-meter program will trigger an event ("limit reached") and send it to the particle cloud. This event will then be redirected to IFTTT, which will send a notification to the IFTTT app on your phone via webhooks. The setup of the webhook to IFTT is described here.

After you finished showering, there is a timeout after which the used_water value is uploaded to your ThingsPeak cloud using the ThingsPeak Community library, which can be added from the Particle web IDE. More info on the library here.

Frontend (Prototype)

The app offers a comprehensive view of who exceeded the water limit and when, and enables you to start the shower by simply pressing the play button. It also showcases water consumption statistics and calculates the associated costs. Additionally, it includes various customization options such as changing the theme, modifying personal details such as name and avatar. Feel free to test our demo here.

Dashboard and Messages Screens

Setup Device (Protoype)

The following steps give a brief explanation how to set up the Dusch-o-Meter (not implemented yet)

Enter your account details like name, profile picture etc.
Create your own group and invite your friends to share your statistics about water consumption or join an existing group.
Set up the Dusch-o-Meter by registering your specific device with the provided identification number and password.
Chose a fancy theme

Code

dusch-o-meter-driver.ino

// This #include statement was automatically added by the Particle IDE.
#include <ThingSpeak.h>

#define END_SHOWER_TIMEOUT 5 * 60 // 5 minutes.
#define WATER_LIMIT 150.0 // water limit after which notification is triggered.

const int Output_Pin = D2; // The sensor Pulses are incoming here.

// Global variables for fetching and calculating water flow values from the sensor.
volatile int Pulse_Count = 0;
unsigned int Liter_per_hour;
unsigned long Current_Time, Loop_Time;

double used_water = 0;         // Amount of water used during showering.
unsigned long off_counter = 0; // if no water is flowing increment until specified timeout to detect shower process ending.
bool already_pushed = false;   // bool to detect if data
bool limit_exceeded = false;   // if exceeding water limit detected.

TCPClient client;

// API Keys for ThingsPeak --> here go your own API key and channel.
unsigned long channelNr = 31461;
const char *writeapikey = "LD79EOAAWRVYF04Y";

void setup()
{
    pinMode(Output_Pin, INPUT);
    attachInterrupt(D2, Detect_Rising_Edge, FALLING);

    Current_Time = millis();
    Loop_Time = Current_Time;
    // initialize thingSpeak tcpClient
    ThingSpeak.begin(client);
}

// calculates the amount of water used within 1s in liters
// return: consumed water in liters for 1s.
double calc_used_water_1s(unsigned int act_consumption)
{
    return (double)act_consumption / 3600;
}

// after some minutes with no water flowing publish data to server and reset water counter, reset limit exceeded.
void reset_and_store_data()
{
    ThingSpeak.writeField(channelNr, 1, (int)used_water, writeapikey); // vielleicht benachrichtigung ueber Abschluss.
    Particle.publish("Showering_Data_pushed", String(used_water));
    already_pushed = true;
    limit_exceeded = false;
    used_water = 0;
}

void loop()
{
    Current_Time = millis();
    if (Current_Time >= (Loop_Time + 1000)) // only calculate water flow rate every 1s
    {
        Loop_Time = Current_Time;
        Liter_per_hour = (Pulse_Count * 60 / 6.6); // Pulse_count == anz Pulse/s [Hz],  7.5 constant, 60 scaling to l/h
        // add used water to the amount of total used water.

        // Print the amount of water that was used up until now.
        Particle.publish("Used_water", String(used_water));

        // add used water to session water counter.
        used_water += calc_used_water_1s(Liter_per_hour);

        if (Pulse_Count > 0) // Pulse count only gets reset if Water is really flowing.
        {
            // add used water to the amount of total used water.
            Particle.publish("Rate:", String(Liter_per_hour));
            Pulse_Count = 0;

            // set already_pushed to false to push showering stats to cloud.
            already_pushed = false;
            // Reset off_time when measurement is started.
            off_counter = 0;
        }
        // no water flowing.
        else
        {
            // off counter measures the time in seconds that the shower is not working.
            if (already_pushed == false && off_counter < END_SHOWER_TIMEOUT)
            {
                off_counter++;
                Particle.publish("off_counter", String(off_counter));
            }
            else if (already_pushed == false && off_counter >= END_SHOWER_TIMEOUT)
            {
                // after timeout push used water to cloud and reset variables for next showering session
                reset_and_store_data();
            }
        }
    }

    // Send notification if consumed water is over defined limit (default 150l)
    if (used_water >= WATER_LIMIT && limit_exceeded == false) // good limit 150l
    {
        Particle.publish("Water_limit_reached", String(used_water)); // publish IFTTT message.
        limit_exceeded = true;
    }
}

// ISR when rising edge is detected.
void Detect_Rising_Edge()
{
    Pulse_Count++;
}

Dusch-o-Meter

Things used in this project

Hardware components

Software apps and online services

Story

Intro

Motivation

Solution

How to use?

Backend/Implementation

Frontend (Prototype)

Setup Device (Protoype)

Schematics

Wiring Schematic

Code

dusch-o-meter-driver.ino

Credits

Daniel Fritz

Raphael Andree

Janfabian Fabriczek

Dionysios Satikidis

Comments

Embed the widget on your own site

Dusch-o-Meter

Dusch-o-Meter

Things used in this project

Hardware components

Software apps and online services

Story

Intro

Motivation

Solution

How to use?

Backend/Implementation

Frontend (Prototype)

Setup Device (Protoype)

Schematics

Wiring Schematic

Code

dusch-o-meter-driver.ino

Credits

Daniel Fritz

Raphael Andree

Janfabian Fabriczek

Dionysios Satikidis

Comments

Related channels and tags