Story
The Problem
The Fix
The Parts
DFRobot
Power
The Setup
The Code
Wrapping Up

Published December 25, 2022 © MIT

How to Use IR Remote and WS2812 LEDs with Arduino

This tutorial is for using a IR Remote with WS2812 LEDs! It is good for building onto an existing project, or a new one! Plenty of modes!

BeginnerFull instructions provided30 minutes642

How to Use IR Remote and WS2812 LEDs with Arduino

Things used in this project

Hardware components

DFRobot WS2812 180led 3m

DFRobot IR Remote Kit for Arduino

Arduino Nano R3

Jumper wires (generic)

Resistor 330 ohm

Story

Have you ever tried to use WS2812 LEDs with Arduino? Well, that may be easy, but have you ever tried adding a IR remote? Now it gets complicated!

This tutorial is not of me building a specific project per se, but rather a How To on using WS2812 and IR together on Arduino!

The Problem

As I have explained in one of my other tutorials, using WS2812 LEDs and a IR remote is a bit complicated.

WS2812 is a LED 5050 chip that is an individually addressable LED. So each of these LEDs on one strip, can be a different color and brightness all at the same time! The different colors work because each chip has 3 LEDs inside; a Red, Green, and Blue! To get white, you just turn all three LED chips on, and the resulting color appears to be white, when its really just red, green, and blue light combined. This type of LED requires precise timing to work correctly.

IR (InfraRed) is a wavelength of light just beyond what the human eye can see; it has a longer wavelength than visible light. A IR remote works by encoding pulses of IR light, which are then received and decoded by a IR receiver. This process also requires precise timing.

Seeing that IR and WS2812 both need precise timing, we have an issue. During my testing, I found that if I am displaying something on the LEDs, the Arduino will still "receive" IR codes, but they turn out as a bungled mess! So the Arduino cannot be controlled while displaying something.

The Fix

There are a couple ways around this problem:

Use Multiple Arduinos
Accept any received IR code as an interruption (i.e. act like a on/off button)
Not use functions that require constant updating (that wouldn't be fun though!)

I decided on using the second method; accepting any IR codes as a on/off button while the LED strip is running.

This method has a few obvious drawbacks though:

TV remotes and other IR remotes will shut the display off also
Cannot update display with IR remote while it is running

Even though these drawbacks are not very good at all, these are the only options I could think of. If you have a different idea, post in the comments and I'll try it out!

Edit:

I found another method; using non-blocking code! My first library utilizes the second method, but my second library ("_NB") utilizes non-blocking code, so it is much better.

The Parts

This project uses only a few parts:

DFRobot Parts

DFRobot

DFRobot was the sponsor for this project! They have many awesome components and modules for building any electronic project you can think of! I personally buy from them and love all of their parts. The quality is very good!

Check them out here.

Or click this link:

https://www.dfrobot.com

Power

WS2812 LEDs, as I explained, really are three separate LEDs! A standard LED uses roughly 20mA, so if we had all three fully on (white), each pixel would be needing 60mA.

I have a 180 pixel strip, so 180 * 0.06 = 10.8A

Wow! That is a lot of power for a 9' LED strip.

So... to provide this amount of power, you can use a caged AC to DC converter as pictured below:

Caged AC to DC converter

Make sure to get a 5V version that can handle the amount of LEDs you have. If you have less LEDs, for example, 40, then you can use a 2.4A power supply, which some USB wall warts can do.

The Setup

The setup is fairly simple, seeing that we only need a couple parts to get us in action!

I borrowed the schematic picture from howtomechatronics.com. They're an awesome website for building Arduino projects too!

Credit: https://howtomechatronics.com/tutorials/arduino/how-to-control-ws2812b-individually-addressable-leds-using-arduino/

The 330Ω resistor on the data line is used to reduce noise, so there is less flickering or missed pixels.

The Code

I wrote two libraries and many, many sketches to perfect a setup that works pretty reliably. In my GitHub repository, I have two working libraries, one of which works with timing and IR interruption, and the other with non-blocking code. I also have two working sketches (besides the libraries); one with modes and the other without! By looking at the sketches, you can understand how non-blocking code works.

All of the libraries and sketches in my GitHub repository have been tested on an Arduino Nano, and they all work!

Github Repository:

https://github.com/Kgray44/WS2812IR

I also made a `doc` directory for my WS2812IR_NB library, which explains what all of the functions do! https://github.com/Kgray44/WS2812IR/tree/main/WS2812IR_NB/docs

Wrapping Up

That was all for this project. If you have any suggestions, comments, questions, please post in the comments section below!

Check out more of my projects here:

https://hackster.io/k-gray

Code

WS2812IR_No_Blocking_with_Modes.ino

/*************************************************************
File Name: WS2812IR_No_Blocking_with_Modes.ino
Processor/Platform: Arduino (Nano tested)
Development Environment: Arduino 2.0.13
Download latest code here:
https://github.com/Kgray44/WS2812IR
Driveway Gates code meant to be used alongside the tutorial found here:
https://www.hackster.io/k-gray/how-to-use-ir-remote-and-ws2812-leds-with-arduino-342df9
Copyright 2022 K Gray
Permission is hereby granted, free of charge, to any person obtaining a copy of this software and
associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation
the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, 
and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE 
WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR 
COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, 
ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
Liscense found here:
https://opensource.org/licenses/MIT
 *************************************************************/

bool testIR = false;//true or false

#include <IRremote.h>
#include <Adafruit_NeoPixel.h>

#define modeAmount 5
#define hueinc 1000
#define brightinc 20

#define RECV_PIN  3
#define PIN       2
#define NUMPIXELS 180

IRrecv irrecv(RECV_PIN);
decode_results results;
unsigned long key_value = 0;

unsigned long hue = 0;

int bright = 127;
int modecount = 0;
bool mode = false;
bool on = true;
bool update = true;
int currentpixel=0;
bool first = true;
int section = 1;
bool flash = false;
int t=1;
int d=1;
int p=1;
unsigned long firstpixelhue=0;

struct structu {
  int value=0;
  unsigned long lastm=0;
  int timeb=0;
  int number=0;
  bool rising=true;
};
structu pixelF[15];
int pc=0;

unsigned long lastmillis=0;

Adafruit_NeoPixel pixels(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);

void setup() {
  Serial.begin(9600);

  irrecv.enableIRIn();
  irrecv.blink13(true);

  pixels.begin();
}

void loop() {
  listenIR();
  takeStep();
}

void listenIR() {
  if (irrecv.decode()) {
    handleKey();
    irrecv.resume();  // Receive the next value
  }
}

void takeStep(){
  if (on){
    pixels.setBrightness(bright);
    if (!mode){
      if (update){
        pixels.fill(pixels.gamma32(pixels.ColorHSV(hue)),0,NUMPIXELS);
        pixels.show();
        update=false;
      }
    }
    else {
      if (modecount == 0){
        if (millis() - lastmillis > 300){
          if (first){
            currentpixel=currentpixel+6;
            pixels.fill(pixels.gamma32(pixels.ColorHSV(hue)),currentpixel,currentpixel+3);
            pixels.fill(pixels.Color(0,0,0),currentpixel+3,currentpixel+6);
            if (currentpixel >= NUMPIXELS){
              pixels.show();
              currentpixel=0;
              first = false;
              lastmillis = millis();
            }
          }
          else {
            currentpixel=currentpixel+6;
            pixels.fill(pixels.Color(0,0,0),currentpixel,currentpixel+3);
            pixels.fill(pixels.gamma32(pixels.ColorHSV(hue)),currentpixel+3,currentpixel+6);
            if (currentpixel >= NUMPIXELS){
              pixels.show();
              currentpixel=0;
              first = true;
              lastmillis = millis();
            }
          }
        }
      }
      else if (modecount == 1){
        if (millis() - lastmillis > 200){
          if (section == 1){
            currentpixel=currentpixel+3;
            pixels.setPixelColor(currentpixel,pixels.gamma32(pixels.ColorHSV(hue)));
            pixels.setPixelColor(currentpixel-1,pixels.Color(0,0,0));
            if (currentpixel >= NUMPIXELS){
              pixels.show();
              currentpixel=1;
              section = 2;
              lastmillis = millis();
            }
          }
          else if (section == 2){
            currentpixel=currentpixel+3;
            pixels.setPixelColor(currentpixel,pixels.gamma32(pixels.ColorHSV(hue)));
            pixels.setPixelColor(currentpixel-1,pixels.Color(0,0,0));
            if (currentpixel >= NUMPIXELS){
              pixels.show();
              currentpixel=2;
              section = 3;
              lastmillis = millis();
            }
          }
          else {
            currentpixel=currentpixel+3;
            pixels.setPixelColor(currentpixel,pixels.gamma32(pixels.ColorHSV(hue)));
            pixels.setPixelColor(currentpixel-1,pixels.Color(0,0,0));
            if (currentpixel >= NUMPIXELS){
              pixels.show();
              currentpixel=0;
              section = 1;
              lastmillis = millis();
            }
          }
        }
      }
      else if (modecount == 2){
        if (millis() - lastmillis > t && !flash){
          pixels.setPixelColor(p,pixels.Color(255,255,255));
          pixels.show();
          flash = true;
          lastmillis = millis();
        }
        else if (millis() - lastmillis > d && flash){
          pixels.setPixelColor(p,pixels.Color(0,0,0));
          pixels.show();
          flash = false;
          lastmillis = millis();
          t = random(10,500);
          d = random(4,30);
          p = random(0,NUMPIXELS);
        }
      }
      else if (modecount == 3){
        if (millis() - lastmillis > 5){
          currentpixel++;
          int pixelHue = firstpixelhue + (currentpixel * 65536L / NUMPIXELS);
          pixels.setPixelColor(currentpixel,pixels.ColorHSV(pixelHue));
          if (currentpixel >= NUMPIXELS){
            pixels.show();
            currentpixel=0;
            firstpixelhue=firstpixelhue+256;
            lastmillis = millis();
          }
        }
      }
      else if (modecount == 4){
        pc++; if (pc>10){pc=0;}
        if (millis() - pixelF[pc].lastm > pixelF[pc].timeb){
          if (pixelF[pc].rising==true){
            pixelF[pc].value=pixelF[pc].value+10;
            pixels.setPixelColor(pixelF[pc].number, pixels.Color(pixelF[pc].value,pixelF[pc].value,map(pixelF[pc].value,0,255,0,80)));
            pixels.show();
            if (pixelF[pc].value >= 250){
              pixelF[pc].value=250;
              pixels.setPixelColor(pixelF[pc].number, pixels.Color(pixelF[pc].value,pixelF[pc].value,map(pixelF[pc].value,0,255,0,80)));
              pixels.show();
              pixelF[pc].timeb=random(50,1000);
              pixelF[pc].lastm=millis();
              pixelF[pc].rising=false;
            }
          }
          else {
            pixelF[pc].value=pixelF[pc].value-10;
            pixels.setPixelColor(pixelF[pc].number, pixels.Color(pixelF[pc].value,pixelF[pc].value,map(pixelF[pc].value,0,255,0,80)));
            pixels.show();
            if (pixelF[pc].value <= 0){
              pixelF[pc].value=0;
              pixels.setPixelColor(pixelF[pc].number, pixels.Color(0,0,0));
              pixels.show();
              pixelF[pc].timeb=random(1000,14000);
              pixelF[pc].lastm=millis();
              pixelF[pc].rising=true;
              pixelF[pc].number=random(0,NUMPIXELS);
            }
          }
        }
      }
    }
  }
  else {
    if (update){
      clear();
      update=false;
    }
  }
}

void clear(){
  pixels.fill(pixels.Color(0,0,0),0,NUMPIXELS);
  pixels.show();
}

void handleKey() {
  uint16_t command;
  if (irrecv.decodedIRData.protocol == 7 && !testIR){
    command = irrecv.decodedIRData.command;
  }
  if (testIR){
    Serial.println(command);
    return;
  }
  Serial.println("Protocol:" + String(irrecv.decodedIRData.protocol));

  switch (command) {
    case 0:  Serial.println("POWER");  update=true;currentpixel=0;on = !on; break;
    case 1:  Serial.println("VOL+");   update=true;bright+=brightinc;if(bright>255){bright=255;} break;
    case 2:  Serial.println("FUNC.");  update=true;clear();mode = !mode; break;
    case 4:  Serial.println("BACK");   update=true;if (mode){clear();modecount--;if(modecount<0){modecount=modeAmount-1;}}else{hue-=hueinc;if(hue<0){hue=65536;}} break;
    case 5:  Serial.println("PLAY");   break;
    case 6:  Serial.println("NEXT");   update=true;if (mode){clear();modecount++;if(modecount>modeAmount-1){modecount=0;}}else{hue+=hueinc;if(hue>65536){hue=0;}} break;
    case 8:  Serial.println("DOWN");   break;
    case 9:  Serial.println("VOL-");   update=true;bright-=brightinc;if(bright<0){bright=0;} break;
    case 10: Serial.println("UP");     break;
    case 12: Serial.println("num: 0"); break;
    case 13: Serial.println("EQ");     break;
    case 14: Serial.println("REPT.");  break;
    case 16: Serial.println("num: 1"); break;
    case 17: Serial.println("num: 2"); break;
    case 18: Serial.println("num: 3"); break;
    case 20: Serial.println("num: 4"); break;
    case 21: Serial.println("num: 5"); break;
    case 22: Serial.println("num: 6"); break;
    case 24: Serial.println("num: 7"); break;
    case 25: Serial.println("num: 8"); break;
    case 26: Serial.println("num: 9"); break;
    default: Serial.println(command);  break;
  }
}

Credits

K Gray

23 projects • 23 followers

I love making things out of electronic components, coding in python and C++, designing PCBs and lots more.

Contact

Comments

Please log in or sign up to comment.

How to Use IR Remote and WS2812 LEDs with Arduino