1. Introduction
2. Starting with Cayenne myDevices
3. Programming Agrumino on Arduino IDE
4. Customizing Cayenne platform and setting some triggers
5. Testing frequency measure and triggered notifications
6. Conclusions

Published July 27, 2022 © GPL3+

Agrumino Lemon-Temperature and Humidity on Cayenne Platform

Using Agrumino Lemon to read Humidity and Temperature on Cayenne myDevices platform

BeginnerFull instructions provided1 hour137

Agrumino Lemon-Temperature and Humidity on Cayenne Platform

Things used in this project

Hardware components

Lifely Agrumino Lemon

Micro-USB to USB Cable (Generic)

Software apps and online services

Arduino IDE

myDevices Cayenne

Story

1. Introduction

The aim of this Project is to visualize, on your Cayenne myDevices account, the measure values of humidity and temperature obtained and sent through MQTT from your Agrumino Lemon(Lifely), device which is chip-based on ESP8266.

Since Agrumino Lemon has all the needed sensors on board (sensor of temperature, soil moisture, illuminance, etc...), it becomes useful in order not to buy and use a lot of connection wires and sensors(as common instead for other microcontrollers), but just connect the Agrumino with a micro-USB cable to the PC.

Below is reported the video tutorial of the overall procedure explained in this web page:

2. Starting with Cayenne myDevices

Step 1: login to Cayenne myDevices

After you created an account on Cayenne myDevices, login to it at the link:

https://accounts.mydevices.com/auth/realms/cayenne/protocol/openid-connect/auth?response_type=code&scope=email+profile&client_id=cayenne-web-app&state=0wWB6jx6U5wteFpQ71jtr1aD9OGhi261repB4wcF&redirect_uri=https%3A%2F%2Fcayenne.mydevices.com%2Fauth%2Fcallback

or search it on google and then do the login.

Step 2: select the correct device (Generic ESP8266 for Agrumino)

Now select "Generic ESP8266" for your Agrumino Lemon chip-based on ESP8266.

Step 3: take note of your given MQTT credentials

In your Cayenne configuration dashboard you can see three MQTT credentials to receive and/or send data from your Agrumino to the Cayenne platform and/or viceversa(MQTT USERNAME, MQTT PASSWORD, CLIENT ID).

Take note of them, because of course these must be used in your Agrumino code.

The only other two credentials to use in your Agrumino code are the connection name and password to connect to your wifi(SSID_NAME and SSID_PASSWORD in the code).

3. Programming Agrumino on Arduino IDE

Step 4: Download the Cayenne MQTT library.ZIP file to include on Arduino IDE

Always in your Cayenne configuration dashboard, on the left, is reported a link to download the Cayenne MQTT Library(click on "Cayenne MQTT Library"), which will bring you at the following github link:

https://github.com/myDevicesIoT/Cayenne-MQTT-ESP

Then from the github page download the.ZIP file with the green button,

and include it on your Arduino UNO libraries:

Also install the Agrumino library already present in the libraries handler of Arduino IDE:

Configure your device selecting "Lifely Agrumino Lemon vx" as the board, set the baud rate (Upload speed) according to that specified in your code(argument of the function call "Serial.begin(****)" into the function declaration "void setup()"), and select the USB port where you attached the USB cable that connects to your Agrumino device:

After that, you can upload the code to your Agrumino.

4. Customizing Cayenne platform and setting some triggers

Step 5: return to your Cayenne myDevices platform

After the code has been correctly uploaded on Agrumino, return to your Cayenne myDevices platform that is waiting for your device to connect to it through MQTT, and check if the current measure values of humidity(channel 0) and temperature(channel 1) have been correctly sent:

Step 6: customize the humidity and temperature widget

To better describe what the two channel widgets represent, it is better to customize them with some more representative names and logos to be displayed to the user. To do that, click on the '+' symbol at the top-right corner of every widget to add them to the dashboard, then click on 'Settings' to customize them:

Step 7: set some notification triggers for the humidity and temperature channels

It is possible to set some triggers for chosen values of humidity and temperature, and to send related notifications to the user via email or sms to warn it about.

From the top-right corner of every widget, click on "Trigger", then give a name to every trigger you create, and fill the form with the trigger conditions(threshold values of humidity or temperature), in order to notify the user when these happen(via sms in this example).

5. Testing frequency measure and triggered notifications

Step 8: check if the real frequency measure corresponds to the specified one in the code

Now it is time to check if the real frequency measure correspond to the desired one specified in the code( 1 min in this example). So a look to the Serial monitor of the Arduino and to the dashboard of Cayenne must be done.

At the same moment, look if the phone is receiving the triggered sms notifications (in case the humidity and temperature values trigger them):

In this case, the frequency measure is exactly 1 minute as we specified in the code, and also the humidity and temperature values triggered the sms notifications(humidity below 20% and temperature above 30°C, on the right).

6. Conclusions

The semplicity of use of the Agrumino Lemon in therm of code(the Lifely community documents and mantains its libraries) and also thanks to the zero wire connections and third part sensors needed, it made a lot easier and fast its use compared to other famous microcontrollers.

In addition, Cayenne myDevices platform semplified a lot the MQTT connection, and gave the possibility to use a lot of useful widgets, and free methods to send trigger notifications (via sms and emails).

Agrumino_Cayenne_humid_temp

/*
Cayenne Agrumino Humidity-Temperature measure
*/


// WiFi network info
char SSID_NAME[] = "****"; //insert your wifi connection name
char SSID_PASSWORD[] = "****"; //insert your wifi password



#define CONNECTION_ATTEMPTS 30
#define MAX_NUM_NOTIFICATIONS_PER_DAY 90 //Cayenne limit is max 90 sms or email notifications per day

//#define SECONDS_BETWEEN_MEASURES 86400/(MAX_NUM_NOTIFICATIONS_PER_DAY/2) //seconds in a day divide the max number of Cayenne notifications per day, 
                                                                           //where the '/2' is because the 90 notifications could be at worst 45 for the humidity and 45 for the temperature.
#define SECONDS_BETWEEN_MEASURES 60  //if it is unlikely to receive 90 notifications per day, use this instead of the expression above, and change the value on your need.

#include <CayenneMQTTESP8266.h>
#include <Agrumino.h>

Agrumino agrumino; //Agrumino object

// Cayenne authentication info. This should be obtained from the Cayenne Dashboard
char username[] = "****";
char password[] = "****";
char clientID[] = "****";

//Variables for humidity and temperature values
float humidity;
float temperature;

//Counter of wifi connection attempts
int wifiCount = 0;

void wifiSetup(){
  
  Serial.print("Connecting to ");
  Serial.println(SSID_NAME);
  WiFi.mode(WIFI_STA);
  WiFi.begin(SSID_NAME, SSID_PASSWORD);

  while ((WiFi.status() != WL_CONNECTED) && (wifiCount < CONNECTION_ATTEMPTS)){
    delay(500);
    wifiCount++;
    Serial.print(".");
  }

  if (wifiCount >= CONNECTION_ATTEMPTS){
    Serial.println("Failed to connect,...."
                  "Please check your internet connection..."
                  "I'm rebooting now...");
    ESP.restart();
  }else if (WiFi.status() == WL_CONNECTED) {
    Serial.print("I'm Connected with:"  );
    Serial.println(SSID_NAME);
    delay(100);
  }
}


void setup(){
  
  Serial.begin(115200);
  Serial.println("Cayenne begin");
  Cayenne.begin(username, password, clientID, SSID_NAME, SSID_PASSWORD);
  Serial.println("Agrumino Setup");
  agrumino.setup();
  agrumino.turnBoardOn();
  long int agruminoChipId = ESP.getChipId();
  Serial.println("My ChipId is : " + String(agruminoChipId));
  wifiSetup();
  delay(500);
}

void loop(){
  
  //Run Cayenne Functions
  Cayenne.loop();
}

CAYENNE_OUT(V0){
  /*V0 is the output Channel #0 for sending data to Cayenne with MQTT, the first channel to be used */
  
  //Check if read failed and try until success
  do {
    //Read humidity (percent)
    humidity = agrumino.readSoil(); //soilMoisture
  } while  (isnan(humidity));

  Serial.print("humidity: ");
  Serial.println(humidity);
  
  //Write to Cayenne Dashboard
  Cayenne.virtualWrite(V0, humidity);
}

CAYENNE_OUT(V1){
  /*V1 is the output Channel #1 for sending data to Cayenne with MQTT, the second channel to be used, so after V0 */
  
  //Check if read failed and try until success
  do {
    //Read temperature as Celsius
    temperature = agrumino.readTempC();
  } while  (isnan(temperature));

  Serial.print("temperature: ");
  Serial.println(temperature);

  //Write to Cayenne Dashboard
  Cayenne.virtualWrite(V1, temperature);
  delay(1000); //there must be a delay between the Cayenne.virtualWrite and the deepSleepSec functions, otherwise the measure doesn't reach cayenne platform (the dashboard would remain 'Offline').
  
  //The deepSleepSec function will be used in order to save battery when the Agrumino is unused for measures or connection.
  //The deepSleepSec time has been chosen according to the max possible number of Cayenne notifications per day(90), and also used as frequency measure.
  //Anyway looking at the Serial Monitor after activating the visible timings (checkbutton bottom-left), it is possible to see that there is a time shift 
  //of 11 seconds between two measures, due to some extra time for the connection, restart and other routines with delays. 
  //So 11 seconds will be subtracted ('-11' in the deepSleepSec argument) to calibrate and obtain the real frequency measure specified as ''SECONDS_BETWEEN_MEASURES''.
  //Anyway, you can change the frequency measure as needed:
  //infact it is very unlikely that there will be a notification for every measure, see the comment at the beginning of this file for the macro 'SECONDS_BETWEEN_MEASURES'.
  agrumino.deepSleepSec(SECONDS_BETWEEN_MEASURES-11); //remember that the max seconds of deepsleep are 4'294 seconds (see the function deepSleepSec in Agrumino.cpp)
}