Published November 5, 2021 © LGPL

Saving Your Sanity From Daylight Saving

We stand with Cousin Micki.

IntermediateFull instructions provided2 hours176

Things used in this project

Hardware components

Espressif Wemos D1 Mini

MAX7219 Microcontroller 4 In 1 Display LED 5P Line Dot Matrix Module

Software apps and online services

PlatformIO IDE

worldtimeapi.org

Story

It happens twice a year. At least one of my clocks is off by one hour because of Daylight Saving. This time, I'll be ready. Instead of hacking my old alarm clock, I built a clock using WeMos D1 Mini and couple of LED Matrix modules.

There are a lot of self setting clock projects out there, but I wanted to build something on my own. Instead of using https://worldclockapi.com/api/json/utc/now like I did in https://www.hackster.io/abouhatab/if-the-allegations-are-not-legit-you-m-aws-t-edukit-326d38 I decided to use http://worldtimeapi.org/api/ip to get the time. The main difference is getting local time directly instead of getting UTC then having to figure out the time difference. I didn't even have to send my public IP address.

I also used WiFiManager to avoid hard coding Wi-Fi credentials. I may add buttons later to adjust the clock manually (like my old alarm clock) if for some reason I have no internet.

Stay tuned.

Code

#include <WiFiManager.h>
#include <esp8266httpclient.h>
#include <ArduinoJson.h>
#include <U8g2lib.h>

WiFiClient client;
HTTPClient http;
StaticJsonDocument<1000> doc;
U8G2_MAX7219_64X8_F_4W_HW_SPI u8g2(U8G2_R2, SS, U8X8_PIN_NONE);
int h, m, s;
unsigned long Timestamp;
char buffer[7];

void GetTime(void)
{
  Serial.printf("%02d:%02d:%02d %s\r\n", h == 0 ? 12 : (h > 12 ? h - 12 : h), m, s, h > 11 ? "PM" : "AM");
  do
  {
    http.begin(client, "http://worldtimeapi.org/api/ip");
    yield();
  }
  while (http.GET() < 0);
  deserializeJson(doc, http.getString());
  http.end();
  h = doc["datetime"].as<String>().substring(11, 13).toInt();
  m = doc["datetime"].as<String>().substring(14, 16).toInt();
  s = doc["datetime"].as<String>().substring(17, 19).toInt();
  Serial.printf("%02d:%02d:%02d %s\r\n", h == 0 ? 12 : (h > 12 ? h - 12 : h), m, s, h > 11 ? "PM" : "AM");
}

void setup()
{
  u8g2.begin();
  u8g2.setContrast(0);
  u8g2.setFont(u8g2_font_chikita_tr);
  u8g2.clearBuffer();
  u8g2.drawStr(1, 6, "Connecting...");
  u8g2.sendBuffer();
  u8g2.setFont(u8g2_font_victoriabold8_8r);
  Serial.begin(115200);
  WiFiManager wm;
  wm.autoConnect("WeMos");
  GetTime();
}

void loop()
{
  if (millis() - Timestamp > 1000)
  {
    Timestamp = millis();
    s++;
    if (s > 59)
    {
      s = 0;
      m++;
      if (m > 59)
      {
        GetTime();
      }
    }
    sprintf(buffer, "%02d:%02d%s", h == 0 ? 12 : (h > 12 ? h - 12 : h), m, h > 11 ? "PM" : "AM");
    u8g2.clearBuffer();
    u8g2.drawStr(0, 7, buffer);
    u8g2.sendBuffer();
  }
}