Team A&T Robotics:

•

teddyyoonie

Published July 4, 2022 © GPL3+

Solar irradiance comparison fixed vs. tracking

Compares solar irradiance performance between fixed system and a tracking system

IntermediateFull instructions provided604

Solar irradiance comparison fixed vs. tracking

Things used in this project

Hardware components

Arduino UNO

5.5V 80mA Solar Panel

Resistor 10k ohm

Resistor 22.1 ohm

Breadboard (generic)

Nema 17 Stepper Motor

SparkFun Stepper motor driver board A4988

12V 2A Power Supply AC Adapter

MG995 servo motor

Story

About this project

This project compares solar panel irradiance between two well-known systems – fixed vs. tracking. Most solar generation systems used for residential areas have fixed solar panels, frequently mounted on the roof. Some solar generation sites have panels mounted in the fixed but optimal angle that can be used year-round. Some sites use adjustable tilt angle panels whose tilt angles are adjusted each season to improve efficiency.

This project will have two solar panels – one is fixed (orientation and tilt) and the other tracks the sun and compare solar irradiance performance of the two systems. For tracking system, the solar panel’s tilt angle is adjusted by a servo motor, and the servo motor is mounted on the stepper for orientation adjustment. From morning to evening, orientation and tilt angle are adjusted to improve solar irradiance. By comparing this with that of fixed panel, net benefit of solar tracking over fixed system is obtained.

The CAD model shows how the tracking system is constructed. A solar panel is attached to a servo motor with a 3-D printed adapter, and the servo motor sits on the acrylic disk glued to the stepper motor.

Sun angle calculation

There are quite a few sites that provide how to calculate Sun’s angle (elevation and azimuth) at a certain location. This project uses the following website to have sun’s elevation and azimuth angles at a specific day and time. This information is entered in the code and the stepper motor and servo motor are used to adjust tilt and orientation of the panel to match the entered data.

How to measure solar irradiance

There is a published project that compares irradiance performance of solar panels using a simple resistor circuit. This method is simple but effective, and also lets the user select solar panels having minimal variation in of performance.

Resistor Circuit

In this project two pre-characterized toy-grade solar panels are used. The nominal specs are, 60mmx60mm, 5.5V, 80mA. Voltage across the resistor is measured every 15 minutes, from 8am to 6pm.

Stepper motor control

Nema 17 bipolar stepper motor is controlled by A4988 stepper motor driver. The stepper motor has 1.8deg step angle which provides a good resolution for orientation without micro-stepping.

16 VMOT -- stepper motor power supply + terminal

15 GND -- stepper motor power supply Gnd

10 VDD -- Arduino 5V

9 GND -- Arduino Gnd

5 RST and 6 SLP are tied together

1 EN, 2 MS1, 3 MS2, and 4 MS3 are left open (full step mode)

7 STEP -- Arduino digital 3

8 DIR -- Arduino digital 2

The A4988_test.ino can be used to test run the stepper motor. Assumes initial orientation being 180deg (south), the orientation angle can be set using moveTo() function. When a target orientation is entered as an argument, it decodes the direction and the number of steps required, and rotates the motor to the target orientation. The example code first moves to 90deg (corresponds to east), and moves to 135deg, 180deg, 225deg, 270deg (corresponds to west), and then brings back to the initial orientation (180deg).

Stepper motor connection

MG995 servo motor

MG995 servo motor controls tilt angle of the panel. Servo motor is easy with Arduino servo library. MG995 VCC and GND are connected to Arduino’s 5V and GND, respectively. And PWM pin is connected to one of Arduino’s PWM pins. In this example, Digital 6 is used. MG995’s angle can be easily adjusted by the servo library’s write() command with the target angle as an argument. It will be easier to mount the solar panel to the motor in the correct position if 0 deg position is marked on the servo motor.

VCC – 5V

GND – GND

PWM – Arduino Digital 6

A4988_MG995_test1.ino code can be used to test both stepper motor and servo together.

Stepper motor & Servo Motor

Hardware setuppicture

Arduino and solar panels

Ground terminals of solar panels are all connected to Gnd of Arduino. Positive terminal of each solar panel is connected to 10kOhm resistor, and the other end of resistor is connected to Analog Input. A0 collects panel #1 data, and A1 collects panel #2 data.

Data collection

For data collection, sun’s azimuth and elevation angles for every 15min are calculated and tabulated in arrays, from 8:00am to 6:00pm. Every 15 minutes, the program sets the orientation and tilt angle per the values in the arrays, collect voltages of the solar panels, and print them on Arduino IDE’s serial monitor.

Solar Panel Tracking the sun

Results

The test was done on early July. The measurement system operated as designed but it was not a good day for solar measurement. It was very cloudy until 10:00am and spotty clouds were not very favorable to the measurement. But still there was meaningful difference in the result. When sun’s elevation is high, both tracking and fixed systems show very similar irradiance performance. But as it gets later afternoon, the difference between the two systems is noticeable. The tracking system still shows fair amount of irradiance unlike the fixed system. At 6:00pm, the fixed system’s irradiance is almost zero while the tracking system still shows a good performance.

Graph shows the difference between Tracking and Fixed Solar Panels

Schematics

Code

/*
 *12V motor: A4988 - orientation
*/

#include <Arduino.h>

#define DIR_PIN   2 //direction
#define STEP_PIN  3 //step

const int stepPause = 15; // micro seconds between step motor input pulses
const float stepAngle = 1.8;  //1.8deg/step
float orientation = 180.;  // current orientation

void setup()
{
  //set pin modes
  pinMode(DIR_PIN, OUTPUT);
  pinMode(STEP_PIN, OUTPUT);
  
  digitalWrite(DIR_PIN, LOW); //LOW = CW, HIGH = CCW
  digitalWrite(STEP_PIN, LOW);
  
  Serial.begin(9600);
  Serial.println("Booting");
}

void loop()
{
  Serial.print("Orientation: ");
  Serial.println(orientation);

  moveTo(90);
  delay(1000);
  Serial.print("Orientation: ");
  Serial.println(orientation);

  moveTo(135);
  delay(1000);
  Serial.print("Orientation: ");
  Serial.println(orientation);

  moveTo(180);
  delay(1000);
  Serial.print("Orientation: ");
  Serial.println(orientation);

  moveTo(225);
  delay(1000);
  Serial.print("Orientation: ");
  Serial.println(orientation);

  moveTo(270);
  delay(1000);
  Serial.print("Orientation: ");
  Serial.println(orientation);

  moveTo(180);
  delay(1000);
  Serial.print("Orientation: ");
  Serial.println(orientation);
}

void moveSteps(int steps)
{
  if (steps > 0)
    digitalWrite(DIR_PIN, LOW); //LOW or HIGH
  else
    digitalWrite(DIR_PIN, HIGH);
    
  for (int i = 0; i < abs(steps); i++)
  {
    digitalWrite(STEP_PIN, HIGH);    
    delay(stepPause);
    digitalWrite(STEP_PIN, LOW);      
    delay(stepPause);
  }
}

void moveTo(float angle)
{
  int steps = round((angle - orientation) / stepAngle);
  orientation += steps * stepAngle;
  moveSteps(steps);
}

/*
 *12V motor: A4988 - orientation
 * MG995 Servo motor - tilt angle
*/

#include <Arduino.h>
#include <Servo.h> // include servo library

#define DIR_PIN   2 //direction
#define STEP_PIN  3 //step
#define MG995_IN 6 // Name Digital D6 pin of Arduinol

Servo mg995Servo;  // Initialize a servo object

const int stepPause = 15; // micro seconds between step motor input pulses
const float stepAngle = 1.8;  //1.8deg/step
float orientation = 180.;  // current orientation
int count = 0; // int to count loop iteration

float orient[] = {77.8, 79.9, 81.9, 84.0, 86.1, 88.2, 90.5, 92.8, 95.3, 98.0, 
                  100.9, 104.0, 107.5, 111.5, 116.1, 121.5, 127.9, 135.7, 145.1, 156.3,
                   169.2, 183.0, 196.6, 208.8, 219.3, 227.9, 235.0, 241.0, 246.0, 250.3,
                   254.0, 257.4, 260.4, 263.2, 265.8, 268.2, 270.5, 272.7, 274.8, 276.9, 
                   279.0};
float tilt[] = {23.0, 25.9, 28.8, 31.8, 34.8, 37.7, 40.7, 43.7, 46.7, 49.6,
                52.6, 55.5, 58.4, 61.2, 63.9, 66.5, 69.0, 71.2, 73.1, 74.5,
                 75.4, 75.6, 75.1, 74.0, 72.3, 70.2, 67.9, 65.4, 62.7, 59.9,
                 57.1, 54.2, 51.3, 48.3, 45.4, 42.4, 39.4, 36.4, 33.5, 30.5, 
                 27.5};

void setup()
{
  //set pin modes
  pinMode(DIR_PIN, OUTPUT);
  pinMode(STEP_PIN, OUTPUT);
  
  digitalWrite(DIR_PIN, LOW); //LOW = CW, HIGH = CCW
  digitalWrite(STEP_PIN, LOW);
  
  Serial.begin(9600);
  mg995Servo.attach(MG995_IN);  // Attach signal pin of MG995 to D6 pin
  
}

void loop()
{
  int iter = count % 41;

  moveTo(orient[iter]);
  mg995Servo.write(tilt[iter]);
  Serial.print(count);
  Serial.print(",");
  Serial.print(orientation);
  Serial.print(",");
  Serial.println(tilt[iter]);

  delay(500); // sets the interval between orientations

  count++;

}

void moveSteps(int steps)
{
  if (steps > 0)
    digitalWrite(DIR_PIN, LOW); //LOW or HIGH
  else
    digitalWrite(DIR_PIN, HIGH);
    
  for (int i = 0; i < abs(steps); i++)
  {
    digitalWrite(STEP_PIN, HIGH);    
    delay(stepPause);
    digitalWrite(STEP_PIN, LOW);      
    delay(stepPause);
  }
}

void moveTo(float angle)
{
  int steps = round((angle - orientation) / stepAngle);
  orientation += steps * stepAngle;
  moveSteps(steps);
}

/*
 *12V motor: A4988 - orientation
 * MG995 Servo motor - tilt angle
 * 
 * Solar panel terminals to Arduino:
  analog in A0 -- panel 1 -- fixed
  analog in A1 -- panel 2 -- tracking

*/

#include <Arduino.h>
#include <Servo.h> // include servo library

#define DIR_PIN   2 //direction
#define STEP_PIN  3 //step
#define MG995_IN 6 // Name Digital D6 pin of Arduinol

Servo mg995Servo;  // Initialize a servo object

const int stepPause = 15; // micro seconds between step motor input pulses
const float stepAngle = 1.8;  //1.8deg/step
float orientation = 180.;  // current orientation
int count = 0; // int to count loop iteration

int analogPin1 = A0;  //solar panel #1
int analogPin2 = A1;  //solar panel #2
                    
float orient[] = {77.8, 79.9, 81.9, 84.0, 86.1, 88.2, 90.5, 92.8, 95.3, 98.0, 
                  100.9, 104.0, 107.5, 111.5, 116.1, 121.5, 127.9, 135.7, 145.1, 156.3,
                   169.2, 183.0, 196.6, 208.8, 219.3, 227.9, 235.0, 241.0, 246.0, 250.3,
                   254.0, 257.4, 260.4, 263.2, 265.8, 268.2, 270.5, 272.7, 274.8, 276.9, 
                   279.0};
float tilt[] = {23.0, 25.9, 28.8, 31.8, 34.8, 37.7, 40.7, 43.7, 46.7, 49.6,
                52.6, 55.5, 58.4, 61.2, 63.9, 66.5, 69.0, 71.2, 73.1, 74.5,
                 75.4, 75.6, 75.1, 74.0, 72.3, 70.2, 67.9, 65.4, 62.7, 59.9,
                 57.1, 54.2, 51.3, 48.3, 45.4, 42.4, 39.4, 36.4, 33.5, 30.5, 
                 27.5};

void setup()
{
  Serial.begin(9600);

  for (int i = 10; i > 0; i--)
  {  
    Serial.print(i); 
    Serial.print(", "); 
    delay(1000);
  }
  Serial.println(" "); 
      
  //set pin modes
  pinMode(DIR_PIN, OUTPUT);
  pinMode(STEP_PIN, OUTPUT);
  
  digitalWrite(DIR_PIN, LOW); //LOW = CW, HIGH = CCW
  digitalWrite(STEP_PIN, LOW);
  
  mg995Servo.attach(MG995_IN);  // Attach signal pin of MG995 to D6 pin

  
}

void loop()
{
  // start of operation
  int iter = count % 41;

  moveTo(orient[iter]);
  mg995Servo.write(tilt[iter]);
  Serial.print(count);
  Serial.print(",");
  Serial.print(orientation);
  Serial.print(",");
  Serial.println(tilt[iter]);

  // read panel data
  analogReference(DEFAULT);
  readPanelData(); // Call readPanleData() function
  delay(60000 * 15); // sets the interval between orientations

  count++;
}

void moveSteps(int steps)
{
  if (steps > 0)
    digitalWrite(DIR_PIN, LOW); //LOW or HIGH
  else
    digitalWrite(DIR_PIN, HIGH);
    
  for (int i = 0; i < abs(steps); i++)
  {
    digitalWrite(STEP_PIN, HIGH);    
    delay(stepPause);
    digitalWrite(STEP_PIN, LOW);      
    delay(stepPause);
  }
}

void moveTo(float angle)
{
  int steps = round((angle - orientation) / stepAngle);
  orientation += steps * stepAngle;
  moveSteps(steps);
}

void readPanelData() {

  Serial.print(count); 
  Serial.print(","); 

  int val1 = analogRead(analogPin1);
  delay(100);
  int val2 = analogRead(analogPin1);
  delay(100);
  int val = int((val1 + val2)/2); // average
  Serial.print(val); 
  Serial.print(",");   
  delay(100);

  val1 = analogRead(analogPin2);
  delay(100);
  val2 = analogRead(analogPin2);
  delay(100);
  val = int((val1 + val2)/2); // average

  Serial.println(val); 
}

Credits

walkingnewbie

2 projects • 2 followers

teddyyoonie

3 projects • 1 follower

Solar irradiance comparison fixed vs. tracking

Things used in this project

Hardware components

Story

About this project

Sun angle calculation

How to measure solar irradiance

Stepper motor control

MG995 servo motor

Arduino and solar panels

Data collection

Results

Custom parts and enclosures

Assembly of tracking panel

Schematics

Full Measurement system

Code

Stepper Motor test

Stepper Motor & Servo Motor Test

Main Test Program

Credits

walkingnewbie

teddyyoonie

Comments

Embed the widget on your own site

Solar irradiance comparison fixed vs. tracking

Solar irradiance comparison fixed vs. tracking

Things used in this project

Hardware components

Story

About this project

Sun angle calculation

How to measure solar irradiance

Stepper motor control

MG995 servo motor

Arduino and solar panels

Data collection

Results

Custom parts and enclosures

Assembly of tracking panel

Schematics

Full Measurement system

Code

Stepper Motor test

Stepper Motor & Servo Motor Test

Main Test Program

Credits

walkingnewbie

teddyyoonie

Comments

Related channels and tags