Team IOT14: Elijah Conrad, Kalan Petrea

Published November 18, 2018 © GPL3+

Peltier Dehumidifier for 3D Printer Filament

A dehumidifier for your 3D printing dry box to keep your filament dry without the need for desiccant.

IntermediateFull instructions provided8 hours16,763

Peltier Dehumidifier for 3D Printer Filament

Things used in this project

Hardware components

Particle Photon

Adafruit HTU21D-F Temperature & Humidity Sensor Breakout Board

TEC1-12706 Peltier Module

Thermal Paste

12V Switching Power Supply

CPU Cooler (Heat Sink)

High Current Barrel Jack

High Current Barrel Plug

Texas Instruments 5V Linear Regulator

Heat Sink

N-Channel MOSFET

SPST On-Off Rocker Switch

1/8" ID x 3/16" OD Polyurethane Tubing

#10-32 UNF to 1/8" Hose Barb

90mm 12V Fan (2 wire)

M3 Screws

Software apps and online services

Particle Build Web IDE

ThingSpeak API

Hand tools and fabrication machines

Prusa i3 MK2.5 3D Printer

Bernzomatic Micro Torch

Wire Strippers

IWISS Crimping Tool (If you choose to use connectors)

2.5mm Hex Driver

Story

Overview

After building this project you should have a fully functioning dehumidifier for your 3D printer dry box to keep your filament dry and ready to use. The dehumidifier works using a Peltier device which transfers heat from one side of the device to the other producing a hot and cold side. The cold side of the device produces condensation thereby removing moisture from the air within the dry box. The Peltier is sandwiched between two heat sinks in which a fan blows across. The fan provides cooling for the hot side of the Peltier while also blowing off built up condensation on the fins of the cold heat sink. The dehumidifier is controlled by two Particle Photons. One Photon controls the Peltier device while the other reads the humidity and temperature inside the dry box. The two photons communicate with one another to determine whether the Peltier should be on or off and whether the power level should be set to one or two (low or high). The high power mode kicks in when the humidity level has reached approximately 30%. At this point further moisture can only be removed from the air by going below freezing. The desired target humidity and other parameters can be set at the top of the code using the predefined variables.

Assembly

First, cut the original barrel plug off of the power supply and solder on the new high current barrel plug.

Assemble the two heat sinks and the Peltier module using thermal paste and the clamp bracket. Attach the clamp bracket using the fasteners included with the large heat sink. Make sure to orient the large heatsink with the fins running in the long direction of the clamp as shown in the picture. Otherwise the heatsink will not fit into the enclosure correctly. Note: The springs included with the heatsink will not be used for this project.

Two Heatsinks Clamped onto the Peltier Module

Reference the circuit schematic to assemble the electronics. Connectors can be used for the low current portions of the circuit if desired. Note: Insert the rocker switch and high current barrel jack into the electronics enclosure box before attaching these two components to the rest of the circuit. Also ensure that the wires carrying 12V to the photon in the filament box are long enough to reach it by traveling through the outlet air pipe and into the filament box.

Electronics Inside the Enclosure

Long Wires for the Photon in the Filament Box Guided Through the Air Outlet

Place the Peltier assembly inside its enclosure and fasten with four M3x16 screws. Warning: Tighten screws only until they are snug.

Peltier Assembly Mounted in its Enclosure

Fasten the 90mm fan onto the top pipe connector using the appropriate fasteners for your chosen fan. Note: Orient the fan to pull air in through the small end of the top pipe connector.

Fan Mounted onto the Top Pipe Connector

Attach the top pipe connector and the electronics enclosure to the Peltier assembly enclosure while guiding the wires through the cut outs of the enclosure. Use four M3x12 screws for the top pipe connector and four M3x6 screws for the electronics enclosure (WARNING: Stop tightening the screws for the electronics enclosure as soon as you feel any resistance or you will strip the threads. This is very easy to do since the screws only have 3mm of engagement with the plastic.) Note: The cut outs may be need to be enlarged for certain wire sizes.

Wires Guided Through Cutouts in the Peltier Assembly Enclosure

Attach the side pipe connector to the Peltier assembly enclosure using four M3x10 screws. (WARNING: Only tighten the screws a small amount after first feeling resistance or your will strip the threads. There is only 6mm of engagement here.)

Route air to and from the dehumidifier using 2-1/2" PVC pipe or pipe of equivalent outer diameter. An M3 screw and nut can be used to tighten the clamp onto the pipe.

Screw the hose barb into the drain outlet near the bottom of the Pelter enclosure assembly. Attach the polyurethane hose and route to desired location. Note: Super glue or appropriate sealant may be needed to prevent leaks around the threads on the hose barb. If the hose barb cannot be successfully threaded into the printed part the polyethylene hose can be encouraged to fit into the hole without the barb and held in place with super glue or other.

Hose Barb Secured in the Drain with Drain Tubing Connected

ThingSpeak

ThingSpeak Interface

ThingSpeak logs real time humidity and temperature of the dry box as well as the power state of the dehumidifier. The status of the dehumidifier can be checked at anytime from anywhere to ensure that the system is functioning properly. Note: The charts displayed above contain data that was reported every 30 seconds instead of the 5 minute default set in the code. ThingSpeak Page

Schematics

Code

Humidity and Temperature Measurement Decision Making Code

Arduino

This code tells the photon located inside the dry box to read the temperature and humidity from the HTU21D sensor and make a decision determining what power settings the Peltier control photon should be set to. Based on the targeted humidity level the photon will determine what power level the Peltier needs to be at to effectively reduce the humidity inside the dry box. Once the humidity inside the dry box reaches the "FreezingDewPointHumidity" the Peltier will need to be in power level 2 to cause frost to form on the Peltiers surface in order to remove additional water from the air. Once the humidity inside the dry box has reached the targeted humidity level the photon will tell the Peltier control photon to turn off the Peltier until the humidity increases in which the photon will tell the control photon to turn it back on again. The photon checks the humidity every five minutes to ensure the target humidity is being maintained. (Note: Make sure to come up with your own event names for the subscribe and publish functions and replace the default ones in the code or else you will have issues.)

#include <HTU21D.h>

HTU21D htu;

int PowerLevel = 0;
int PeltierState = 0;
const int TargetHum = 25;
const int FreezingDewPointHumidity = 40;
float Humidity;
float Temperature;
unsigned long LastTime = 0;
int main_fuction_CallTime = 300000;

void Peltier_onoff_Handler(String event, String data) {
    PeltierState = data.toInt();
}

void Peltier_power_level_Handler(String event, String data) {
    PowerLevel = data.toInt();

}

void setup() {
 htu.begin();
 Particle.subscribe("Gunner_P/MEGR_3171/Dehumidifier_Filament_Box/Peltier_state", Peltier_onoff_Handler);
 Particle.subscribe("Gunner_P/MEGR_3171/Dehumidifier_Filament_Box/Peltier_power", Peltier_power_level_Handler);
 Particle.publish("Elijah_C_MEGR_3171_Dehumidifier_Filament_Box_Project", String(0), 10);
 //LastResetTime = millis();
}

void main_function() {
    Humidity = htu.readHumidity();
    Temperature = htu.readTemperature();
    Particle.publish("3D Printer Filament Box", + "{ \"1\":\"" + String(Humidity) + "\"," + "\"2\":\"" + String(Temperature) + "\"," + "\"3\":\"" + String(PeltierState) + "\"," + "\"4\":\"" + String(PowerLevel) + "\" }", 10, PRIVATE);
    
    if (TargetHum < Humidity && PeltierState == 0) {
       
       Particle.publish("Elijah_C_MEGR_3171_Dehumidifier_Filament_Box_Project", String(1), 10);
       
       
       if (FreezingDewPointHumidity <= Humidity && PowerLevel != 1) {
           
           Particle.publish("Elijah_C_MEGR_3171_Peltier_Power_Level_Dehumidifier_Box", String(1), 10);
          
       }
       
       if (FreezingDewPointHumidity > Humidity && PowerLevel != 2) {
           
           Particle.publish("Elijah_C_MEGR_3171_Peltier_Power_Level_Dehumidifier_Box", String(2), 10);
           
       }
    }
    
    
    if (TargetHum > Humidity && PeltierState == 1) {
        
        Particle.publish("Elijah_C_MEGR_3171_Dehumidifier_Filament_Box_Project", String(0), 10);
        
    }
}

void loop() { 
    if (millis() - LastTime >= main_fuction_CallTime) {
        main_function();
        LastTime = millis();
    }
}

/* Program description*/


// User Configuration
const float Power_Level_1 = 90;          //Low power level in percent supplied to the Peltier module that will not cause the dehumidifier to ice up
const float Power_Level_2 = 100;         //Supplies maximum power to the Peltier module but may cause the dehumidifier to ice up
const float Fan_Speed_1 = 40;            //Fan speed in percent for power level 1 above
const float Fan_Speed_2 = 60;            //Fan speed in percent for power level 2 avove
const char Peltier_MOSFET_Pin = D0;      //Pin that will control the Peltier MOSFET (Must be digital PWM)
const char Fan_MOSFET_Pin = D2;          //Pin that will control the fan MOSFET (Must be digital PWM if anything other than 100 is used for the fan speeds)
const int Fan_PWM_Frequency = 20;        //Frequency of the PWM signal that will be sent to the Fan
const int Peltier_PWM_Frequency = 500;   //Frequency of the PWM signal that will be sent to the Peltier module

// Program Variables
bool request_Peltier_on = false;
float Peltier_power_level = (Power_Level_1/100)*255;
int Peltier_current_state = 0;
float Peltier_current_power_level = Peltier_power_level;
float fan_speed = (Fan_Speed_1/100)*255;
unsigned long last_millis = 0;
int update_interval = 60000;


// Recieved Data Handlers
void on_off_request_handler(String event, String data) {
    request_Peltier_on = data.toInt();
    Particle.publish("Gunner_P/MEGR_3171/Dehumidifier_Filament_Box/Peltier_state", String(request_Peltier_on), 10);
}

void Peltier_power_handler(String event, String data) {
    if (data.toInt() == 1) {
        Peltier_power_level = (Power_Level_1/100)*255;
        fan_speed = (Fan_Speed_1/100)*255;
        Particle.publish("Gunner_P/MEGR_3171/Dehumidifier_Filament_Box/Peltier_power", String(1), 10);
    }
    if (data.toInt() == 2) {
        Peltier_power_level = (Power_Level_2/100)*255;
        fan_speed = (Fan_Speed_2/100)*255;
        Particle.publish("Gunner_P/MEGR_3171/Dehumidifier_Filament_Box/Peltier_power", String(2), 10);
    }
}


// Dehumidifier Manager
void dehumidifier_manager() {
    if (request_Peltier_on && Peltier_current_state == 0) {
        analogWrite(Peltier_MOSFET_Pin, Peltier_power_level, Peltier_PWM_Frequency);
        Peltier_current_power_level = Peltier_power_level;
        analogWrite(Fan_MOSFET_Pin, 255, Fan_PWM_Frequency);
        delay(200);
        analogWrite(Fan_MOSFET_Pin, fan_speed, Fan_PWM_Frequency);
        Peltier_current_state = 1;
    }
    if (!request_Peltier_on && Peltier_current_state == 1) {
        analogWrite(Peltier_MOSFET_Pin, 0);
        analogWrite(Fan_MOSFET_Pin, 0);
        Peltier_current_state = 0;
    }
    if (Peltier_current_state == 1 && Peltier_current_power_level != Peltier_power_level) {
        analogWrite(Peltier_MOSFET_Pin, Peltier_power_level, Peltier_PWM_Frequency);
        Peltier_current_power_level = Peltier_power_level;
        analogWrite(Fan_MOSFET_Pin, 255, Fan_PWM_Frequency);
        delay(200);
        analogWrite(Fan_MOSFET_Pin, fan_speed, Fan_PWM_Frequency);
    }
}


// Setup
void setup() {
    pinMode(Peltier_MOSFET_Pin, OUTPUT);
    pinMode(Fan_MOSFET_Pin, OUTPUT);
    Particle.subscribe("Elijah_C_MEGR_3171_Dehumidifier_Filament_Box_Project", on_off_request_handler);
    Particle.subscribe("Elijah_C_MEGR_3171_Peltier_Power_Level_Dehumidifier_Box", Peltier_power_handler);
    Particle.publish("Gunner_P/MEGR_3171/Dehumidifier_Filament_Box/Peltier_state", String(request_Peltier_on), 10);
}


// Loop
void loop() {
    if (millis() - last_millis >= update_interval); {
        dehumidifier_manager();
        last_millis = millis();
    }
}

Credits

Elijah Conrad

1 project • 0 followers

Kalan Petrea

1 project • 0 followers

Peltier Dehumidifier for 3D Printer Filament