Team CMSC730 Group9:

•

•

•

•

Published December 15, 2024

Blinds Robot

Control blinds’ lift and tilt via smartphone

IntermediateFull instructions provided155

Things used in this project

Hardware components

DFRobot FireBeetle ESP32 IOT Microcontroller (Supports Wi-Fi & Bluetooth)

Greartisan 12V motor

SparkFun Ultrasonic Sensor - HC-SR04

SparkFun Full-Bridge Motor Driver Breakout - L298N

Software apps and online services

Serial Bluetooth Terminal

Hand tools and fabrication machines

3D Printer (generic)

Story

Introduction

In the United States, window blinds often require manual operation, where users need to pull them down to close and use a small rod to rotate the slats to block or allow sunlight. This process can be inconvenient, especially when a room has multiple windows and blinds that must be operated individually. To address this issue, we developed a robotic system that automates curtain control. Our solution uses an ESP32 microcontroller connected to a mobile app, enabling remote operation of two motors mounted on the window frame for seamless and efficient curtain control.

Description

A video of using our blinds robot is linked below

Hardware

Our system incorporates the following hardware components to achieve seamless curtain automation:

1. A wooden frame with blind and ropes

Lifting

Dropping

A wooden frame with a simple bline for demonstration purpose
Fix ropes in the middle to pull up/down the blind symmetrically

2. ESP32 Microcontroller:

Serves as the core of the system, enabling Bluetooth communication with the Android mobile app and controlling motor operations.
Handles real-time signals from the sensors and motor drivers.

3. L298N Motor Driver:

Drives the two motors simultaneously, providing precise control over their speed and direction.

Our circuits that connect ESP32 with L298N through a breadboard.

4. Two Greartisan DC 12V 10RPM Motors:

Mounted on the window frame, the motors work in tandem to move the curtain and rotate the slats.

5. Two Radar Sensors:

sparkfun ultrasonic sensors

Placed at the top and bottom of the window frame, these sensors detect the curtain’s endpoints to prevent over-rotation or misalignment during operation.

6. 3D-Printed Components:

Our motor enclosure for the motor that rotates the slats. This component is fixed to the inner wall of the wooden frame.

Our motor enclosure for the motor that rotates the roller for the ropes to control up/down. This component is fixed to the bottom wall of the wooden frame.

Tilt rod enclosure for the motor that rotates the slats

Custom-designed and printed parts are used to integrate the motors with the window frame, including pulleys and fixtures for securing rods and motors

7. Android Smartphone:

Acts as the remote control via a user-friendly mobile app, communicating with the ESP32 over Bluetooth for seamless operation.

Our design optimizes hardware utilization by using a single ESP32 to coordinate all system functions, from communicating with the app to controlling the L298N motor driver. This ensures a compact, efficient, and cost-effective solution.

Software

Our code (see attachment) controls two motors (Motor1 and Motor2) connected to the ESP32 microcontroller via Bluetooth. Motor1 moves up or down based on ultrasonic distance sensor measurements to avoid exceeding boundaries (top and bottom). Motor2 rotates in specific directions (open, close, stop) and can automatically align to a middle position. Commands for motor control are received via Bluetooth. The code also includes safety features to stop motors when boundaries are detected and uses timers to track movement and position. Real-time status updates are sent to a serial monitor and Bluetooth device.

Summary of Milestone 1

We chose to proceed with the smart blind project from our two initial proposals.

Summary of Milestone 2

We built the frame with blind and ropes, and were able to pull up/down the blind and rotate the slats by manually holding the motors and connecting ESP32 with a laptop.

Summary of Milestone 3

By 3D-printing motor closures and fixing them to the frame, we finally set our hands free! The ultrasonic sensors to support automatically detect the curtain’s endpoints and avoid over-rotation. We also re-write our program to support the sensors and bluetooth connection, so that we could control the whole system on a mobile device.

Schematics

Code

main.cpp

#include <Arduino.h>
#include "BluetoothSerial.h"
#include "esp_bt.h"
#include "esp_log.h"
#include "esp_gap_bt_api.h"
#include "WiFi.h"
#include <time.h>  

int triggerPin_up = 5;
int echoPin_up = 18;
int triggerPin_down = 17;
int echoPin_down = 16;

const int IN1 = 33;    
const int IN2 = 32;    
const int EN = 23;  

// Motor 2
const int IN3 = 25;    
const int IN4 = 26;  

char motorDirection = 'U'; 
char rotateDirection = 'V';
// 'V' - Stop
// 'B' - Rotate
// 'N' - Inverse Roatae
char cmd;
bool isMovingToMiddle = false; 

bool testResults[10];  
int testIndex = 0;     
int successCount = 0;  

BluetoothSerial SerialBT;

time_t rotateStartTime; 
unsigned long lastLoopTime = 0;  
const float MAX_POSITION = 50.0f;
const float MIN_POSITION = 0.0f;
float rotatePosition = (MAX_POSITION + MIN_POSITION) / 2;   

long detectDistance(int triggerPin, int echoPin) {
  long duration = 0, distance = -1;
  digitalWrite(triggerPin, LOW);
  delayMicroseconds(2);
  digitalWrite(triggerPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(triggerPin, LOW);
  duration = pulseIn(echoPin, HIGH);
  distance = (duration / 2) * 0.0343;
  return distance;
}

void setup() {
  Serial.begin(9600);
  pinMode(triggerPin_up , OUTPUT);
  pinMode(echoPin_up, INPUT);
  pinMode(triggerPin_down , OUTPUT);
  pinMode(echoPin_down, INPUT);

  pinMode(IN1, OUTPUT);
  pinMode(IN2, OUTPUT);
  pinMode(IN3, OUTPUT);
  pinMode(IN4, OUTPUT);
  pinMode(EN, OUTPUT);

  digitalWrite(IN1, LOW);
  digitalWrite(IN2, LOW);
  digitalWrite(IN3, LOW);
  digitalWrite(IN4, LOW);

  digitalWrite(EN, HIGH);

  WiFi.mode(WIFI_OFF);
  btStop();

  esp_log_level_set("*", ESP_LOG_VERBOSE);

  if (!SerialBT.begin("ESP32test")) {
    Serial.println("Bluetooth initialization failed!");
    while (1);
  }

  esp_bt_gap_set_scan_mode(ESP_BT_CONNECTABLE, ESP_BT_GENERAL_DISCOVERABLE);
  Serial.println("Bluetooth initialized successfully. You can pair now!");
  cmd = 'S';
}

int up_distance_less_than_20 = 0;
int down_distance_less_than_20 = 0;
int up_distance_greater_than_20 = 0;
int down_distance_greater_than_20 = 0;
int is_less_than_20 = 0;
int is_greater_than_20 = 0;

void compareDistance(int* is_less_than_20, int* is_greater_than_20){
 up_distance_less_than_20 = 0;
  down_distance_less_than_20 = 0;
  up_distance_greater_than_20 = 0;
  down_distance_greater_than_20 = 0;
  *is_less_than_20 = 0;
  *is_greater_than_20 = 0;
  for(int i = 0; i < 10; i++){
    long curtain_position_up = detectDistance(triggerPin_up, echoPin_up);
    long curtain_position_down = detectDistance(triggerPin_down, echoPin_down);
    if(curtain_position_up < 20){
      up_distance_less_than_20++;
    }
    if(curtain_position_down < 20){
      down_distance_less_than_20++;
    }
    if(curtain_position_up > 20){
      up_distance_greater_than_20++;
    }
    if(curtain_position_down > 20){
      down_distance_greater_than_20++;
    }
      Serial.print("Motor1: Distances: ");
    Serial.print(curtain_position_up);
    Serial.print(",");
    Serial.println(curtain_position_down);
    SerialBT.print("Motor1: Distances: ");
    SerialBT.print(curtain_position_up);
    SerialBT.print(",");
    SerialBT.println(curtain_position_down);
    delay(20);
  }
  if(up_distance_less_than_20 > 2* up_distance_greater_than_20 && down_distance_less_than_20 > 2*down_distance_greater_than_20){
    *is_less_than_20 = 1;
  } else if(up_distance_greater_than_20 > 2* up_distance_less_than_20 && down_distance_greater_than_20 > 2* down_distance_less_than_20){
    *is_greater_than_20 = 1;
  }

  Serial.print("Motor1: Distances: ");
  Serial.print(up_distance_less_than_20?"up less than 20":"up greater than 20");
  Serial.print(",");
  Serial.println(down_distance_less_than_20?"down less than 20":"down greater than 20");
  SerialBT.print("Motor1: Distances: ");
  SerialBT.print(up_distance_less_than_20?"up less than 20":"up greater than 20");
  SerialBT.print(",");
  SerialBT.println(down_distance_less_than_20?"down less than 20":"down greater than 20");
}

void readCommand(){
  cmd = ' ';

  if (SerialBT.available() > 0) {
    cmd = SerialBT.read();
    cmd = toupper(cmd);
  }

  if (cmd == 'U') {
    motorDirection = 'U';
    Serial.println("Motor1: Moving Up");
    SerialBT.println("Motor1: Moving Up");
  } else if (cmd == 'D') {
    motorDirection = 'D';
    Serial.println("Motor1: Moving Down");
    SerialBT.println("Motor1: Moving Down");
  } else if (cmd == 'S') {
    motorDirection = 'S';
    Serial.println("Motor1: Stopped");
    SerialBT.println("Motor1: Stopped");
  }
  
  if (cmd == 'V') {
    rotateDirection = 'V';
    isMovingToMiddle = false; 
    SerialBT.println("Motor2: Set rotation: Stop");
  } else if (cmd == 'B') {
    rotateDirection = 'B';
    isMovingToMiddle = false; 
    SerialBT.println("Motor2: Set rotation: Open");
  } else if (cmd == 'N') {
    rotateDirection = 'N';
    isMovingToMiddle = false;  
    SerialBT.println("Motor2: Set rotation: Close");
  } else if (cmd == 'M') {
    isMovingToMiddle = true; 
    float middlePosition = (MAX_POSITION + MIN_POSITION) / 2;
    if (rotatePosition < middlePosition - 0.1) {
      rotateDirection = 'B';
      SerialBT.println("Motor2: Moving to middle position: Opening");
    } else if (rotatePosition > middlePosition + 0.1) {
      rotateDirection = 'N';
      SerialBT.println("Motor2: Moving to middle position: Closing");
    } else {
      rotateDirection = 'V';
      isMovingToMiddle = false; 
      SerialBT.println("Motor2: Already at middle position");
    }
  }
}

void loop() {
  
  readCommand();

  // Motor1:
  // up down motor: compare distance
  compareDistance(&is_less_than_20, &is_greater_than_20);
  if(motorDirection == 'U' && is_greater_than_20){
    motorDirection = 'S';
    Serial.println("Motor1: Hit the top");
    SerialBT.println("Motor1: Hit the top");
  } else if(motorDirection == 'D' && is_less_than_20){
    motorDirection = 'S';
    Serial.println("Motor1: Hit the bottom");
    SerialBT.println("Motor1: Hit the bottom");
  }

  // up down motor: move or stop
  if (motorDirection == 'U') {
    digitalWrite(IN1, HIGH);
    digitalWrite(IN2, LOW);
  } else if (motorDirection == 'D') {
    Serial.println("Motor1: in Down");
    digitalWrite(IN1, LOW);
    digitalWrite(IN2, HIGH);
  } else if (motorDirection == 'S') {
    digitalWrite(IN1, LOW);
    digitalWrite(IN2, LOW);
  }

  // Motor2:
  unsigned long currentTime = millis();
  float deltaTime = (currentTime - lastLoopTime) / 1000.0f;  
  lastLoopTime = currentTime;

  if (rotateDirection == 'B') {  
    if (rotatePosition < MAX_POSITION) {
        digitalWrite(IN3, HIGH);
        digitalWrite(IN4, LOW);
        rotatePosition += deltaTime;  
        float displayPosition = constrain(rotatePosition, MIN_POSITION, MAX_POSITION);
        float percentage = (displayPosition / MAX_POSITION) * 100;  
        Serial.printf("Motor2: Rotating position: %.1f%%\n", percentage);   
        SerialBT.printf("Motor2: Rotating position: %.1f%%\n", percentage);
    } else {
        digitalWrite(IN3, LOW);
        digitalWrite(IN4, LOW);
        rotateDirection = 'V';
        Serial.println("Motor2: Reached max position, stopping");
        SerialBT.println("Motor2: Reached max position, stopping");
    }
  } else if (rotateDirection == 'N') { 
    if (rotatePosition > MIN_POSITION) {
        digitalWrite(IN3, LOW);
        digitalWrite(IN4, HIGH);
        rotatePosition -= deltaTime;  
        float displayPosition = constrain(rotatePosition, MIN_POSITION, MAX_POSITION);
        float percentage = (displayPosition / MAX_POSITION) * 100;  
        Serial.printf("Motor2: Rotating position: %.1f%%\n", percentage);   
        SerialBT.printf("Motor2: Rotating position: %.1f%%\n", percentage);
    } else {
        digitalWrite(IN3, LOW);
        digitalWrite(IN4, LOW);
        rotateDirection = 'V';
        Serial.println("Motor2: Reached min position, stopping");
        SerialBT.println("Motor2: Reached min position, stopping");
    }
  } else if (rotateDirection == 'V') {
    digitalWrite(IN3, LOW);
    digitalWrite(IN4, LOW);
  }

  if (rotateDirection != 'V' && isMovingToMiddle) {  
    float middlePosition = (MAX_POSITION + MIN_POSITION) / 2;
    if (rotatePosition >= middlePosition - 0.1 && rotatePosition <= middlePosition + 0.1) {
        rotateDirection = 'V';
        digitalWrite(IN3, LOW);
        digitalWrite(IN4, LOW);
        isMovingToMiddle = false; 
        SerialBT.println("Motor2: Reached middle position, stopping");
        Serial.println("Motor2: Reached middle position, stopping");
    }
  }

  delay(50);
}

Credits

Comments

Please log in or sign up to comment.

Blinds Robot

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Introduction

Description

Hardware

Software

Summary of Milestone 1

Summary of Milestone 2

Summary of Milestone 3

Custom parts and enclosures

enclosure_for_slats_NpCRzlEKM5.f3z

roller_v13_g7f8zts2tA.f3d

motor_stand_Nw3v5o8UeC.f3z

Schematics

861734299698__pic_EH7bk70hdq.jpg

Code

main.cpp

Credits

Wei Wang

Hao Dong

Xiyi Chen

Nengneng Yu

Peiqing Chen

Comments

Embed the widget on your own site

Blinds Robot

Blinds Robot

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Introduction

Description

Hardware

Software

Summary of Milestone 1

Summary of Milestone 2

Summary of Milestone 3

Custom parts and enclosures

enclosure_for_slats_NpCRzlEKM5.f3z

roller_v13_g7f8zts2tA.f3d

motor_stand_Nw3v5o8UeC.f3z

Schematics

861734299698__pic_EH7bk70hdq.jpg

Code

main.cpp

Credits

Wei Wang

Hao Dong

Xiyi Chen

Nengneng Yu

Peiqing Chen

Comments

Related channels and tags