Published May 13, 2018

ATtiny85 Plant Watering Autonomous System

Your plant will have the needed water for months. Displayed: humidity and time since last pumped water! Cheap and only a few components!

BeginnerFull instructions provided12 hours13,065

ATtiny85 Plant Watering Autonomous System

Things used in this project

Hardware components

Attiny85 module

SparkFun Soil Moisture Sensor (with Screw Terminals)

Pololu Mini MOSFET Slide Switch with Reverse Voltage Protection, SV

8x2 monochrome LCD

12V 280L/H Water Pump

LCD 1602 Adapter I2C

Software apps and online services

Arduino IDE

Story

Get inspired by this code (three versions available), press the "thumb-up" button if it worked for you!

There are many Arduino projects dedicated to this objective, but it depends on what you want:

Receive a warning (alarm sound, SMS, etc.) and go watering the plant ?
After a while (days in general) some water is poured by a timing machine. Maybe your plant does not deed it at that time !
Rely completely on moisture sensor. Big mistake! Local humidity can be misleading for the average pot humidity!
Your device is monitoring the plant, pouring water if needed, when needed. You simply visit it, from time to time, and refill the water container when needed.

This last option was selected in this project.

Full detail at: https://sites.google.com/site/pre2arduino/

This is the central unit, which displays the mimosa emoticons: happy :) normal :| or unhappy :( , then the soil humidity (%), number of days and hours since last water was pumped. You can use any another display, of course. This one is reused from another board (Pololu A-Star Prime).

Mimosa spirit, here :| but best is :), the measured humidity, and days & hours since last watering.

Mimosa, Arduino unit, moisture sensor, water hose. Put a small sponge at the hose mouth to avoid dirt back-flow in the pump.

The moisture sensor is in fact from here: BangGood. It is a resistivity based sensor, which is not corroded as others write in Hackster projects. If you power-it on for only several milliseconds each time, just enough to read the humidity, it works fine. The one I show, worked for years, without any sign of corrosion. Just use the attached software. However other issues could occur: wet mud attaching to the sensor, shows a wrong local humidity as for the rest of the pot! If the sensor is too far from the water tube, the readings will have a large delay: the time needed for water to diffuse in the pot!! Put it relatively close to the water tube to stop water pumping, before there is too much water in the pot !! Change the humidity threshold in the software, according to your plant requirements. This one pumps water below 95% humidity (after some tests with my mimosa, I changed to 75% this threshold), for a certain number seconds, depending on the pot size. Then, after the reading period (10-15 min), if the indicated humidity did not surpass the threshold, a new quantity of water is pumped, but for a limited number of iterations. This method allows time for water to diffuse in the pot. Only two watering in a given interval (8-12 hours) are allowed to avoid spilling water, before diffusion, avoiding some possible sensor temporary errors. Re-calibration of the humidity sensor every few months is recommended: adjust the thresholds in the software: the value with sensor in air (0% humidity) and the value with sensor in short-circuit (100% humidity).

As micro-controller, we suggest the AtTiny85: it has the necessary I-O pins, just enough for the purpose (and cheaper than other Micro Controllers!).

The whole device (pump included) is continuously powered from a 220V power adapter giving 9V/ 0.5A. In case of a power failure, (hopefully lasting less than a few days, or else the plant will dry out!), it is not a problem. The system will restart, reading the humidity and pump water if needed, then will reset the hours and days counter.

Powering the pump is done by a Mosfet module, but this can be done by other means too, (e.g. a relay). The display can be any other with I2C interface. This one has a parallel interface, so a I2C adapter was needed (AtTiny85 has only 6 pins!!) as shown in the left side of the following figure as a prototype board with hot glue on it!

A year (and more) later

The project works for more than 18 months. One day the moisture sensor stopped dead ("bricked" in Hackster's terms!). Fortunately the software pumps water once every 2 days if no humidity requirements occur during that period. Now it's replaced and all works fine (a new humidity threshold had to be tested and set in the code, from 95% to 75%! Variability of products and soil salinity!)

If you build a project based on this code (three versions available), thank you for pressing the "respect" button!

LCD I2C adapter (left over the display), removable Attiny85 module (up), Pololu MOSFET (down). Power (L), pump and sensor wires (R)

The chosen pump is immersed in this big bottle (5l). Enough water for 1-2 months for a small pot.

Mimosa after 6 months. Flowers as a nice reward!!

Code

/* Sketch for ATtiny85. Based on the Digispark (Use Digispark Default 16.5 MHz), no port select.
 *  Compile, Upload and then coonect ATtiny85 to USB.
 * {ATtiny85 alone pins: 1=PB5, 2=PB3,ADC3, 3=PB4,ADC2, 4=GND, 5=PB0,MOSI,SDA, 6=PB1,MISO, 7=PB2,SCK,SCL, 8=VCC}
 * ATtiny Pin 5 = PB0 (P0 on ATTiny board) = SDA 
 * ATtiny Pin 7 = PB2 (P2 on ATTiny board) = SCK=SCL 
 * ATtiny PB1 = to SWITCH power of a POLOLU MOSFET: power the Pump (6-12V)
 * ATtiny PB3 = Humidity sensor output= analog read
 * ATtiny PB4 = Power for the sensor (pin: 20mA = sufficient) 
*   Uses 26 mA for CPU, Sensor + Mosfet on + Display
 *  Uses 20 mA for CPU + Display (between readings)
 *  Uses 8 mA in deep sleep (Display on only)
 * Between reads: deep sleep. Protection against over-watering by humidity sensor. 
 */


#include <TinyWireM.h>                  // I2C Master lib for ATTinys which use USI
#include <LiquidCrystal_attiny.h>       // for LCD w/ GPIO MODIFIED for the ATtiny85
#define GPIO_ADDR 0x27                  // the address i2c for this 8x2 LCD
LiquidCrystal_I2C lcd(GPIO_ADDR, 8, 2); // set the I2C address & 8/16 chars / 2 lines
// Utility sleep macros
#include <avr/sleep.h>
#include <avr/wdt.h>                    //Needed to enable/disable watch dog timer
#define adc_disable() (ADCSRA &= ~(1<<ADEN)) // disable ADC (before power-off)
#define adc_enable()  (ADCSRA |=  (1<<ADEN)) // re-enable ADC

#define LED_BUILTIN PB5           // Change PB5 to PB1 only for testing delays
#define powsen PB4                // PB4 provides 4.1V to power the humidity sensor
#define sensor PB3                // Sensor data pin for analog read
#define pump PB1                  // Pin for LED & MOSFET feeding the Pump


// Reading humidity once in 30min...1hour is sufficient:
int D, H, nr=100;                 // Attiny85 will sleep nr*9 (sec.) (E.g. 200=>30min; 400=>1h))
unsigned long psec, corr=nr*300; // time counter since start or watering

//This runs each time the watch dog wakes us up from sleep
ISR(WDT_vect) {
  //Don't do anything. This is just here for wake up.
}

void setup() {
 lcd.init(); lcd.backlight();  lcd.clear();
 pinMode(powsen,OUTPUT);      // Power to the sensor by powsen PIN
 pinMode(sensor, INPUT);      // Sensor read value from sensor PIN
 pinMode(pump, OUTPUT);       // Pump control PIN
 pinMode(LED_BUILTIN, OUTPUT);
 
 set_sleep_mode(SLEEP_MODE_PWR_DOWN);  // sleep mode is set here
 sleep_enable();                   // enables the sleep bit in the mcucr register, so sleep is possible
 psec=0;                              // Starting moment
}

void loop() {
  adc_enable();
  digitalWrite(LED_BUILTIN, HIGH);      // turn the LED on (HIGH is the voltage level)     
  digitalWrite(powsen,HIGH);           // Power on the sensor 
  int humidity=analogRead(sensor);     // Read sensor data
  delay(200);                          // A short time, just to read the sensor!
  digitalWrite(powsen,LOW);            // Power off the humidity sensor
  digitalWrite(LED_BUILTIN, LOW);       // turn the LED off by making the voltage LOW
  // Convert analog values from sensor to humidity. Tested: free and short-circuit. 
  humidity = constrain(humidity, 85, 660);   // accept values between these limits for 4.8V on sensor 
  humidity = map(humidity, 85, 660, 0, 100); // and map them between 0 and 100%

  // The pump is started if humidity drops below a level determined for each plant!
  // Then, the pump cannot restart before 'pause', waiting for water to diffuse in the pot.
  // Set below the DRY Limit for Your Plant (E.G.: 95):
  if (humidity<=95) {                   
    digitalWrite(pump,HIGH);        // Power the pump through a Pololu-LV-MOSFET
    delay(15000);                   // Time [ms] to pump the tested REQUIRED volume of WATER to the plant!!
    digitalWrite(pump,LOW);         // Power down the pump through the MOSFET
    delay(1000);
    psec=0;                        // Reset timer of water pumping. 
    // Test that after [nr*9] seconds (15min in this case), water was absorbed and sensor is above threshold.
    // Otherwise, the pump will start again after. Warning: too much water can be bad for your plant!   
  }

  // Show the results on the screen
  lcd.setCursor(0, 0);  lcd.print("Mimosa:");
  if (humidity>95)
    if (humidity>97)
       lcd.print(")");
     else
       lcd.print("|");
  else
    lcd.print("(");
  
  lcd.setCursor(0, 1);  
  lcd.print(humidity); lcd.print("%");      // Write on LCD the humidity (%) and
  D=psec/86400;                            //  days since last watering/reset ...
  H=(psec%86400)/3600;                     //    and hours
  lcd.print(D); lcd.print("d");
  lcd.print(H); lcd.print("h ");
  
  // Most of the time, go to sleep for 'nr' multiples of 8 seconds + opp. time         
  adc_disable(); // ADC uses ~320uA
  for (int i=0; i<nr; i++){
    setup_watchdog(9); //Setup watchdog to go off after 9->8s sec + opp. time
    sleep_mode(); //Go to sleep! Wake up n sec later and work
  }
  delay(corr);                    // Timer correction since sleep is less than nr*9 sec.
  psec+=nr*9;                      // Update timer after deep sleep for Half an hour
}

// ===================================================================
void setup_watchdog(int timerPrescaler) {
    //Sets the watchdog timer to wake up, but not reset
    //0=16ms, 1=32ms, 2=64ms, 3=128ms, 4=250ms, 5=500ms
    //6=1sec, 7=2sec, 8=4sec, 9=8sec
    //From: http://interface.khm.de/index.php/lab/experiments/sleep_watchdog_battery/
  if (timerPrescaler > 9 ) timerPrescaler = 9; //Limit incoming amount to legal settings
  byte bb = timerPrescaler & 7; 
  if (timerPrescaler > 7) bb |= (1<<5); //Set the special 5th bit if necessary
  //This order of commands is important and cannot be combined
  MCUSR &= ~(1<<WDRF);            //Clear the watchdog reset
  WDTCR |= (1<<WDCE) | (1<<WDE);  //Set WD_change enable, set WD enable
  WDTCR = bb;                     //Set new watchdog timeout value
  WDTCR |= _BV(WDIE);  //Set the interrupt enable, will keep unit from resetting after each int
}

/* Sketch for ATtiny85. Based on the Digispark (Use Digispark Default 16.5 MHz), no port select.
 *  Compile, Upload and then coonect ATtiny85 to USB.
 * {ATtiny85 alone pins: 1=PB5, 2=PB3,ADC3, 3=PB4,ADC2, 4=GND, 5=PB0,MOSI,SDA, 6=PB1,MISO, 7=PB2,SCK,SCL, 8=VCC}
 * ATtiny Pin 5 = PB0 (P0 on ATTiny board) = SDA 
 * ATtiny Pin 7 = PB2 (P2 on ATTiny board) = SCK=SCL 
 * ATtiny PB1 = to SWITCH power of a POLOLU MOSFET: power the Pump (6-12V)
 * ATtiny PB3 = Humidity sensor output= analog read
 * ATtiny PB4 = Power for the sensor (20mA is sufficient) 
 * Uses 26 mA for CPU, Sensor + Mosfet
 * Uses 20 mA for CPU only (IN delay)
 * Uses 8 mA in deep sleep
 * Between reads, deep sleep. Protection against over-watering. 
 */


#include <TinyWireM.h>                  // I2C Master lib for ATTinys which use USI
#include <LiquidCrystal_attiny.h>       // for LCD w/ GPIO MODIFIED for the ATtiny85
#define GPIO_ADDR 0x27                  // the address i2c for this 8x2 LCD
LiquidCrystal_I2C lcd(GPIO_ADDR, 8, 2); // set the I2C address & 8/16 chars / 2 lines
// Utility sleep macros
#include <avr/sleep.h>
#include <avr/wdt.h>                    //Needed to enable/disable watch dog timer
#define adc_disable() (ADCSRA &= ~(1<<ADEN)) // disable ADC (before power-off)
#define adc_enable()  (ADCSRA |=  (1<<ADEN)) // re-enable ADC

#define LED_BUILTIN PB5           // Change PB5 to PB1 only for testing delays
#define powsen PB4                // PB4 provides 4.1V to power the humidity sensor
#define sensor PB3                // Sensor data pin for analog read
#define pump PB1                  // Pin for LED & MOSFET feeding the Pump


// Reading humidity once in 30min...1hour is sufficient:
int D, H, nr=100;                 // Attiny85 will sleep nr*9 (sec.) (E.g. 200=>30min; 400=>1h))
unsigned long psec, corr=nr*300; // time counter since start or watering

//This runs each time the watch dog wakes us up from sleep
ISR(WDT_vect) {
  //Don't do anything. This is just here for wake up.
}

void setup() {
 lcd.init(); lcd.backlight();  lcd.clear();
 pinMode(powsen,OUTPUT);      // Power to the sensor by powsen PIN
 pinMode(sensor, INPUT);      // Sensor read value from sensor PIN
 pinMode(pump, OUTPUT);       // Pump control PIN
 pinMode(LED_BUILTIN, OUTPUT);
 
 set_sleep_mode(SLEEP_MODE_PWR_DOWN);  // sleep mode is set here
 sleep_enable();                       // enables the sleep bit in the mcucr register, so sleep is possible
 psec=0;                              // Starting moment
}

void loop() {
  adc_enable();
  digitalWrite(LED_BUILTIN, HIGH);   // turn the LED on (HIGH is the voltage level)     
  digitalWrite(powsen,HIGH);           // Power on the sensor 
  int humidity=analogRead(sensor);     // Read sensor data
  delay(200);                          // A short time, just to read the sensor!
  digitalWrite(powsen,LOW);            // Power off the humidity sensor
  digitalWrite(LED_BUILTIN, LOW);    // turn the LED off by making the voltage LOW
  // Convert analog values fro sensor to humidity (%. Tested: free and short-circuit. 
  humidity = constrain(humidity, 85, 660);   // accept values between these limits for 4.8V on sensor 
  humidity = map(humidity, 85, 660, 0, 100); // and map them between 0 and 100%

  // Show the results on the screen
  lcd.setCursor(0, 0);  lcd.print("Mimosa:");
  if (humidity>93)
    if (humidity>96)
       lcd.print(")");
     else
       lcd.print("|");
  else
    lcd.print("(");
  
  lcd.setCursor(0, 1);  
  lcd.print(humidity); lcd.print("%");      // Write on LCD the humidity (%) and
  D=psec/86400;                            //  days since last watering/reset ...
  H=(psec%86400)/3600;                     //    and hours
  lcd.print(D); lcd.print("d");
  lcd.print(H); lcd.print("h ");
  
  // The pump is started if humidity drops below a level determined for each plant!
  // Then, the pump cannot restart before 'pause', waiting for water to diffuse in the pot.
  // Set below the DRY Limit for Your Plant (E.G.: 80):
  if (humidity<=93) {                   
    digitalWrite(pump,HIGH);        // Power the pump through a Pololu-LV-MOSFET
    delay(15000);                   // Time [ms] to pump the tested REQUIRED volume of WATER to the plant!!
    digitalWrite(pump,LOW);         // Power down the pump through the MOSFET
    delay(1000);
    psec=0;                        // Reset timer of water pumping. 
    // Test that after [nr*9] seconds (30min in this case), water was absorbed and sensor is above 80%
    // Otherwise, the pump will start again after 30 min. Too much water can be bad for the plant!   
  }
  
  // Most of the time, go to sleep for 'nr' multiples of 8 seconds + opp. time         
  adc_disable(); // ADC uses ~320uA
  for (int i=0; i<nr; i++){
    setup_watchdog(9); //Setup watchdog to go off after 9->8s sec + opp. time
    sleep_mode(); //Go to sleep! Wake up n sec later and work
  }
  delay(corr);                    // Timer correction since sleep is less than nr*9 sec.
  psec+=nr*9;                      // Update timer after deep sleep for Half an hour
}

// =======================================================================
void setup_watchdog(int timerPrescaler) {
    //Sets the watchdog timer to wake us up, but not reset
    //0=16ms, 1=32ms, 2=64ms, 3=128ms, 4=250ms, 5=500ms
    //6=1sec, 7=2sec, 8=4sec, 9=8sec
    //From: http://interface.khm.de/index.php/lab/experiments/sleep_watchdog_battery/
  if (timerPrescaler > 9 ) timerPrescaler = 9; //Limit incoming amount to legal settings

  byte bb = timerPrescaler & 7; 
  if (timerPrescaler > 7) bb |= (1<<5); //Set the special 5th bit if necessary

  //This order of commands is important and cannot be combined
  MCUSR &= ~(1<<WDRF);            //Clear the watchdog reset
  WDTCR |= (1<<WDCE) | (1<<WDE);  //Set WD_change enable, set WD enable
  WDTCR = bb;                     //Set new watchdog timeout value
  WDTCR |= _BV(WDIE);             //Set the interrupt enable, this will keep unit from resetting after each int
}

/* Water pumping device for a plant (Mimosa pudica) in a pot. 
 * Water is pumped as function of soil humidity & time intervals.
 *  Sketch for ATtiny85. Based on the Digispark (Use Digispark Default 16.5 MHz), no port select.
 *  Compile, Upload and then connect ATtiny85 module to USB cable.
 * {ATtiny85 alone pins: 1=PB5, 2=PB3,ADC3, 3=PB4,ADC2, 4=GND, 5=PB0,MOSI,SDA, 6=PB1,MISO, 7=PB2,SCK,SCL, 8=VCC}
 * ATtiny Pin 5 = PB0 (P0 on ATTiny board) = SDA 
 * ATtiny Pin 7 = PB2 (P2 on ATTiny board) = SCK=SCL 
 * ATtiny PB1 = to SWITCH power of a POLOLU MOSFET: power the Pump (6-12V)
 * ATtiny PB3 = Humidity sensor output= analog read
 * ATtiny PB4 = Power for the sensor (pin: 20mA = sufficient) 
 * Uses 26 mA for CPU, Sensor + Mosfet 
 * Uses 20 mA for CPU + Display (between readings)
 * Uses 8 mA in deep sleep (Only LCD display ON)
 * Between reads: deep sleep. Protection against over-watering by humidity sensor. 
 */


#include <TinyWireM.h>                  // I2C Master lib for ATTinys which use USI
#include <LiquidCrystal_attiny.h>       // for LCD w/ GPIO MODIFIED for the ATtiny85
#define GPIO_ADDR 0x27                  // the address i2c for this 8x2 LCD
LiquidCrystal_I2C lcd(GPIO_ADDR, 8, 2); // set the I2C address & 8/16 chars / 2 lines
// Utility sleep macros
#include <avr/sleep.h>
#include <avr/wdt.h>                    //Needed to enable/disable watch dog timer
#define adc_disable() (ADCSRA &= ~(1<<ADEN)) // disable ADC (before power-off)
#define adc_enable()  (ADCSRA |=  (1<<ADEN)) // re-enable ADC

#define LED_BUILTIN PB5           // Change PB5 to PB1 only for testing delays
#define powsen PB4                // PB4 provides 4.1V to power the humidity sensor
#define sensor PB3                // Sensor data pin for analog read
#define pump PB1                  // Pin for LED & MOSFET feeding the Pump


// Reading humidity once every 15 min...1 hour is sufficient:
// Set here the humidity threshhold (lim):
int D, H, Q, lim=75, npump=0, nr=100;// Attiny85 will sleep nr*9 (sec.) (E.g. 100=>15 min; 200=>30min; 400=>1h))
int humidity; 
unsigned long psec, corr=nr*300;  // time counter since start or watering

//This runs each time the watch dog wakes us up from sleep
ISR(WDT_vect) {
  //Don't do anything. This is just here for wake up.
}

void setup() {
 lcd.init(); lcd.backlight();  lcd.clear();
 pinMode(powsen,OUTPUT);      // Power to the sensor by powsen PIN
 pinMode(sensor, INPUT);      // Sensor read value from sensor PIN
 pinMode(pump, OUTPUT);       // Pump control PIN
 pinMode(LED_BUILTIN, OUTPUT);
 
 set_sleep_mode(SLEEP_MODE_PWR_DOWN);  // sleep mode is set here
 sleep_enable();                       // enables the sleep bit in the mcucr register, so sleep is possible
 psec=0;                              // Starting moment
}

void loop() {
  adc_enable();
  digitalWrite(LED_BUILTIN, HIGH);      // turn the LED on (HIGH is the voltage level)     
  digitalWrite(powsen,HIGH);           // Power on the sensor
  delay(200);                          // Sensor stabilization 
  humidity=analogRead(sensor);     // Read sensor data
  delay(200);                          // A short time, just to read the sensor!
  digitalWrite(powsen,LOW);            // Power off the humidity sensor
  
  // Convert analog values from sensor to humidity. Tested: free and short-circuit. 
  humidity = constrain(humidity, 85, 660);   // accept values between these limits for 4.8V on sensor 
  humidity = map(humidity, 85, 660, 0, 100); // and map them between 0 and 100%


  // Show the results on the screen
  lcd.setCursor(0, 0);  
  lcd.print("Min="); lcd.print(lim); lcd.print("%");
  lcd.setCursor(0, 1);  
  lcd.print("NOW=");lcd.print(humidity); lcd.print("%");      // Write on LCD the humidity (%)
  delay(3000);


  if (humidity==0){
    lcd.setCursor(0, 0);  
    lcd.print("S-ERROR!");
    delay(10000);
  }
  
  
  //===============================================================================
  if (H>=8)
    npump=0;                      // After 8 Hours: reset the number of water pumpings: new pump possible.. 
                                  //  if humidity <= lim
  //===============================================================================
  // The pump is started if humidity drops below a lim level determined for each plant, 
  //  and in any case 2 days after the last watering (if the sensor is in wet mud and the rest is dry!)
  // The pump is activated for max 2 times at psec interval, waiting for water to diffuse in the pot.
  // Set below the DRY Limit for Your Plant (E.G.: 80 to 95):
  if ((humidity <= lim || D >= 2) && npump <=2) {                   
    digitalWrite(pump,HIGH);        // Power the pump through a Pololu-LV-MOSFET
    delay(14000);                   // Pumping time 10 -14 [s] to pump the tested REQUIRED volume of WATER to the plant!!
    digitalWrite(pump,LOW);         // Power down the pump through the MOSFET
    psec=0;                         // Reset timer of water pumping.
    npump++;                        // Count the pumping. Max 3/ 24H to avoid flooding and have uniform humidity. 
    // Test that after [nr*9] seconds (15min in this case), water was absorbed and sensor is above threshold.
    // Otherwise, the pump will restart too soon. Warning: too much water can be bad for your plant! 
    // To avoid flooding, no more than 2 (npump) pumpings in 12 Hours are allowed!

    // After a few seconds, read again the humidity:
    delay(3000);
    digitalWrite(powsen,HIGH);           // Power on the sensor
    delay(200);                          // Sensor stabilization 
    humidity=analogRead(sensor);         // Read sensor data
    delay(200);                          // A short time, just to read the sensor!
    digitalWrite(powsen,LOW);            // Power off the humidity sensor
    // Convert analog values from sensor to humidity. Tested: free and short-circuit. 
    humidity = constrain(humidity, 85, 660);   // accept values between these limits for 4.8V on sensor 
    humidity = map(humidity, 85, 660, 0, 100); // and map them between 0 and 100% 
    lcd.setCursor(0, 1);  
    lcd.print(humidity); lcd.print("%");      // Write on LCD the humidity (%)
  }
  
  lcd.setCursor(0, 0);
  lcd.print("Mimosa>");
  if (humidity>=lim)
    if (humidity>lim+2)
       lcd.print(")");
     else
       lcd.print("|");
  else
    lcd.print("(");
  if (humidity==0){
    lcd.setCursor(0, 0);  
    lcd.print("S-ERROR!");
    delay(10000);
  } 


  lcd.setCursor(0, 1);  
  lcd.print(humidity); lcd.print("%");      // Write on LCD the humidity (%) and mark
  D=psec/86400;                            //  days since last watering/reset ...
  H=(psec%86400)/3600;                     //    and hours
  Q=((psec%86400)%3600)/900;               //    and quarter of hours
  lcd.print(D); lcd.print("d");
  lcd.print(H); lcd.print("h");
  lcd.print(Q*15);lcd.print("m");
  
  digitalWrite(LED_BUILTIN, LOW);       // turn the LED off by making the voltage LOW  
  
  // Most of the time, go to sleep for 'nr' multiples of 8 seconds + opp. time         
  adc_disable();                        // ADC uses ~320uA
  for (int i=0; i<nr; i++){
    setup_watchdog(9);                  //Setup watchdog to go off after 9->8s sec + opp. time
    sleep_mode();                       //Go to sleep! Wake up n sec later and work
  }
  delay(corr);                          // Timer correction since sleep is less than nr*9 sec.
  psec+=nr*9;                           // Update timer after deep sleep for Quarter/Half an hour
}

// =======================================================================
void setup_watchdog(int timerPrescaler) {
    //Sets the watchdog timer to wake up, but not reset
    //0=16ms, 1=32ms, 2=64ms, 3=128ms, 4=250ms, 5=500ms
    //6=1sec, 7=2sec, 8=4sec, 9=8sec
    //From: http://interface.khm.de/index.php/lab/experiments/sleep_watchdog_battery/
  if (timerPrescaler > 9 ) timerPrescaler = 9; //Limit incoming amount to legal settings

  byte bb = timerPrescaler & 7; 
  if (timerPrescaler > 7) bb |= (1<<5); //Set the special 5th bit if necessary

  //This order of commands is important and cannot be combined
  MCUSR &= ~(1<<WDRF);            //Clear the watchdog reset
  WDTCR |= (1<<WDCE) | (1<<WDE);  //Set WD_change enable, set WD enable
  WDTCR = bb;                     //Set new watchdog timeout value
  WDTCR |= _BV(WDIE);             //Set the interrupt enable, this will keep unit from resetting after each int
}

Credits

M.V.P.

7 projects • 46 followers

Arduino: Amazing, useful and rewarding hobby for some!

ATtiny85 Plant Watering Autonomous System

Things used in this project

Hardware components

Software apps and online services

Story

Schematics

Fritzing schematics

Code

Arduino code for Attiny-plant-care

New version

Latest version

Credits

M.V.P.

Comments

Embed the widget on your own site

ATtiny85 Plant Watering Autonomous System

ATtiny85 Plant Watering Autonomous System

Things used in this project

Hardware components

Software apps and online services

Story

Schematics

Fritzing schematics

Code

Arduino code for Attiny-plant-care

New version

Latest version

Credits

M.V.P.

Comments

Related channels and tags