Simple Environmental Monitoring

This story began 2 years ago when I originally backed a Kickstarter project called WeatherPoint - a circuit which plugged into your android phone and displays various atmospheric variables such as temperature, pressure and humidity. After waiting far too long for the project to materialise and deciding that I still wanted this functionality on my phone, I set out to design my own.

The features I wanted were:

• Must be portable (ie battery powered).

• Must measure, as a minimum, temperature and humidity.

• Preferably have a wireless connection to the phone.

With this in mind I decided on using a Particle Photon as the microcontroller as it has wifi connectivity built in. The main sensor I used was the BME280, a sensor with an I2C interface which measures temperature, humidity and atmospheric pressure. I also included an LDR for light measurement.

Electronic Circuit Design

The main connection was between the Photon and the BME280 sensor which was connected into D0 and D1 together with pull-up resistors. The LDR was connected into analogue input A0. The connections are shown in the following circuit diagram.

Once the circuit was built and tested, a pcb was designed on easyeda.com and ordered from them. The pcb shown below which is public can be viewed, duplicated and modified using this link: https://easyeda.com/pahowells/Photon_Generic_Prototype-91AWGcuMs

On the right hand side of the board, a single neopixel was also added as well as pads to breakout the various digital pins not being used. This was so that I could use the board as a generic board for other projects and therefore is certainly not necessary to the final functionality of the circuit.

Once the pcb's had arrived, one of them was populated and the following code was written on the particle.io IDE.

Code

Initialisation:

The following libraries are included:

• Blynk.h for connecting to my smartphone

• CE_BME280.h for connecting easily to I2C data from the sensor

• Neopixel.h - optional library for the neopixel.

Various variables are configured which will be used in the main code and then the setup() routine starts by firstly setting up the neopixel strip (in this case, just 1 led). Next the connection to the blynk server is started and the bme280 sensor is detected. If the sensor is not connected an error message is published onto the particle.io website. Lastly the current time is stored in a variable for use in a timing structure in the main() loop.

/************************************************************************************
* EnviroMon V1 connected to Blynk app 
* LDR for light level 
* BME280/BMP180 (temperature, humidity, pressure) 
*  
* Written: Peter Howells 
*  
* Blynk connections: 
* V11 = Light 
* V12 = Temperature 
* V13 = Humidity 
* V14 = Pressure 
* V15 = Dewpoint (calculated) 
* V20 = WiFi Signal Strength 
*  
*********************************************************************************/ 
#include "blynk/blynk.h" 
#include "neopixel/neopixel.h" 
#include "CE_BME280/CE_BME280.h" 
SYSTEM_MODE(AUTOMATIC); 
// For neopixels
#define PIXEL_PIN D6 
#define PIXEL_COUNT 1
#define PIXEL_TYPE WS2812B 
Adafruit_NeoPixel strip = Adafruit_NeoPixel(PIXEL_COUNT, PIXEL_PIN, PIXEL_TYPE);
#define SEALEVELPRESSURE_HPA (1013.25) 
CE_BME280 bme;
char auth[] = "xxxxxx"; 
int brightness = 50; 
float bmeTemperature; 
float bmePressure; 
float bmeHumidity; 
float Light; 
float dewpoint; 
int wifiStrength; 
float startTime; 
float sensorValue; 
float Temp;
void setup() 
{ 
   strip.begin(); 
   strip.setBrightness(brightness); 
   strip.show(); // Initialize all pixels 
   Blynk.begin(auth); 
   delay(2000); 
   if(!bme.begin()){ 
       String errorMessage; 
       errorMessage = "Not found"; 
       Spark.publish("BME280 Error", errorMessage); 
       } 
   startTime = millis(); 
}

Main Loop() Routine

The main structures are divided up into the loop() structure, a structure to process the data on analogue 0 (LDR), and a structure to process the data from the bme280 sensor.

In the loop() structure, the Blynk system is run - this provides communication with the Blynk server. Then a timed structure is executed - every 2s (2000ms) the contents of this timed structure will be run. The structure first calculates the WiFi signal strength and publishes it to Blynk, it then executes the getLight() subroutine and finally executes the getBME280Data() subroutine.

void loop(){ 
   Blynk.run(); 
   if (millis() > startTime + 2000){ 
       startTime = millis(); 
       wifiStrength = map(WiFi.RSSI(), -100, 0, 0, 100); 
       Blynk.virtualWrite(V20, wifiStrength);         
       getLight(); 
       getBME280Data(); 
   } 
} 

The getLight() subroutine starts by setting up a 3 point averaging filter to reduce the noise on the ADC. A loop structure was executed 3 times which summed the input on A0. This sum was then divided by 3 to get the actual raw value between 0 and 1024 (10 bit ADC), and the percentage was then calculated and published to the Blynk server.

void getLight(){ 
   for(int x = 0; x <= 2; x++){      //3 point averaging filter
       sensorValue = sensorValue + analogRead(A0); 
   } 
   sensorValue = sensorValue / 3; 
   Light = float(sensorValue) * 100 / 4095; 
   Blynk.virtualWrite(V11, Light); 
} 

The getBME280Data() subroutine started by reading in the temperature and publishing it to Blynk, then the humidity was processed and lastly the pressure was processed. The dewpoint was then calculated and also published to the Blynk server.

void getBME280Data(){ 
   bmeTemperature = bme.readTemperature() - 3; 
   Blynk.virtualWrite(V12, bmeTemperature); 
   bmeHumidity = bme.readHumidity(); 
   if (bmeHumidity > 1){ 
   Blynk.virtualWrite(V13, bmeHumidity); 
   } 
   bmePressure = (bme.readPressure()/100) - 3; 
   Blynk.virtualWrite(V14, bmePressure); 
   dewpoint = bmeTemperature - ((100 - bmeHumidity)/5); 
   Blynk.virtualWrite(V15, dewpoint);
}

The complete code listing can be copied from here:

/************************************************************************************
* EnviroMon V1 connected to Blynk app 
* LDR for light level 
* BME280/BMP180 (temperature, humidity, pressure) 
*  
* Written: Peter Howells 
*  
* Blynk connections: 
* V11 = Light 
* V12 = Temperature 
* V13 = Humidity 
* V14 = Pressure 
* V15 = Dewpoint (calculated) 
* V20 = WiFi Signal Strength 
*  
*********************************************************************************/ 
#include "blynk/blynk.h" 
#include "neopixel/neopixel.h" 
#include "CE_BME280/CE_BME280.h" 
SYSTEM_MODE(AUTOMATIC); 
// For neopixels
#define PIXEL_PIN D6 
#define PIXEL_COUNT 1
#define PIXEL_TYPE WS2812B 
Adafruit_NeoPixel strip = Adafruit_NeoPixel(PIXEL_COUNT, PIXEL_PIN, PIXEL_TYPE);
#define SEALEVELPRESSURE_HPA (1013.25) 
CE_BME280 bme;
char auth[] = "xxxxxx"; 
int brightness = 50; 
float bmeTemperature; 
float bmePressure; 
float bmeHumidity; 
float Light; 
float dewpoint; 
int wifiStrength; 
float startTime; 
float sensorValue; 
float Temp;
void setup() 
{ 
   strip.begin(); 
   strip.setBrightness(brightness); 
   strip.show(); // Initialize all pixels 
   Blynk.begin(auth); 
   delay(2000); 
   if(!bme.begin()){ 
       String errorMessage; 
       errorMessage = "Not found"; 
       Spark.publish("BME280 Error", errorMessage); 
       } 
   startTime = millis(); 
}
void loop(){ 
   Blynk.run(); 
   if (millis() > startTime + 2000){ 
       startTime = millis(); 
       wifiStrength = map(WiFi.RSSI(), -100, 0, 0, 100); 
       Blynk.virtualWrite(V20, wifiStrength);         
       getLight(); 
       getBME280Data(); 
   } 
}
void getLight(){ 
   for(int x = 0; x <= 2; x++){      //3 point averaging filter
       sensorValue = sensorValue + analogRead(A0); 
   } 
   sensorValue = sensorValue / 3; 
   Light = float(sensorValue) * 100 / 4095; 
   Blynk.virtualWrite(V11, Light); 
}
void getBME280Data(){ 
   bmeTemperature = bme.readTemperature() - 3; 
   Blynk.virtualWrite(V12, bmeTemperature); 
   bmeHumidity = bme.readHumidity(); 
   if (bmeHumidity > 1){ 
   Blynk.virtualWrite(V13, bmeHumidity); 
   } 
   bmePressure = (bme.readPressure()/100) - 3; 
   Blynk.virtualWrite(V14, bmePressure); 
   dewpoint = bmeTemperature - ((100 - bmeHumidity)/5); 
   Blynk.virtualWrite(V15, dewpoint);
}

Blynk App Design

The Blynk app allows a simple way to visualise data on a mobile phone and can be found in the Google PlayStore or the Apple AppStore. Once installed, a new project can be created with the Particle Photon as the device. An authorisation code will be generated for this project which must be used in the line of code:

char auth[] = "xxxxxx";

where xxxxxx is your authorisation code.

The connections into the Blynk app are as follows:

• V11 = Light (LDR)

• V12 = Temperature in degrees Celsius

• V13 = Humidity (10 to 90%)

• V14 = Pressure (hPa)

• V15 = Dewpoint (degrees Celsius)

• V20 = WiFi Signal Strength

I used the Gauge Widget for temperature, humidity, pressure and dewpoint, and the Slider Widget for light level and WiFi signal strength. Of course you can experiment and create a GUI to your own liking.

Testing / Calibration

My readings were checked against calibrated temperature, pressure and humidity sensors and I found that both the temperature and pressure were slightly incorrect. These values were corrected to the calibrated reading by subtracting 3 from the measured value. Thereafter the following errors were calculated:

The final working app together with the circuit with battery connected is shown below.