Created December 3, 2015

Remote-Controlled Car (Pt 4): Bluetooth Wireless Control

IntermediateWork in progress1,875

Things used in this project

Hardware components

Breadboard (generic)

Jumper wires (generic)

Arduino UNO

Adafruit Bluefruit LE nRF8001

SparkFun Dual H-Bridge motor drivers L298

Software apps and online services

Adafruit Bluefruit LE Connect

For Android

Arduino IDE

Hand tools and fabrication machines

Soldering iron (generic)

Story

First, I cut a strip of male header pins to the correct length, which was 10 pins. Then, I installed the Adafruit library (Software: UART Service) according to the Adafruit Tutorial.

I also installed Adafruit Bluefruit LE Connect app on my Android smartphone.

I then connected the bluetooth module nRF001 to the arduino following the instructions and schematic in the above tutorial. Everything was the same except the RST went to pin 4 instead of pin 9~ since the 9~ pin was already being used by one of the motors on my vehicle.

Bluetooth module connected to arduino

Closeup of bluetooth

To run echoDemo, I used the code provided on the site and changed the pin for RST from 9 to 4. Note that you need to import the code into the Arduino Libraries folder. In order to do this on Mac, go to Finder > Applications > [Right click] Arduino > Show Package Contents. Then find the folder "libraries" by opening the Contents folder followed by the Java folder. Drag the Adafruit_nRF8001 folder into the libraries folder. There will also be the examples echoDemo and callbackDemo, which you should put into the "examples" folder, also in the Java folder. Put the two demo files into its own folder called Adafruit_nRF8001 within the "examples" folder.

When I ran the echoDemo, I received the error message, "Adafruit Bluefruit Low Energy nRF8001 Print echo demo" in the serial monitor with baud rate 11520, , which means the bluetooth module never connected. When I removed the bluetooth module, I received the same message. Interestingly, I saw the bluetooth via my phone, but was unable to connect.

Screenshot of phone trying to connect to Bluefruit LE

Then, I tried the datamode tutorial by following the instructions on this website: https://learn.adafruit.com/introducing-the-adafruit-bluefruit-le-uart-friend?view=all In the software section, I scrolled to the "Select the Serial Bus" section. I followed the instructions for "UART Based Boards (Bluefruit LE UART Friend)", which instructs you to uncomment the Software Serial lines and to comment out the hardware SPI lines in the example. I also changed the pin for RST from 9 to 4. The code compiled, but output the error message "Couldn't find Bluefruit, make sure it's in CoMmanD mode & check wiring?"

After consulting others for help, I found out two things I was doing wrong:

This Bluetooth module was SPI, not UART.
The Bluetooth module needed to be soldered to the header pins in order to conduct power

After changing my code to reflect the SPI module (commenting out the UART section) and soldering the header pins, I used the echoDemo example code and was finally able to "advertise" or connect to my phone! I then used the callbackEcho demo. On my Android smartphone, I connected with the bluetooth module in "UART" mode and was able to send messages and see them display in the serial monitor console. I then chose to connect via the "controller" mode and scrolled down to the "Control Pad" option, which allowed me to use the up/down/left/and right buttons on my smartphone. By viewing the serial monitor, I found out that the there is a character number that was associated with each direction. Specifically, '5' is for forward, '6' for backward, '7' for left, and '8' for right. Therefore, I created a macro in the code to assign each character to its respective direction:

// c macro that replaces defined word when compiled

#define BUTTON_FORWARD '5'

#define BUTTON_BACK '6'

#define BUTTON_LEFT '7'

#define BUTTON_RIGHT '8'

From the callbackEcho demo code, I was able to parse the character that was returned to determine which direction was selected.

I then combined the callbackEcho demo code with my motor control logic code with the idea that the bluetooth would eventually control my motors. However, when I combined the two programs, the bluetooth was no longer advertising. The solution was to comment out the remote control line (associated with my d-pad control) in the loop(). For some reason, the uart.pollACI(); code could not run simultaneously with the remote control code.

1 / 2 • Bluetooth soldered and advertising!

Now the bluetooth module was advertising, but the motors were not moving. To debug, I disconnected the bluetooth module and reconnected the d-pad to make sure that was still working and there wasn't a problem with the motors. The d-pad control still worked, so there shouldn't have been an issue with the motors. I noticed that the L298N H-bridge red light on the module was much brighter when using the D-pad, because it was obtaining extra power from being connected to the breadboard. I concluded that there was probably just not enough power for the motors to move when the bluetooth was connected since it didn't have that additional power source.

After powering the H-bridge with an additional 6V from 4x AA batteries, it worked!

Wheels turning via bluetooth remote-control!

Code

/*********************************************************************/
/*!
    CONTROLLER SETUP
*/
/*********************************************************************/

// This version uses call-backs on the event and RX so there's no data handling in the main loop!

#include <SPI.h>
#include "Adafruit_BLE_UART.h"

#define ADAFRUITBLE_REQ 10
#define ADAFRUITBLE_RDY 2
#define ADAFRUITBLE_RST 4

//SCK -> 13
//MISO -> 12
//MOSI -> 11
//REQ -> 10
//RDY -> 2
//RST -> 4

Adafruit_BLE_UART uart = Adafruit_BLE_UART(ADAFRUITBLE_REQ, ADAFRUITBLE_RDY, ADAFRUITBLE_RST);

/**************************************************************************/
/*!
    This function is called whenever select ACI events happen
*/
/**************************************************************************/
void aciCallback(aci_evt_opcode_t event)
{
  switch(event)
  {
    case ACI_EVT_DEVICE_STARTED:
      Serial.println(F("Advertising started"));
      break;
    case ACI_EVT_CONNECTED:
      Serial.println(F("Connected!"));
      break;
    case ACI_EVT_DISCONNECTED:
      Serial.println(F("Disconnected or advertising timed out"));
      break;
    default:
      break;
  }
}

/**************************************************************************/
/*!
    This function is called whenever data arrives on the RX channel
*/
/**************************************************************************/
// c macro that replaces defined word when compiled 
#define BUTTON_FORWARD '5'
#define BUTTON_BACK '6'
#define BUTTON_LEFT '7'
#define BUTTON_RIGHT '8'

void rxCallback(uint8_t *buffer, uint8_t len)
{
  Serial.print(F("Received "));
  Serial.print(len);
  Serial.print(F(" bytes: "));

  char numbutt = 0;
  if (len >= 3) numbutt = (char)buffer[2]; //make sure there is character in the spot

  switch(numbutt) {
    case BUTTON_FORWARD:
      moveForward();
      break;
    case BUTTON_BACK:
      moveBackward();
      break;
    case BUTTON_LEFT:
      moveLeft();
      break;
    case BUTTON_RIGHT:
      moveRight();
      break;
  }
  stop();
}

/*********************************************************************/
/*!
    MOTOR SETUP
*/
/*********************************************************************/

// connect motor controller pins to Arduino digital pins
// MOTOR A
//int enA = 10; //to control speed
int motorPin1 = 9;
int motorPin2 = 8;
// MOTOR B
//int enB = 5; //to control speed
int motorPin3 = 7;
int motorPin4 = 6;

// set button pins
int buttonPinBack = 2; //backwards; green
int buttonPinLeft = 3; //left; blue
int buttonPinFwd = 4; //forward; yellow
int buttonPinRight = 5; //right; purple

// initialize button states
int buttonStateBack = 0;
int buttonStateLeft = 0;
int buttonStateFwd = 0;
int buttonStateRight = 0;  


void stop() {
  Serial.println("stop");
  digitalWrite(motorPin1, LOW);
  digitalWrite(motorPin2, LOW);  
  digitalWrite(motorPin3, LOW);
  digitalWrite(motorPin4, LOW);
}

void moveForward() {
  Serial.println("forward");
  digitalWrite(motorPin1, HIGH);
  digitalWrite(motorPin2, LOW);  
  digitalWrite(motorPin3, HIGH);
  digitalWrite(motorPin4, LOW); 
  delay(500);
}

void moveBackward() {
  Serial.println("backward");
  // this function will run the motors in both directions at a fixed speed
  // turn on motor A
  digitalWrite(motorPin1, LOW);
  digitalWrite(motorPin2, HIGH);
  //xxxxx analogWrite(enA, 200);  // set speed to 200 out of possible range 0~255
  // turn on motor B
  digitalWrite(motorPin3, LOW);
  digitalWrite(motorPin4, HIGH);
  //xxxxx analogWrite(enB, 200); // set speed to 200 out of possible range 0~255
  delay(500);
}

void moveLeft() {
  Serial.println("left");
  digitalWrite(motorPin1, HIGH);
  digitalWrite(motorPin2, LOW);  
  digitalWrite(motorPin3, LOW);
  digitalWrite(motorPin4, HIGH);
  delay(500);
}

void moveRight() {
  Serial.println("right");
  digitalWrite(motorPin1, LOW);
  digitalWrite(motorPin2, HIGH);  
  digitalWrite(motorPin3, HIGH);
  digitalWrite(motorPin4, LOW); 
  delay(500);
}

void setup()
{
  //serial monitor 9600 for printing to console
  Serial.begin(9600);

  while(!Serial); // Leonardo/Micro should wait for serial init
  Serial.println(F("Adafruit Bluefruit Low Energy nRF8001 Callback Echo demo"));

  // register UART communication with bluetooth module
  uart.setRXcallback(rxCallback);
  uart.setACIcallback(aciCallback);
  uart.setDeviceName("AUDI"); /* 7 characters max! */
  uart.begin();
   
  // set all the motor control pins to outputs
  //pinMode(enA, OUTPUT);
  //pinMode(enB, OUTPUT);
  pinMode(motorPin1, OUTPUT);
  pinMode(motorPin2, OUTPUT);
  pinMode(motorPin3, OUTPUT);
  pinMode(motorPin4, OUTPUT);

  stop();
 
  //initialize the button pins as INPUT for wired D-pad only:
  pinMode(buttonPinBack, INPUT);
  pinMode(buttonPinLeft, INPUT);
  pinMode(buttonPinFwd, INPUT);
  pinMode(buttonPinRight, INPUT);
}

void dumpState() {
  Serial.print("\t");
  Serial.print(buttonStateBack);
  Serial.print("\t");
  Serial.print(buttonStateLeft);
  Serial.print("\t");
  Serial.print(buttonStateFwd);
  Serial.print("\t");
  Serial.print(buttonStateRight);
  Serial.println();
  delay(50);
}

void remoteControl()
{
  buttonStateBack = digitalRead(buttonPinBack);
  buttonStateLeft = digitalRead(buttonPinLeft);
  buttonStateFwd = digitalRead(buttonPinFwd);
  buttonStateRight = digitalRead(buttonPinRight);
  dumpState();
  
  if (buttonStateBack == HIGH) {   // BACKWARD
    moveBackward();
  } 
  
  if (buttonStateLeft == HIGH) { // TURN LEFT
    moveLeft(); 
  }
  
  if (buttonStateFwd == HIGH) {  // FORWARD
    moveForward();
  }
  
  if (buttonStateRight == HIGH) {  // TURN RIGHT
    moveRight();
  } 
  
  if (buttonStateBack == LOW &&
      buttonStateLeft == LOW &&
      buttonStateFwd == LOW &&
      buttonStateRight == LOW) {
    stop(); 
  }
}

void loop()
{
  uart.pollACI(); // Constantly checks for new events on the nRF8001
//  remoteControl();  
  // Serial.print("test");
}

/*********************************************************************
This is an example for our nRF8001 Bluetooth Low Energy Breakout

  Pick one up today in the adafruit shop!
  ------> http://www.adafruit.com/products/1697

Adafruit invests time and resources providing this open source code, 
please support Adafruit and open-source hardware by purchasing 
products from Adafruit!

Written by Kevin Townsend/KTOWN  for Adafruit Industries.
MIT license, check LICENSE for more information
All text above, and the splash screen below must be included in any redistribution
*********************************************************************/

// This version uses call-backs on the event and RX so there's no data handling in the main loop!

#include <SPI.h>
#include "Adafruit_BLE_UART.h"

#define ADAFRUITBLE_REQ 10
#define ADAFRUITBLE_RDY 2
#define ADAFRUITBLE_RST 9

Adafruit_BLE_UART uart = Adafruit_BLE_UART(ADAFRUITBLE_REQ, ADAFRUITBLE_RDY, ADAFRUITBLE_RST);

/**************************************************************************/
/*!
    This function is called whenever select ACI events happen
*/
/**************************************************************************/
void aciCallback(aci_evt_opcode_t event)
{
  switch(event)
  {
    case ACI_EVT_DEVICE_STARTED:
      Serial.println(F("Advertising started"));
      break;
    case ACI_EVT_CONNECTED:
      Serial.println(F("Connected!"));
      break;
    case ACI_EVT_DISCONNECTED:
      Serial.println(F("Disconnected or advertising timed out"));
      break;
    default:
      break;
  }
}

/**************************************************************************/
/*!
    This function is called whenever data arrives on the RX channel
*/
/**************************************************************************/
void rxCallback(uint8_t *buffer, uint8_t len)
{
  Serial.print(F("Received "));
  Serial.print(len);
  Serial.print(F(" bytes: "));
  for(int i=0; i<len; i++)
   Serial.print((char)buffer[i]); 

  Serial.print(F(" ["));

  for(int i=0; i<len; i++)
  {
    Serial.print(" 0x"); Serial.print((char)buffer[i], HEX); 
  }
  Serial.println(F(" ]"));

  /* Echo the same data back! */
  uart.write(buffer, len);
}

/**************************************************************************/
/*!
    Configure the Arduino and start advertising with the radio
*/
/**************************************************************************/
void setup(void)
{ 
  Serial.begin(9600);
  while(!Serial); // Leonardo/Micro should wait for serial init
  Serial.println(F("Adafruit Bluefruit Low Energy nRF8001 Callback Echo demo"));

  uart.setRXcallback(rxCallback);
  uart.setACIcallback(aciCallback);
  // uart.setDeviceName("NEWNAME"); /* 7 characters max! */
  uart.begin();
}

/**************************************************************************/
/*!
    Constantly checks for new events on the nRF8001
*/
/**************************************************************************/
void loop()
{
  uart.pollACI();
}

// COMMON SETTINGS
// ----------------------------------------------------------------------------------------------
// These settings are used in both SW UART, HW UART and SPI mode
// ----------------------------------------------------------------------------------------------
#define BUFSIZE                        128   // Size of the read buffer for incoming data
#define VERBOSE_MODE                   true  // If set to 'true' enables debug output


// SOFTWARE UART SETTINGS
// ----------------------------------------------------------------------------------------------
// The following macros declare the pins that will be used for 'SW' serial.
// You should use this option if you are connecting the UART Friend to an UNO
// ----------------------------------------------------------------------------------------------
#define BLUEFRUIT_SWUART_RXD_PIN       9    // Required for software serial!
#define BLUEFRUIT_SWUART_TXD_PIN       10   // Required for software serial!
#define BLUEFRUIT_UART_CTS_PIN         11   // Required for software serial!
#define BLUEFRUIT_UART_RTS_PIN         4   // Optional, set to -1 if unused


// HARDWARE UART SETTINGS
// ----------------------------------------------------------------------------------------------
// The following macros declare the HW serial port you are using. Uncomment
// this line if you are connecting the BLE to Leonardo/Micro or Flora
// ----------------------------------------------------------------------------------------------
#ifdef Serial1    // this makes it not complain on compilation if there's no Serial1
  #define BLUEFRUIT_HWSERIAL_NAME      Serial1
#endif


// SHARED UART SETTINGS
// ----------------------------------------------------------------------------------------------
// The following sets the optional Mode pin, its recommended but not required
// ----------------------------------------------------------------------------------------------
#define BLUEFRUIT_UART_MODE_PIN        12    // Set to -1 if unused


// SHARED SPI SETTINGS
// ----------------------------------------------------------------------------------------------
// The following macros declare the pins to use for HW and SW SPI communication.
// SCK, MISO and MOSI should be connected to the HW SPI pins on the Uno when
// using HW SPI.  This should be used with nRF51822 based Bluefruit LE modules
// that use SPI (Bluefruit LE SPI Friend).
// ----------------------------------------------------------------------------------------------
#define BLUEFRUIT_SPI_CS               8
#define BLUEFRUIT_SPI_IRQ              7
#define BLUEFRUIT_SPI_RST              6    // Optional but recommended, set to -1 if unused

// SOFTWARE SPI SETTINGS
// ----------------------------------------------------------------------------------------------
// The following macros declare the pins to use for SW SPI communication.
// This should be used with nRF51822 based Bluefruit LE modules that use SPI
// (Bluefruit LE SPI Friend).
// ----------------------------------------------------------------------------------------------
#define BLUEFRUIT_SPI_SCK              13
#define BLUEFRUIT_SPI_MISO             12
#define BLUEFRUIT_SPI_MOSI             11

/*********************************************************************
 This is an example for our nRF51822 based Bluefruit LE modules

 Pick one up today in the adafruit shop!

 Adafruit invests time and resources providing this open source code,
 please support Adafruit and open-source hardware by purchasing
 products from Adafruit!

 MIT license, check LICENSE for more information
 All text above, and the splash screen below must be included in
 any redistribution
*********************************************************************/

#include <Arduino.h>
#include <SPI.h>
#if not defined (_VARIANT_ARDUINO_DUE_X_) && not defined (_VARIANT_ARDUINO_ZERO_)
  #include <SoftwareSerial.h>
#endif

#include "Adafruit_BLE.h"
#include "Adafruit_BluefruitLE_SPI.h"
#include "Adafruit_BluefruitLE_UART.h"

#include "BluefruitConfig.h"

/*=========================================================================
    APPLICATION SETTINGS

    FACTORYRESET_ENABLE       Perform a factory reset when running this sketch
   
                              Enabling this will put your Bluefruit LE module
                              in a 'known good' state and clear any config
                              data set in previous sketches or projects, so
                              running this at least once is a good idea.
   
                              When deploying your project, however, you will
                              want to disable factory reset by setting this
                              value to 0.  If you are making changes to your
                              Bluefruit LE device via AT commands, and those
                              changes aren't persisting across resets, this
                              is the reason why.  Factory reset will erase
                              the non-volatile memory where config data is
                              stored, setting it back to factory default
                              values.
       
                              Some sketches that require you to bond to a
                              central device (HID mouse, keyboard, etc.)
                              won't work at all with this feature enabled
                              since the factory reset will clear all of the
                              bonding data stored on the chip, meaning the
                              central device won't be able to reconnect.
    MINIMUM_FIRMWARE_VERSION  Minimum firmware version to have some new features
    MODE_LED_BEHAVIOUR        LED activity, valid options are
                              "DISABLE" or "MODE" or "BLEUART" or
                              "HWUART"  or "SPI"  or "MANUAL"
    -----------------------------------------------------------------------*/
    #define FACTORYRESET_ENABLE         1
    #define MINIMUM_FIRMWARE_VERSION    "0.6.6"
    #define MODE_LED_BEHAVIOUR          "MODE"
/*=========================================================================*/

// Create the bluefruit object, either software serial...uncomment these lines

SoftwareSerial bluefruitSS = SoftwareSerial(BLUEFRUIT_SWUART_TXD_PIN, BLUEFRUIT_SWUART_RXD_PIN);

//Adafruit_BluefruitLE_UART ble(bluefruitSS, BLUEFRUIT_UART_MODE_PIN,
//                      BLUEFRUIT_UART_CTS_PIN, BLUEFRUIT_UART_RTS_PIN);


/* ...or hardware serial, which does not need the RTS/CTS pins. Uncomment this line */
// Adafruit_BluefruitLE_UART ble(BLUEFRUIT_HWSERIAL_NAME, BLUEFRUIT_UART_MODE_PIN);

/* ...hardware SPI, using SCK/MOSI/MISO hardware SPI pins and then user selected CS/IRQ/RST */
 Adafruit_BluefruitLE_SPI ble(BLUEFRUIT_SPI_CS, BLUEFRUIT_SPI_IRQ, BLUEFRUIT_SPI_RST);

/* ...software SPI, using SCK/MOSI/MISO user-defined SPI pins and then user selected CS/IRQ/RST */
//Adafruit_BluefruitLE_SPI ble(BLUEFRUIT_SPI_SCK, BLUEFRUIT_SPI_MISO,
//                             BLUEFRUIT_SPI_MOSI, BLUEFRUIT_SPI_CS,
//                             BLUEFRUIT_SPI_IRQ, BLUEFRUIT_SPI_RST);


// A small helper
void error(const __FlashStringHelper*err) {
  Serial.println(err);
  while (1);
}

/**************************************************************************/
/*!
    @brief  Sets up the HW an the BLE module (this function is called
            automatically on startup)
*/
/**************************************************************************/
void setup(void)
{
  while (!Serial);  // required for Flora & Micro
  delay(500);

  Serial.begin(115200);
  Serial.println(F("Adafruit Bluefruit Command <-> Data Mode Example"));
  Serial.println(F("------------------------------------------------"));

  /* Initialise the module */
  Serial.print(F("Initialising the Bluefruit LE module: "));

  if ( !ble.begin(VERBOSE_MODE) )
  {
    error(F("Couldn't find Bluefruit, make sure it's in CoMmanD mode & check wiring?"));
  }
  Serial.println( F("OK!") );

  if ( FACTORYRESET_ENABLE )
  {
    /* Perform a factory reset to make sure everything is in a known state */
    Serial.println(F("Performing a factory reset: "));
    if ( ! ble.factoryReset() ){
      error(F("Couldn't factory reset"));
    }
  }

  /* Disable command echo from Bluefruit */
  ble.echo(false);

  Serial.println("Requesting Bluefruit info:");
  /* Print Bluefruit information */
  ble.info();

  Serial.println(F("Please use Adafruit Bluefruit LE app to connect in UART mode"));
  Serial.println(F("Then Enter characters to send to Bluefruit"));
  Serial.println();

  ble.verbose(false);  // debug info is a little annoying after this point!

  /* Wait for connection */
  while (! ble.isConnected()) {
      delay(500);
  }

  Serial.println(F("******************************"));

  // LED Activity command is only supported from 0.6.6
  if ( ble.isVersionAtLeast(MINIMUM_FIRMWARE_VERSION) )
  {
    // Change Mode LED Activity
    Serial.println(F("Change LED activity to " MODE_LED_BEHAVIOUR));
    ble.sendCommandCheckOK("AT+HWModeLED=" MODE_LED_BEHAVIOUR);
  }

  // Set module to DATA mode
  Serial.println( F("Switching to DATA mode!") );
  ble.setMode(BLUEFRUIT_MODE_DATA);

  Serial.println(F("******************************"));
}

/**************************************************************************/
/*!
    @brief  Constantly poll for new command or response data
*/
/**************************************************************************/
void loop(void)
{
  // Check for user input
  char n, inputs[BUFSIZE+1];

  if (Serial.available())
  {
    n = Serial.readBytes(inputs, BUFSIZE);
    inputs[n] = 0;
    // Send characters to Bluefruit
    Serial.print("Sending: ");
    Serial.println(inputs);

    // Send input data to host via Bluefruit
    ble.print(inputs);
  }

  // Echo received data
  while ( ble.available() )
  {
    int c = ble.read();

    Serial.print((char)c);

    // Hex output too, helps w/debugging!
    Serial.print(" [0x");
    if (c <= 0xF) Serial.print(F("0"));
    Serial.print(c, HEX);
    Serial.print("] ");
  }
}

Credits

Audrey Leung

9 projects • 15 followers

Remote-Controlled Car (Pt 4): Bluetooth Wireless Control

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Schematics

nRF8001 Breakout BLE Bluetooth Schematic

Code

Bluetooth car controller

Callback echo demo

Bluefruit config.h

Adafruit Bluetooth LE SPI based

Credits

Audrey Leung

Comments

Embed the widget on your own site

Remote-Controlled Car (Pt 4): Bluetooth Wireless Control

Remote-Controlled Car (Pt 4): Bluetooth Wireless Control

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Schematics

nRF8001 Breakout BLE Bluetooth Schematic

Code

Bluetooth car controller

Callback echo demo

Bluefruit config.h

Adafruit Bluetooth LE SPI based

Credits

Audrey Leung

Comments

Related channels and tags