Published December 31, 2015

IoT real-time dashboard with PubNub & TI LaunchPad

Create a real-time sensor data dashboards using PubNub & TI LaunchPad development kits.

BeginnerFull instructions provided6,968

IoT real-time dashboard with PubNub & TI LaunchPad

Things used in this project

Hardware components

Texas Instruments MSP-EXP432P401R SimpleLink MSP432 LaunchPad

Texas Instruments CC3100BOOST SimpleLink CC3100 Wi-Fi BoosterPack

Seeed Studio Grove Starter Kit for LaunchPad

Software apps and online services

Texas Instruments Energia

PubNub Publish/Subscribe API

Story

Making a REAL-TIME IoT data dashboard with PubNub, PubNub EON & TI LaunchPad.

In this tutorial, we are going to create a Wi-Fi internet-connected sensor node using the MSP432 LaunchPad from Texas Instruments, the CC3100 Wi-Fi BoosterPack & various sensors from Seeed Studio.

Here's a quick preview video of it all working together!

RECORDED WEBINAR FEATURING THIS PROJECT!

Our friends @PubNub were so kind to invite us to give a training/webinar featuring this tutorial.

Check out the recording here: goo.gl/7bHjOQ

Let's build the hardware

In this system, we are using several modular components from the Texas Instruments LaunchPad ecosystem.

MSP432 LaunchPad Development Kit
CC3100 Wi-Fi BoosterPack
Grove Base BoosterPack
Grove Moisture Sensor
Grove Ambient Light Sensor

Plug in the hardware as shown in the images above. Note the sensor connections. This will be helpful when we start looking at the embedded code/firmware.

Ambient Light Sensor = PIN 23
Moisture Sensor = PIN 24

Let's write the embedded code/firmware!

Now that our hardware is setup, let's switch our attention to the firmware/code. In this demo, we use Energia, an easy to use programming tool for the TI LaunchPad development kits. Energia is a fork of the open source Arduino IDE, so it's a very familiar environment to those familiar with that coding style/language.

NOTE however, that Energia offers a unique feature called multi-tasking when used with certain LaunchPad development kits (including the MSP432 LaunchPad we are using). This multi-tasking feature allows you to run multiple Energia/Arduino sketches in parallel on the same microcontroller! This is a powerful concept that we will take some advantage of in this tutorial.

In this demo, we will have 3 tasks running in parallel.

TASK 1: Reading the moisture sensor
TASK 2: Reading the ambient light sensor
TASK 3: Encoding the latest sensor data in JSON, then publish to PubNub!

We use simple global variables for inter-task communication. Task 1 & 2 will simply update a global variable periodically with the latest sensor readings. Task 3 takes the latest values in the global variables, encodes them into a JSON payload, then publishes it up to PubNub. The code for each task is below in the code section of this Hackster.io tutorial.

To create a new task in Energia, we simply need to create a separate "setup/loop" pair. Each setup/loop pair resides in it's own tab.

Be sure to modify the code examples with your own PubNub pub & sub keys & the desired channel!!! Also be sure to add in your Wi-Fi credentials.

The pictures below show how the three tasks can be setup into separate tabs in the Energia IDE. Be sure to select the MSP432 LaunchPad by going to Tools > Board > [select MSP432 LaunchPad].

1 / 2

Let's build our web-side dashboard with the help of PubNub's EON!

Once your LaunchPad is flashed with the code shared in this tutorial, we can start building the web-side dashboard.

To test if you are indeed sending the appropriate JSON encoded data to PubNub, be sure to try PubNub's easy-to-use Developer Debug Console. Simply log into PubNub & click on the "Debug Console" link. This will allow you to see all of the messages across your various PubNub channels.

Here is a link to a jsFiddle for the web-side dashboard:

http://jsfiddle.net/qc3bzzjx/2/

Note that the jsFiddle is broken up into 3 code files (HTML, Javascript & CSS). Most of the magic resides in the Javascript file.

You can fork the jsfiddle above to make modifications & test out your own code. Remember to modify the jsfiddle to include the appropriate PubNub pub & sub keys. Also make sure to modify the jsfiddle to listen to the appropriate channel.

There are lots of documentation on how to modify the look & feel of these EON-based charts. Below are a few nifty links:

PubNub EON reference/documentation: https://github.com/pubnub/eon
Generic c3.js reference/documentation: http://c3js.org/reference.html

/*
  PubNub sample client

  This sample client will publish raw (JSON pre-encoded) PubNub messages.

  This code is in the public domain.
  */

#include <SPI.h>
#include <WiFi.h>
#include <PubNub.h>
#include <aJSON.h>

byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };

WiFiClient *client;
PubSubClient *subClient;
  
char pubkey[] = "ADD_YOUR_PUBKEY_HERE";
char subkey[] = "ADD_YOUR_SUBKEY_HERE";
char* channel = "ADD_YOUR_CHANNEL_HERE";
//char subChannel[] = "hello_world_sub";

// your network name also called SSID
char ssid[] = "ADD_YOUR_WIFI_SSID_HERE";
// your network password
char password[] = "ADD_YOUR_WIFI_PASSWORD_HERE";

//GLOBAL VARIABLES
int MOISTURE = 0;
int LIGHT = 0;

void setup()
{
  Serial.begin(115200);
  Serial.println("Serial set up");

  // attempt to connect to Wifi network:
  Serial.print("Attempting to connect to Network named: ");
  Serial.println(ssid); 
  
  // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
  WiFi.begin(ssid, password);
  
  while ( WiFi.status() != WL_CONNECTED) {
    // print dots while we wait to connect
    Serial.print(".");
    delay(300);
  }
  Serial.println("\nYou're connected to the network");
  
  Serial.println("Waiting for an ip address");
  while (WiFi.localIP() == INADDR_NONE) {
    // print dots while we wait for an ip addresss
    Serial.print(".");
    delay(300);
  }
  Serial.println("\nIP Address obtained");

  // Print the WiFi status.
  printWifiStatus();

  PubNub.begin(pubkey, subkey);
  Serial.println("PubNub set up");
}

void loop()
{
  
    // CREATE JSON ENCODED PAYLOAD TO PUBLISH
    aJsonObject *msg = createMessage();
    char* myPayload = (char*)aJson.print(msg);
  
    client = PubNub.publish(channel, myPayload);  // https://jsfiddle.net/qc3bzzjx/embedded/result/
    Serial.print("published message: ");
    Serial.println(myPayload);
    aJson.deleteItem(msg);
    free(myPayload);
    
    delay(250);

}


aJsonObject *createMessage()
{
  aJsonObject *msg = aJson.createObject();
  aJsonObject *eon = aJson.createObject();
  aJson.addStringToObject(eon, "myName", "TI_LaunchPad");
  aJson.addNumberToObject(eon, "LIGHT", (int)LIGHT);
  aJson.addNumberToObject(eon, "MOISTURE", (int)MOISTURE);
  aJson.addItemToObject(msg, "eon", eon);
  return msg;
}

void printWifiStatus() {
	// print the SSID of the network you're attached to:
	Serial.print("SSID: ");
	Serial.println(WiFi.SSID());

	// print your WiFi IP address:
	IPAddress ip = WiFi.localIP();
	Serial.print("IP Address: ");
	Serial.println(ip);

	// print the received signal strength:
	long rssi = WiFi.RSSI();
	Serial.print("signal strength (RSSI):");
	Serial.print(rssi);
	Serial.println(" dBm");
}