If you want to use my sketch, you must use my attached Google Script and use the following in Pushingbox
Project update - the future is here!

Published March 21, 2017 © CC BY-NC

Cloud-Based Temperature Logger For Homebrew Fermenter

Using battery powered NodeMCU v2 and DS18B20 thermometer to log temperature and system voltage on Google Sheets.

BeginnerWork in progress3 hours3,195

Cloud-Based Temperature Logger For Homebrew Fermenter

Things used in this project

Hardware components

NodeMCU ESP8266 Breakout Board

NodeMCU v2

Jumper wires (generic)

Breadboard (generic)

Maxim Integrated DS18B20 Programmable Resolution 1-Wire Digital Thermometer

USB-A to Micro-USB Cable

18650 Micro USB 1A Charging Board

Software apps and online services

Arduino IDE

Google Sheets

Pushingbox

Story

I have been brewing beer for the past two years and have continuously made small improvements to my brewing equipment in the hope of making my beer more consistently delicious.

I hadn't considered fermentation temperature until I experienced a stalled fermentation in a Westmalle Dubbel clone. After that, I wanted to know everything I could about the temperature of my fermentation, so I went about making a device.

Being a total novice to Arduino, I combined the projects below in order to get exactly the device I needed. Rather than duplicate these excellent resources, it's probably better to follow these and make a few adjustments along the way.

All it needed to do was:

run from a battery for multiple days

fetch system voltage

fetch temperature from a waterproof thermometer

log this data, with a timestamp to a cloud based service

Using the attached sketch, and hardware, the bulk of the project should work. The most complicated aspect was getting the data to Google Sheets through Pushingbox, but the guide above by Stephen Borsay worked perfectly. In the comments of his project, Amol P suggests that this is possible without Pushingbox, but I was unable to get this to work.

If you want to use my sketch, you must use my attached Google Script and use the following in Pushingbox.

?celData=$celData$&volData=$volData$

Here is a link to my Google Sheet to show the logged data, which I am over the moon with! I am currently testing different battery capacities, and sleep intervals so it is a little messy. https://docs.google.com/spreadsheets/d/1vhIw8N9_N7dHcB3fNVhj1E9cVRg9hRfgyqzK-10kAeI/

Here is a top-down image of the breadboard I have the hardware hooked up to.

After some testing, I have found that a 1200mAhr battery lasts approximately 5 days. Unexpectedly, changing logging frequency between 60 and 15 minutes has little affect on battery life. I do have a problem remembering to check on the battery voltage, so I may set up an email alarm when voltage drops to 3v on Google Sheets.

I am satisfied if I get a few days out of the device without having to recharge, but a few physical alterations on the NodeMCU could extend the battery life to months. I am a bit reluctant to make these changes, but please see https://tinker.yeoman.com.au/2016/05/29/running-nodemcu-on-a-battery-esp8266-low-power-consumption-revisited/ for a great discussion on doing this.

My ultimate goal is to find or make an enclosure that will contain the project, so that it can be dropped straight into the fermenter and active fermentation temperature can be observed directly.

It will need to be:

food safe

openable

water tight

fairly conductive to heat

But that's for the future - any suggestions are very much welcomed!

Project update - the future is here!

I tried my best to find a submersible enclosure for the project above, but I quickly realised the project was far too bulky for the kind of containers I could find in my local supermarket. I looked for NodeMCU v2 equivalents, and was pleased to find a very compact alternative, the Wemos D1 Mini (mine is by Wavgat). I was sceptical that I could throw the same code onto it, but after a brief configuration on Arduino it was up and running. Sadly, the internal voltage readings were unreliable when compared to my multimeter. I looked for another method of providing battery voltage on the D1 Mini and found a helpful post:

https://arduinodiy.wordpress.com/2016/12/25/monitoring-lipo-battery-voltage-with-wemos-d1-minibattery-shield-and-thingspeak/

After a good read, I added the following to my code:

// Read A0 and scale it to match multimeter (must have 100K resistor between A0 and positive terminal of cell).
float volData;
pinMode(A0, INPUT);
volData = analogRead(A0);
volData = (volData/1024)*4.52;

On a side note, after taking the 1200mAhr battery through a few charge cycles, it appears the D1 Mini consumes much less power. At the time of writing, 27 days after it's last charge, the battery has dropped from 4.12v to 3.96v (2449 readings at 15 minute intervals). I have been using a Poundshop LiPo AA sized battery that I have short-circuited more times than I can count. The NodeMCU v2 would rarely make it to 7 days before running a 1200mAhr battery flat.

I had a look at other projects that had enclosures suitable for the D1 Mini, and stumbled upon the marvellous iSpindel project: https://universam1.github.io/iSpindel/

It is a fascinating project that focuses on measuring the inclination angle of a heeling cylinder in order to relate this to density of the surrounding medium. I don't have a use for this, but the container was a perfect size. I eventually sourced one from uniquegeocaches on eBay. It was described as an XL PET preform soda bottle and came from Lithuania.

Once the enclosure arrived I started stuffing the various components in there, but realised I needed some sort of structure. I purchased a breadboard that would fit in the bottle and crossed my fingers that I could stick/tie/solder my components to it.

I tried a number of combinations, but settled on the following configuration. I wasn't brave enough to commit to soldering everything at this stage.

'Front' showing D1 mini and 18650 charging board mounted on breadboard

'Back' showing 1200mAhr LiPo battery and DS18B20 temperature sensor

As you can see, there were some superficial additions to the project mainly due to the introduction of the enclosure. I added a generic QI compatible wireless charger, which can be used to receive power from a QI charging pad without having to disturb the components.

I also added small lead weights in the form of split-shot (more commonly used in angling). More lead weights can be added to ensure the project is submerged and measuring the actual fermentation temperature.

Here is the finished project, ready to hit the wort!

Mission complete - now to decide on a name!

Code

//Required libraries
#include "ESP8266WiFi.h"
#include "OneWire.h"
#include "DallasTemperature.h"

// Data wire is plugged into pin 2 on the Arduino, which maps to D4 on this board.
#define ONE_WIRE_BUS 2

// Setup a OneWire instance to communicate with any OneWire devices.
  OneWire oneWire(ONE_WIRE_BUS);

// Pass our OneWire reference to Dallas Temperature.
  DallasTemperature sensors(&oneWire);

// Sleep time / logging interval in seconds (accounting shift in data logging).
  const int sleeptime = 935;

// Pushingbox API server.
  const char WEBSITE[] = "api.pushingbox.com";

// Device ID from Pushingbox
  const String devid = "vD1F0274433B664B";

// Wifi SSID
  const char* MY_SSID = "SSID";

// Wifi password
  const char* MY_PWD =  "PASSWORD";

// Used at the beginning of sketch to read VCC voltage (ADC pin must be free)
  ADC_MODE(ADC_VCC);

void setup()
{
// Begin connection to Wireless LAN.
  Serial.begin(115200);
  Serial.println("");
  Serial.println("ESP8266/NodeMCU is awake.");
  Serial.print("Attempting connection to designated Wireless LAN");
  WiFi.begin(MY_SSID, MY_PWD);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(1000);
    Serial.print(".");
  }
  Serial.println(" connected to Wireless LAN!");

// Issue a global temperature request to all devices on the bus.
  Serial.print("Reading DS18B20 sensor...");
  sensors.requestTemperatures();
  delay (1000);

// Read temperature as celsius (this is the default).
  float celData = sensors.getTempCByIndex(0);

// Read VCC and scale it to match multimeter.
  float voltage = ESP.getVcc() / 1000.0 * 1.53
  ;

// Check if there are any read failures and exit early to try again.
  if (isnan(celData))
  {
    Serial.println("Failed to read from DS18B20 sensor!");
    return;
  }

// Print to serial monitor or terminal of your choice, at 115200 baud.
  Serial.print(" the temperature is ");
  Serial.print(celData);
  Serial.println(" *C ");
  Serial.print("The battery is reading ");
  Serial.print(voltage);
  Serial.println(" volts.");

// Instantiate WiFi object.
  WiFiClient client;

// Start API service using our WiFi client through PushingBox.
  if (client.connect(WEBSITE, 80))
  {
    client.print("GET /pushingbox?devid=" + devid
                 + "&celData="      + (String) celData
                 + "&voltage="      + (String) voltage
                );
    client.println(" HTTP/1.1");
    client.print("Host: ");
    client.println(WEBSITE);
    client.println("User-Agent: ESP8266/1.0");
    client.println("Connection: close");
    client.println();
  }
  Serial.println("Data was sent to Google Sheets via Pushingbox.");

// Sending ESP8266/NodeMCU into deep sleep (requires jumper between RST and D0).
  Serial.println("ESP8266/NodeMCU is now going to sleep.");
  ESP.deepSleep(sleeptime * 1000000, WAKE_RF_DEFAULT);
  delay(1000);

}

void loop()
{
  
}

//-----------------------------------------------
//Originally published by Mogsdad@Stackoverflow
//Modified for jarkomdityaz.appspot.com
//Modified for Hackster.io by Stephen Borsay
//-----------------------------------------------
/*

GET request query:

https://script.google.com/macros/s/<gscript id>/exec?celData=data_here
----------------------------------------------------------------------

GScript, PushingBox and Arduino/ESP8266 Variables in order:

celData
volData
----------------------------------------------------
*/


/* Using spreadsheet API */

function doGet(e) { 
  Logger.log( JSON.stringify(e) );  // view parameters

  var result = 'Ok'; // assume success

  if (e.parameter == undefined) {
    result = 'No Parameters';
  }
  else {
    var id = '1vhIw8N9_N7dHcB3fNVhj1E9cVRg9hRfgyqzK-10kAeI';//docs.google.com/spreadsheetURL/d
    var sheet = SpreadsheetApp.openById(id).getActiveSheet();
    var newRow = sheet.getLastRow() + 1;
    var rowData = [];
    //var waktu = new Date();
    rowData[0] = new Date(); // Timestamp in column A
    
    for (var param in e.parameter) {
      Logger.log('In for loop, param='+param);
      var value = stripQuotes(e.parameter[param]);
      //Logger.log(param + ':' + e.parameter[param]);
      switch (param) {
        case 'celData'://parameter1
          rowData[1] = value;//value1
          break;
        case 'volData'://parameter2
          rowData[2] = value;//value2
          break;
          default:
          result = "unsupported parameter";
      }
    }
    Logger.log(JSON.stringify(rowData));

    // Write new row below
    var newRange = sheet.getRange(newRow, 1, 1, rowData.length);
    newRange.setValues([rowData]);
  }

  // Return result of operation
  return ContentService.createTextOutput(result);
}

/**
* Remove leading and trailing single or double quotes
*/
function stripQuotes( value ) {
  return value.replace(/^["']|['"]$/g, "");
}