The Ultimate IoT Sensor Box for Smart Offices and Buildings

/************************** Configuration ***********************************/
// edit the config.h tab and enter your Adafruit IO credentials
// and any additional configuration needed for WiFi, cellular,
// or ethernet clients.
#include "config.h"

/************************ Example Starts Here *******************************/
#include <Arduino.h>
#include <pas-co2-ino.hpp>
#include <Dps422.h>
#include "DHT.h"            

#define I2C_FREQ_HZ 400000 

//Humidity
#define DHTPIN 14     // Digital pin connected to the DHT sensor
#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
DHT dht(DHTPIN, DHTTYPE);
float humidity_read;
 
//CO2 sensor
PASCO2Ino cotwo;
int16_t co2ppm_read;
int i = 0;

//Pressure/ Temperature sensor
Dps422 Dps422PressureSensor = Dps422();
float temperature_read;
float pressure_read;

//Noise
const int sound_pin = 33;
int sound_read;

//presence
const int radar1_pin = 32; int radar1_read;
const int radar2_pin = 15; int radar2_read;
const int radar3_pin = 21; int radar3_read;
const int radar4_pin = 34; int radar4_read;

// set up the feeds
AdafruitIO_Feed *humidity = io.feed("humidity");
AdafruitIO_Feed *CO2 = io.feed("CO2");
AdafruitIO_Feed *pressure = io.feed("pressure");
AdafruitIO_Feed *temperature = io.feed("temperature");
AdafruitIO_Feed *Noise = io.feed("Noise");
AdafruitIO_Feed *presence1 = io.feed("presence1");
AdafruitIO_Feed *presence2 = io.feed("presence2");
AdafruitIO_Feed *presence3 = io.feed("presence3");
AdafruitIO_Feed *presence4 = io.feed("presence4");

void setup() {

  // start the serial connection
  Serial.begin(115200);
  // wait for serial monitor to open
  while(! Serial);

  // start all sensors
  Wire.begin(SDA,SCL,I2C_FREQ_HZ); 
  //CO2
  cotwo.begin();
  //Pressure / Temperature
  Dps422PressureSensor.begin(Wire);
  //humidity
  dht.begin();
  //noise detection
  pinMode(sound_pin, INPUT);  
  //presence detection
  pinMode(radar1_pin, INPUT);  
  pinMode(radar2_pin, INPUT);  
  pinMode(radar3_pin, INPUT);  
  pinMode(radar4_pin, INPUT);  
  
  Serial.print("Connecting to Adafruit IO");
  // connect to io.adafruit.com
  io.connect();
  // wait for a connection
  while(io.status() < AIO_CONNECTED) {
    Serial.print(".");
    delay(500);
  }
  // we are connected
  Serial.println();
  Serial.println(io.statusText());

}

void loop() {

  // io.run(); is required for all sketches.
  // it should always be present at the top of your loop
  // function. it keeps the client connected to
  // io.adafruit.com, and processes any incoming data.
  io.run();

  //Read all sensor values
  cotwo.startMeasure();
  do{cotwo.getCO2(co2ppm_read);
    i++; if(i>1000){Serial.print("no "); i = 0; break;}
    } while (0 == co2ppm_read);
    Serial.print("co2 ppm value : ");
    Serial.println(co2ppm_read);
  
  Dps422PressureSensor.measurePressureOnce(pressure_read);
    Serial.print("Pressure: ");
    Serial.print(pressure_read);
    Serial.println(" Pascal");
    
  Dps422PressureSensor.measureTempOnce(temperature_read);
    Serial.print("Temperature: ");
    Serial.println(temperature_read);

  humidity_read = dht.readHumidity();
    Serial.print("Humidity: ");    
    Serial.println(humidity_read);

  sound_read = pulseIn(sound_pin, HIGH);
    Serial.print("Noise: ");    
    Serial.println(sound_read);

  radar1_read = digitalRead(radar1_pin);
    Serial.print("Radar1: ");    
    Serial.println(radar1_read);
  radar2_read = digitalRead(radar2_pin);  
    Serial.print("Radar2: ");    
    Serial.println(radar2_read);  
  radar3_read = digitalRead(radar3_pin);
    Serial.print("Radar3: ");    
    Serial.println(radar3_read);  
  radar4_read = digitalRead(radar4_pin);
    Serial.print("Radar4: ");    
    Serial.println(radar4_read);  

  // save to feed on Adafruit IO
  Serial.println("sending -> ");
  CO2->save(co2ppm_read);
  humidity->save(humidity_read);
  pressure->save(pressure_read/100);
  temperature->save(temperature_read-4);
  Noise->save(sound_read);
  presence1->save(radar1_read);
  presence2->save(radar2_read);
  presence3->save(radar3_read);
  presence4->save(radar4_read);

  // Adafruit IO is rate limited for publishing, so a delay is required in
  // between feed->save events.
  delay(18000);

}